commit: f4a0e8c9bc441d54f6afc0aa27739044427daa8a
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 15 08:03:33 2022 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Apr 15 08:22:01 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f4a0e8c9
dev-python/cmd2: add 2.4.1
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
dev-python/cmd2/Manifest | 1 +
dev-python/cmd2/cmd2-2.4.1.ebuild | 58 +++++++++++++++++++++++++++++++++++++++
2 files changed, 59 insertions(+)
diff --git a/dev-python/cmd2/Manifest b/dev-python/cmd2/Manifest
index eef60eddc678..f8d354948f0b 100644
--- a/dev-python/cmd2/Manifest
+++ b/dev-python/cmd2/Manifest
@@ -1 +1,2 @@
DIST cmd2-2.4.0.tar.gz 680118 BLAKE2B
09f4893db7587dce9fd59103f8a1ef54c2b61248dd4aed313a90a390bb50e8927ef7a11dc5ca3af90b5ccf36ce16e0e18f3b555cc961a8c6862f7b8131f190ae
SHA512
4ecd4c71294bee86f02b39a588c42a7232309db54459c950f77734926dedc3ec273237b9615bab6ef8a499c65442e3d6f7d2e9f159ccca021db0b450435ffbc0
+DIST cmd2-2.4.1.tar.gz 676903 BLAKE2B
10b27d7658ee366d44d5fd13a4daf3adb65537043e0475e4c30b5a3b5e142cae982515f033e52fbd63bbce583ffc64e7b0a032d4cc0bbca76303720ecb2a8232
SHA512
862ff0ed301dc8fd588fb564602b32c9e8dee1dcae9965b0ed4605acc98b63ca5767b28c0030410395fb34ea1a0c7cf966972c19b75b93c1a3a3b90b582279fb
diff --git a/dev-python/cmd2/cmd2-2.4.1.ebuild
b/dev-python/cmd2/cmd2-2.4.1.ebuild
new file mode 100644
index 000000000000..26a05e90d1bf
--- /dev/null
+++ b/dev-python/cmd2/cmd2-2.4.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Extra features for standard library's cmd module"
+HOMEPAGE="https://github.com/python-cmd2/cmd2";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc64 ~sparc ~x86
~amd64-linux ~x86-linux"
+
+RDEPEND="
+ dev-python/attrs[${PYTHON_USEDEP}]
+ >=dev-python/colorama-0.3.7[${PYTHON_USEDEP}]
+ >=dev-python/pyperclip-1.6[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]
+ dev-python/wcwidth[${PYTHON_USEDEP}]
+"
+# pyperclip uses clipboard backends in the following preference order:
+# pygtk, xclip, xsel, klipper, qtpy, pyqt5, pyqt4.
+# klipper is known to be broken in Xvfb, and therefore causes test
+# failures. to avoid them, we must ensure that one of the backends
+# preferred to it is available (i.e. xclip or xsel) + which(1).
+BDEPEND="
+ dev-python/setuptools_scm[${PYTHON_USEDEP}]
+ test? (
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ sys-apps/which
+ || (
+ x11-misc/xclip
+ x11-misc/xsel
+ )
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ distutils-r1_src_prepare
+ sed -i -e '/--cov/d' setup.cfg || die
+}
+
+src_test() {
+ # tests rely on very specific text wrapping...
+ local -x COLUMNS=80
+ virtx distutils-r1_src_test
+}
+
+python_test() {
+ epytest -p no:pytest-qt || die
+}
