commit: b36f42426095efaa70ddd4275b77f2a215cb87e9
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Thu May 5 07:10:40 2022 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Thu May 5 07:11:59 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b36f4242
dev-python/autobahn: add 22.4.2
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
dev-python/autobahn/Manifest | 1 +
dev-python/autobahn/autobahn-22.4.2.ebuild | 115 +++++++++++++++++++++++++++++
2 files changed, 116 insertions(+)
diff --git a/dev-python/autobahn/Manifest b/dev-python/autobahn/Manifest
index 23a153a25e38..a1a85babf638 100644
--- a/dev-python/autobahn/Manifest
+++ b/dev-python/autobahn/Manifest
@@ -1 +1,2 @@
DIST autobahn-22.3.2.tar.gz 376020 BLAKE2B
5d7b776c24541b08363942ed1868d5e7a2ccb4f99edc1ad722d3d68417852f324e79afa5ec8cc0251499ba27c078087ba40be744d657b562f5f1c431492705b6
SHA512
a33619bb7624f56bf571a4c61d11290316554c5c5a23724c6d5624f1e8e673dfc6a8e12ea3b17f809306a14f45e982b3425a23efb123003b575b248718c9a299
+DIST autobahn-22.4.2.tar.gz 396061 BLAKE2B
da51f53f138ff6935f55561305c9cb0b29dcfef27fa63f32beac867f8aec2149a681f2dcbea6f30423e5571bf0fbf18fe13604c11d1accf78629c714bcbbc754
SHA512
9d803a699dd370b25e6c1601e635fe60a8e24f33245008bfe271d34ba47e70b7fab8c555a2c68a5255515a51e56476a63bfb0c9d98ed3687b71317ab46efc5ec
diff --git a/dev-python/autobahn/autobahn-22.4.2.ebuild
b/dev-python/autobahn/autobahn-22.4.2.ebuild
new file mode 100644
index 000000000000..a15603075d58
--- /dev/null
+++ b/dev-python/autobahn/autobahn-22.4.2.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 optfeature
+
+MY_P=${PN}-$(ver_rs 3 -)
+
+DESCRIPTION="WebSocket and WAMP for Twisted and Asyncio"
+HOMEPAGE="https://pypi.org/project/autobahn/
+ https://crossbar.io/autobahn/
+ https://github.com/crossbario/autobahn-python";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="test xbr"
+RESTRICT="!test? ( test )"
+
+# The order of deps is based on their appearance in setup.py
+# All extra deps should be included in test and in optfeature
+RDEPEND="
+ >=dev-python/zope-interface-5.2.0[${PYTHON_USEDEP}]
+ >=dev-python/twisted-20.3.0[${PYTHON_USEDEP}]
+ >=dev-python/attrs-20.3.0[${PYTHON_USEDEP}]
+ >=dev-python/txaio-21.2.1[${PYTHON_USEDEP}]
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ >=dev-python/hyperlink-21.0.0[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ >=dev-python/wsaccel-0.6.3[${PYTHON_USEDEP}]
+ >=dev-python/snappy-0.6.0[${PYTHON_USEDEP}]
+ >=dev-python/msgpack-1.0.2[${PYTHON_USEDEP}]
+ >=dev-python/ujson-4.0.2[${PYTHON_USEDEP}]
+ >=dev-python/cbor2-5.2.0[${PYTHON_USEDEP}]
+ >=dev-python/py-ubjson-0.16.1[${PYTHON_USEDEP}]
+ >=dev-python/flatbuffers-1.12[${PYTHON_USEDEP}]
+ >=dev-python/pyopenssl-20.0.1[${PYTHON_USEDEP}]
+ >=dev-python/service_identity-18.1.0[${PYTHON_USEDEP}]
+ >=dev-python/pynacl-1.4.0[${PYTHON_USEDEP}]
+ >=dev-python/pytrie-0.4[${PYTHON_USEDEP}]
+ >=dev-python/pyqrcode-1.2.1[${PYTHON_USEDEP}]
+ >=dev-python/cffi-1.14.5[${PYTHON_USEDEP}]
+ >=dev-python/argon2-cffi-20.1.0[${PYTHON_USEDEP}]
+ >=dev-python/passlib-1.7.4[${PYTHON_USEDEP}]
+
+ dev-python/pytest[${PYTHON_USEDEP}]
+ dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+ dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+ )
+"
+
+python_prepare_all() {
+ if use xbr ; then
+ eerror "***************"
+ eerror "Required xbr dependencies are incomplete in Gentoo."
+ eerror "So this functionality will not yet work"
+ eerror "Please file a bug if this feature is needed"
+ eerror "***************"
+ else
+ # remove xbr components
+ export AUTOBAHN_STRIP_XBR="True"
+ fi
+
+ # avoid useless rust dependency
+ sed -i -e '/cryptography/s:>=3.4.6::' setup.py || die
+
+ # remove twisted plugin cache regen in setup.py
+ # to fix tinderbox sandbox issue
+ sed -e '/import/s:reactor:__importmustfail__:' \
+ -i setup.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ einfo "Testing all, cryptosign using twisted"
+ local -x USE_TWISTED=true
+ cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+ "${EPYTHON}" -m twisted.trial autobahn || die "Tests failed with
${EPYTHON}"
+ unset USE_TWISTED
+
+ einfo "RE-testing cryptosign and component_aio using asyncio"
+ local -x USE_ASYNCIO=true
+ epytest autobahn/wamp/test/test_wamp_{cryptosign,component_aio}.py
+ unset USE_ASYNCIO
+
+ rm -f twisted/plugins/dropin.cache || die
+}
+
+pkg_postinst() {
+ optfeature "C-based WebSocket acceleration" "dev-python/wsaccel"
+ optfeature "non-standard WebSocket compression support"
"dev-python/snappy"
+ optfeature "accelerated WAMP serialization support" \
+ "dev-python/msgpack dev-python/ujson dev-python/cbor2
dev-python/flatbuffers dev-python/py-ubjson"
+ optfeature "TLS transport encryption" \
+ "dev-python/pyopenssl dev-python/pynacl dev-python/pytrie
dev-python/pyqrcode dev-python/service_identity"
+ optfeature "WAMP-SCRAM authentication" \
+ "dev-python/cffi dev-python/argon2-cffi dev-python/passlib"
+ optfeature "native SIMD acceleration" "dev-python/cffi"
+
+ python_foreach_impl twisted-regen-cache
+}
+
+pkg_postrm() {
+ python_foreach_impl twisted-regen-cache
+}
