commit: ea0efe16fc0bafb21f44597c97b6ac5529aa8e10
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun May 8 18:04:12 2022 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun May 8 18:07:14 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ea0efe16
net-misc/gnome-connections: Add new package, version 42.1.2
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
net-misc/gnome-connections/Manifest | 1 +
.../gnome-connections-42.1.2.ebuild | 64 ++++++++++++++++++++++
net-misc/gnome-connections/metadata.xml | 8 +++
3 files changed, 73 insertions(+)
diff --git a/net-misc/gnome-connections/Manifest
b/net-misc/gnome-connections/Manifest
new file mode 100644
index 000000000000..a3cd4d100bc0
--- /dev/null
+++ b/net-misc/gnome-connections/Manifest
@@ -0,0 +1 @@
+DIST gnome-connections-42.1.2.tar.xz 3987992 BLAKE2B
2cad2376c238884b069767efbcd8afae5270f576e499fa59defe2d8ec10188cfd9b263a63cd44fcbe9ceed315267807f6b106f93d1fc73092e6c5366d9daac62
SHA512
34bc8e167ccd828c1aa52728017a52282d96b607751d566e3f8a5169d6fd5ccd7c6ae04abb073946f5cf6038c7b23b3eb897e2922b6d5b914d89ac0afbbbc7ed
diff --git a/net-misc/gnome-connections/gnome-connections-42.1.2.ebuild
b/net-misc/gnome-connections/gnome-connections-42.1.2.ebuild
new file mode 100644
index 000000000000..8fb4b3b9b9da
--- /dev/null
+++ b/net-misc/gnome-connections/gnome-connections-42.1.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="A remote desktop client for the GNOME desktop environment"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/connections";
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+ dev-libs/gobject-introspection
+ >=dev-libs/glib-2.50:2
+ >=x11-libs/gtk+-3.22:3[introspection]
+ >=net-libs/gtk-vnc-0.4.4[vala]
+ >=gui-libs/libhandy-1.2.0:1[vala]
+ >=dev-libs/libxml2-2.7.8
+ app-crypt/libsecret[vala]
+
+ >=net-misc/freerdp-2.0.0:0=
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+ ${PYTHON_DEPS}
+ $(vala_depend)
+ dev-libs/glib
+ dev-util/glib-utils
+ dev-util/itstool
+ sys-devel/gettext
+ virtual/pkgconfig
+
+ test? (
+ dev-libs/appstream-glib
+ dev-util/desktop-file-utils
+ )
+"
+
+src_prepare() {
+ default
+ vala_setup
+}
+
+src_configure() {
+ local emesonargs=(
+ -Dprofile=default
+ )
+ meson_src_configure
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}
diff --git a/net-misc/gnome-connections/metadata.xml
b/net-misc/gnome-connections/metadata.xml
new file mode 100644
index 000000000000..f453528b934f
--- /dev/null
+++ b/net-misc/gnome-connections/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd";>
+<pkgmetadata>
+ <maintainer type="project">
+ <email>[email protected]</email>
+ <name>Gentoo GNOME Desktop</name>
+ </maintainer>
+</pkgmetadata>
