commit: 8faabf8ab57ce47b23b84c9621d926d75428d0be
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon May 9 19:27:47 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon May 9 20:11:58 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8faabf8a
dev-python/pytest-xdist: EAPI 8, PEP517
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
.../pytest-xdist/pytest-xdist-2.5.0-r1.ebuild | 45 ++++++++++++++++++++++
1 file changed, 45 insertions(+)
diff --git a/dev-python/pytest-xdist/pytest-xdist-2.5.0-r1.ebuild
b/dev-python/pytest-xdist/pytest-xdist-2.5.0-r1.ebuild
new file mode 100644
index 000000000000..68f728f1bae7
--- /dev/null
+++ b/dev-python/pytest-xdist/pytest-xdist-2.5.0-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Distributed testing and loop-on-failing modes"
+HOMEPAGE="
+ https://pypi.org/project/pytest-xdist/
+ https://github.com/pytest-dev/pytest-xdist/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+ dev-python/execnet[${PYTHON_USEDEP}]
+ dev-python/psutil[${PYTHON_USEDEP}]
+ >=dev-python/pytest-6.2.0[${PYTHON_USEDEP}]
+ dev-python/pytest-forked[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+ dev-python/setuptools_scm[${PYTHON_USEDEP}]
+ test? (
+ dev-python/filelock[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ # disable autoloading plugins in nested pytest calls
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ # since we disabled autoloading, force loading necessary plugins
+ local -x PYTEST_PLUGINS=xdist.plugin,xdist.looponfail,pytest_forked
+
+ epytest
+}
