commit: 5bac27d308f715dc38fffedc2318e9fddb0a3ba4
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu May 19 00:29:57 2022 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu May 19 01:09:19 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5bac27d3
dev-python/dbus-next: new package, add 0.2.3
Signed-off-by: Sam James <sam <AT> gentoo.org>
dev-python/dbus-next/Manifest | 1 +
dev-python/dbus-next/dbus-next-0.2.3.ebuild | 42 +++++++++++++++++++++++++++++
dev-python/dbus-next/metadata.xml | 12 +++++++++
3 files changed, 55 insertions(+)
diff --git a/dev-python/dbus-next/Manifest b/dev-python/dbus-next/Manifest
new file mode 100644
index 000000000000..1695fd2e9bea
--- /dev/null
+++ b/dev-python/dbus-next/Manifest
@@ -0,0 +1 @@
+DIST dbus-next-0.2.3.tar.gz 81711 BLAKE2B
6acc38a05511b3de7e13893d82dd1ecd55f9a6124b4d859574294602b921ff012776c12ddb02e1be437b258c7bd5120a3a9625fc5b06bbbe02915dcc4c14897b
SHA512
7836d855c755c8ac6cbbb251ca0cbd2f4df9b573f31b1ea1cab480e47896d36b4cb0d479b2469b0bf0b5c700068361a18874b4a087f73020cdcb4e04a2d7dbe7
diff --git a/dev-python/dbus-next/dbus-next-0.2.3.ebuild
b/dev-python/dbus-next/dbus-next-0.2.3.ebuild
new file mode 100644
index 000000000000..6e7d9b789770
--- /dev/null
+++ b/dev-python/dbus-next/dbus-next-0.2.3.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1 virtualx
+
+DESCRIPTION="The next great DBus library for Python with asyncio support"
+HOMEPAGE="https://python-dbus-next.readthedocs.io/en/latest/";
+SRC_URI="https://github.com/altdesktop/python-dbus-next/archive/refs/tags/v${PV}.tar.gz
-> ${P}.tar.gz"
+S="${WORKDIR}"/python-${P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="test? (
+ dev-python/pygobject[${PYTHON_USEDEP}]
+ dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+ dev-python/pytest-timeout[${PYTHON_USEDEP}]
+ )"
+
+EPYTEST_IGNORE=(
+ # "interface not found on this object: org.freedesktop.DBus.Debug.Stats"
+ # Seems like we build dbus w/o this?
+ test/client/test_signals.py
+)
+
+distutils_enable_tests pytest
+
+src_test() {
+ local dbus_params=(
+ $(dbus-daemon --session --print-address --fork --print-pid)
+ )
+ local -x DBUS_SESSION_BUS_ADDRESS=${dbus_params[0]}
+
+ virtx distutils-r1_src_test
+
+ kill "${dbus_params[1]}" || die
+}
diff --git a/dev-python/dbus-next/metadata.xml
b/dev-python/dbus-next/metadata.xml
new file mode 100644
index 000000000000..4c10a1f049b6
--- /dev/null
+++ b/dev-python/dbus-next/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd";>
+<pkgmetadata>
+ <maintainer type="project">
+ <email>[email protected]</email>
+ <name>Python</name>
+ </maintainer>
+ <upstream>
+ <remote-id type="github">altdesktop/python-dbus-next</remote-id>
+ <remote-id type="pypi">dbus-next</remote-id>
+ </upstream>
+</pkgmetadata>
