commit: c9658e27a32cd3a49da496ee0aedf68aacc5d97a
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun May 22 10:07:11 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun May 22 10:46:21 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c9658e27
dev-python/cherrypy: Use PEP517 build
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/cherrypy/cherrypy-18.6.1-r1.ebuild | 66 +++++++++++++++++++++++++++
1 file changed, 66 insertions(+)
diff --git a/dev-python/cherrypy/cherrypy-18.6.1-r1.ebuild
b/dev-python/cherrypy/cherrypy-18.6.1-r1.ebuild
new file mode 100644
index 000000000000..85965bd7d707
--- /dev/null
+++ b/dev-python/cherrypy/cherrypy-18.6.1-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+MY_PN="CherryPy"
+MY_P=${MY_PN}-${PV}
+DESCRIPTION="CherryPy is a pythonic, object-oriented HTTP framework"
+HOMEPAGE="
+ https://cherrypy.dev/
+ https://github.com/cherrypy/cherrypy/
+ https://pypi.org/project/CherryPy/
+"
+SRC_URI="mirror://pypi/${MY_PN::1}/${MY_PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="ssl test"
+
+RDEPEND="
+ >=dev-python/cheroot-8.2.1[${PYTHON_USEDEP}]
+ >=dev-python/portend-2.1.1[${PYTHON_USEDEP}]
+ dev-python/more-itertools[${PYTHON_USEDEP}]
+ dev-python/zc-lockfile[${PYTHON_USEDEP}]
+ dev-python/jaraco-collections[${PYTHON_USEDEP}]
+ ssl? (
+ dev-python/pyopenssl[${PYTHON_USEDEP}]
+ )
+"
+BDEPEND="
+ dev-python/setuptools_scm[${PYTHON_USEDEP}]
+ test? (
+ dev-python/routes[${PYTHON_USEDEP}]
+ dev-python/simplejson[${PYTHON_USEDEP}]
+ dev-python/objgraph[${PYTHON_USEDEP}]
+ dev-python/path-py[${PYTHON_USEDEP}]
+ dev-python/requests-toolbelt[${PYTHON_USEDEP}]
+ dev-python/pytest-services[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ local PATCHES=(
+ # https://github.com/cherrypy/cherrypy/pull/1946
+ "${FILESDIR}"/${P}-close-files.patch
+ )
+
+ sed -r -e '/(pytest-sugar|pytest-cov)/ d' \
+ -i setup.py || die
+
+ sed -r -e 's:--cov-report[[:space:]]+[[:graph:]]+::g' \
+ -e 's:--cov[[:graph:]]+::g' \
+ -e 's:--doctest[[:graph:]]+::g' \
+ -i pytest.ini || die
+
+ distutils-r1_python_prepare_all
+}
