commit: e4c19a453e1ee804e2824bdcb1fd4fe395cb2cae
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 12 15:34:12 2022 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Jun 12 15:34:12 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e4c19a45
sci-geosciences/routino: fix distutils-r1 usage
Signed-off-by: Sam James <sam <AT> gentoo.org>
sci-geosciences/routino/routino-3.3.3-r2.ebuild | 88 +++++++++++++++++++++++++
1 file changed, 88 insertions(+)
diff --git a/sci-geosciences/routino/routino-3.3.3-r2.ebuild
b/sci-geosciences/routino/routino-3.3.3-r2.ebuild
new file mode 100644
index 000000000000..1393713d8bf8
--- /dev/null
+++ b/sci-geosciences/routino/routino-3.3.3-r2.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{8..10} )
+inherit toolchain-funcs distutils-r1
+
+DESCRIPTION="Routing application based on openstreetmap data"
+HOMEPAGE="https://routino.org/";
+SRC_URI="https://routino.org/download/${P}.tgz";
+
+LICENSE="AGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="python test"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+ python? (
+ ${PYTHON_DEPS}
+ dev-lang/swig[pcre]
+ )
+"
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+
+PATCHES=( "${FILESDIR}"/${PN}-3.3.2.patch )
+
+src_prepare() {
+ default
+
+ sed -i -e "s@libdir=\(.*\)@libdir=\$(prefix)/$(get_libdir)@" \
+ -e "s@CC=gcc@CC=$(tc-getCC)@" \
+ -e "s@LD=gcc@LD=$(tc-getCC)@" \
+ Makefile.conf || die "failed sed"
+}
+
+src_compile() {
+ emake -j1
+
+ rm README.txt || die "rm README.txt failed"
+ mv doc/README.txt . || die "mv doc/README.txt . failed"
+
+ if use python; then
+ pushd python > /dev/null || die
+ distutils-r1_src_compile
+ popd > /dev/null || die
+ fi
+}
+
+python_compile() {
+ rm -f build/.timestamp || die
+ emake PYTHON=${EPYTHON}
+}
+
+src_test() {
+ emake test
+
+ # Need to fix import issues with these
+ #if use python; then
+ # pushd python > /dev/null || die
+ # distutils-r1_src_test
+ # popd > /dev/null || die
+ #fi
+}
+
+python_test() {
+ emake PYTHON=${EPYTHON} test
+}
+
+src_install() {
+ default
+
+ if use python; then
+ pushd python > /dev/null || die
+ distutils-r1_src_install
+ newdoc README.txt README_python.txt
+ popd > /dev/null || die
+ fi
+}
+
+python_install() {
+ esetup.py install
+ python_optimize
+}
