commit: 4948b991ef0f4865db6f770b06abb2419339ed5a
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 21 17:32:30 2022 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Tue Jun 21 17:32:39 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4948b991
dev-python/dns-lexicon: add 3.11.3
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
dev-python/dns-lexicon/Manifest | 1 +
dev-python/dns-lexicon/dns-lexicon-3.11.3.ebuild | 67 ++++++++++++++++++++++++
2 files changed, 68 insertions(+)
diff --git a/dev-python/dns-lexicon/Manifest b/dev-python/dns-lexicon/Manifest
index 16c1de0ff4ee..bce796690d34 100644
--- a/dev-python/dns-lexicon/Manifest
+++ b/dev-python/dns-lexicon/Manifest
@@ -1 +1,2 @@
DIST dns-lexicon-3.11.2.tar.gz 8479426 BLAKE2B
aced03c62f809bbb22d2456da8d7a66c4b3cdfd47903a67cafd8a97cbc7cdbbe22fe7e79ad3eada716a569241def4e42cf7d910ba9837dfe05a31ce3f8ed2bdb
SHA512
bf77cee4e483b36c8cc8cb176291f0170a1d611551246e27ddd91d9712e8750c9ee57863697e975065f6924c03fdfd636c5c7df29a620d37441b12dd0a1c597d
+DIST dns-lexicon-3.11.3.gh.tar.gz 8442678 BLAKE2B
3898e572b409f19c6c3064046adbbbbfefe0ef287caceb2495972c946bdab0b4bb484330e3ae98afdc8d65cc849c11ed199e6c1eeeeb1296f09063124c166b91
SHA512
770a3c052ecc26fb3a27ac49b8f14132b69ea6ca9dfc93caea1ac66c4e6a458e6484b8a8ab921eea97761216fa34d8ad0d95964cdcff30a5713de7189c1e987d
diff --git a/dev-python/dns-lexicon/dns-lexicon-3.11.3.ebuild
b/dev-python/dns-lexicon/dns-lexicon-3.11.3.ebuild
new file mode 100644
index 000000000000..c6c99ff85a56
--- /dev/null
+++ b/dev-python/dns-lexicon/dns-lexicon-3.11.3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Manipulate DNS records on various DNS providers in a
standardized/agnostic way"
+HOMEPAGE="
+ https://github.com/AnalogJ/lexicon/
+ https://pypi.org/project/dns-lexicon/
+"
+SRC_URI="
+ https://github.com/AnalogJ/lexicon/archive/v${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/lexicon-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+ dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ >=dev-python/importlib_metadata-4[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/tldextract[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/boto3[${PYTHON_USEDEP}]
+ dev-python/zeep[${PYTHON_USEDEP}]
+ dev-python/vcrpy[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+ # Requires the "localzone" module
+ lexicon/tests/providers/test_localzone.py
+ # Requires the "softlayer" module
+ lexicon/tests/providers/test_softlayer.py
+ # Requires the "transip" module
+ lexicon/tests/providers/test_transip.py
+ # Requires the "oci" module
+ lexicon/tests/providers/test_oci.py
+ # Uses tldextract which needs Internet access to download its database
+ lexicon/tests/providers/test_auto.py
+ # All recordings seem to be broken
+ lexicon/tests/providers/test_namecheap.py
+)
+
+pkg_postinst() {
+ if [[ -z ${REPLACING_VERSIONS} ]]; then
+ optfeature_header \
+ "Install the following packages to enable support for
additional DNS providers:"
+ optfeature Gransy dev-python/zeep
+ optfeature Route53 dev-python/boto3
+ optfeature DDNS dev-python/dnspython
+ fi
+}
