commit: 4d46cbec6d02ae40773352abd6f48e302ee5dea5
Author: John Helmert III <ajak <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 5 21:07:59 2022 +0000
Commit: John Helmert III <ajak <AT> gentoo <DOT> org>
CommitDate: Tue Jul 5 21:08:20 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4d46cbec
net-misc/apt-cacher-ng: add 3.7.4_p1
Signed-off-by: John Helmert III <ajak <AT> gentoo.org>
net-misc/apt-cacher-ng/Manifest | 1 +
.../apt-cacher-ng/apt-cacher-ng-3.7.4_p1.ebuild | 104 +++++++++++++++++++++
2 files changed, 105 insertions(+)
diff --git a/net-misc/apt-cacher-ng/Manifest b/net-misc/apt-cacher-ng/Manifest
index f208121fab43..14a5618b82d6 100644
--- a/net-misc/apt-cacher-ng/Manifest
+++ b/net-misc/apt-cacher-ng/Manifest
@@ -1 +1,2 @@
+DIST apt-cacher-ng-debian-3.7.4-1.tar.gz 524480 BLAKE2B
ebb450af29439910fe35a558ae6f7ea02337bfbbe5a8efcb20a803e779deedd7901358a71b69745a53036fb8db9db3c9112fc09b47055f07dfe225f3df95202d
SHA512
a2aa3218d8cf216cef7177f30bfb90b9961460add2a90823e15952e38d19b0dd527e3cecd029bbf1f10abcfcfd11d406bc9019919d1efccf0d9d69bb7cc1a173
DIST apt-cacher-ng_3.6.3.orig.tar.xz 334620 BLAKE2B
7e77edb966f0732f392a3fb243cda547dca7d4f878e44c6c000491ccb0a3115ad58a553706ef02834d25366b09d24ee6af2dafad76f97cd1978dc5a4d35f3380
SHA512
57d991c71f6d0bb9d43b4645ee7be2fb38ccbf73581206e01b6ca389bd8591d5e9f425350e3aff053527125c95caefe9ab1217dedff812162cf6bd4cdfdef792
diff --git a/net-misc/apt-cacher-ng/apt-cacher-ng-3.7.4_p1.ebuild
b/net-misc/apt-cacher-ng/apt-cacher-ng-3.7.4_p1.ebuild
new file mode 100644
index 000000000000..a80672c370a3
--- /dev/null
+++ b/net-misc/apt-cacher-ng/apt-cacher-ng-3.7.4_p1.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake tmpfiles
+
+MY_PV="${PV/_p/-}"
+MY_P="${PN}-debian-${MY_PV}"
+
+DESCRIPTION="Yet another caching HTTP proxy for Debian/Ubuntu software
packages"
+HOMEPAGE="https://www.unix-ag.uni-kl.de/~bloch/acng/
+ https://packages.qa.debian.org/a/apt-cacher-ng.html";
+SRC_URI="https://salsa.debian.org/blade/${PN}/-/archive/debian/${MY_PV}/${MY_P}.tar.gz";
+
+LICENSE="BSD-4 ZLIB public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc fuse systemd tcpd"
+
+DEPEND="acct-user/apt-cacher-ng
+ acct-group/apt-cacher-ng
+ app-arch/bzip2
+ dev-libs/libevent:=[threads]
+ dev-libs/openssl:0=
+ sys-libs/zlib
+ fuse? ( sys-fs/fuse:0 )
+ systemd? ( sys-apps/systemd )
+ tcpd? ( sys-apps/tcp-wrappers )"
+BDEPEND="virtual/pkgconfig"
+RDEPEND="${DEPEND}
+ dev-lang/perl"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-3.3.1-flags.patch"
+ "${FILESDIR}/${PN}-3.5-perl-syntax.patch"
+ "${FILESDIR}/${PN}-3.6-optional-systemd.patch"
+)
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+ # Fixup systemd/CMakeLists.txt cmake version requirement
+ sed -ie "s/2.6/3.1/" systemd/CMakeLists.txt || die
+
+ # Make sure we install everything the same way it used to be after
+ # switching from mostly custom src_install to relying on build system
+ # installation
+ sed -e "/install/s/LIBDIR/CFGDIR/" \
+ -e "/install.*acng\.conf/s/)$/ RENAME ${PN}.conf)/" \
+ -e "/file/s/)$/ \"*hooks\" \"backends_debian\")/" -i
conf/CMakeLists.txt || die
+ sed -ie "/INSTALL.*acngtool/s/LIBDIR/CMAKE_INSTALL_SBINDIR/"
src/CMakeLists.txt || die
+
+ cmake_src_prepare
+}
+
+src_configure() {
+ local mycmakeargs=(
+ "-DHAVE_FUSE_25=$(usex fuse)"
+ "-DHAVE_LIBWRAP=$(usex tcpd)"
+ "-DSDINSTALL=$(usex systemd)"
+ )
+
+ cmake_src_configure
+
+ sed -ie '/LogDir/s|/var/tmp|/var/log/'"${PN}"'|g'
"${BUILD_DIR}"/conf/acng.conf || die
+}
+
+src_install() {
+ # README is a symlink to doc/README and README automatically gets
+ # installed, leading to a broken symlink installed. Fix this by removing
+ # the symlink then installing the actual README.
https://bugs.gentoo.org/770046
+ rm README || die
+ dodoc doc/README
+
+ newinitd "${FILESDIR}/initd-r3" "${PN}"
+ newconfd "${FILESDIR}/confd-r2" "${PN}"
+
+ insinto /etc/logrotate.d
+ newins "${FILESDIR}/logrotate" "${PN}"
+
+ insinto /etc/cron.daily
+ newins "${FILESDIR}/cron.daily" "${PN}"
+
+ # USE=fuse installs acngfs, don't install manpage without the bin
+ if use !fuse; then
+ rm doc/man/acngfs.8 || die
+ fi
+
+ if use !doc; then
+ rm -r doc/html || die
+ fi
+
+ dosbin scripts/expire-caller.pl
+
+ keepdir "/var/log/${PN}"
+ fowners -R ${PN}:${PN} "/var/log/${PN}"
+
+ cmake_src_install
+}
+
+pkg_postinst() {
+ tmpfiles_process "${PN}.conf"
+}
