commit: 63ebb48db2f9e9dfaed563ff92889dcc7a167c75
Author: Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 10 11:56:53 2022 +0000
Commit: Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Wed Aug 10 13:37:11 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=63ebb48d
app-admin/rsyslog: bump to 8.2208.0
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>
app-admin/rsyslog/Manifest | 2 +
app-admin/rsyslog/rsyslog-8.2208.0.ebuild | 492 ++++++++++++++++++++++++++++++
2 files changed, 494 insertions(+)
diff --git a/app-admin/rsyslog/Manifest b/app-admin/rsyslog/Manifest
index 666b7c3b07aa..537ba6373311 100644
--- a/app-admin/rsyslog/Manifest
+++ b/app-admin/rsyslog/Manifest
@@ -5,6 +5,7 @@ DIST rsyslog-8.2110.0.tar.gz 3217225 BLAKE2B
df239609b7a5e08d2a5b1ab5823d45868ac
DIST rsyslog-8.2112.0.tar.gz 3230105 BLAKE2B
deee27f0b1e2b9783bef4d90e396c92c772465156ae8242172548794d628edb5d1e9a95d9ee2aeb2b301ec4b691572391ea7db7b1e8fdb1d14c65e3857857799
SHA512
32ee475d4ef34a68aa43997a97472d21f45c27052c528c1904786df608977189a53e8bb88f310dc2ebe3bf11857824e4e2188c5b85591a005b6977f90a6b17c3
DIST rsyslog-8.2204.0.tar.gz 3242825 BLAKE2B
1e7a75f151053c28bf8e1215f8f1da58ee2232127b4edae6c1a59ff236b2ff0aea57fb175bcdde9a3bd3ce516015422a2eda1f857fdeb56489555de27cf2deda
SHA512
d26ab950788b8931b895719f7d8a42509f709b69a76e4188df16f72be050863ee402310ad9300840fed4ac089638497725d67433172778be7b2932fa82210472
DIST rsyslog-8.2206.0.tar.gz 3246829 BLAKE2B
cfe88f12821146011914610e33cb907bd96f19b6e67c0eb3f9bd88b749eebd3a91ae27e445688842a806719cfe9757778d3f9705cd2d6a497d358015c9ddf36b
SHA512
000d2a05ef4823879e615a347f62f76d3af7d43cddb119e7f57a8470aade00139475368579385ba008a1d5979082128ef6148e0fac2478f6e0ccb26e68d317b7
+DIST rsyslog-8.2208.0.tar.gz 3262298 BLAKE2B
c13920c755a24d8060335f3281a349d2f32c3c99de7351991e09e62302f6d9f61f4390b7945e30816c7d28afe5f757f6a49b2855e40e3f2f518a423662196b1b
SHA512
e63f2465011722eb1bc99676ef6afd66e655af4fb9d751b3d8776499d054c422b195c65fef9ea6b9012d9fb334b7ed8a1c918167fecff389cbb79aa6b74acb73
DIST rsyslog-doc-8.2102.0.tar.gz 6419104 BLAKE2B
134c7ccde6f7435b35840fa37f5774223ac1ebd7dc10db961900a7b1600483156518433c7f70d0981e96ea750e1916ab53e346abacf58066bf141e85c719ae00
SHA512
a5dc4fb9bd8892fac693c5692b926c8d7d9fa36667d6b4c6eccba750713af88d4317f6232efc2a16de38c2e58c4a8bc4d04c9ebb2e7ebc3b0878d53eef20dd2e
DIST rsyslog-doc-8.2106.0.tar.gz 6500747 BLAKE2B
d004af40dfc82577fe262993b10497cbf50142295ccfc046126e0d8cc85dd964cca7798732d2f41ef9d776096b3ec99a8c835bb037a78c9030ea6cd596d1e057
SHA512
04c205ea463f7487baedf60d0469f3752edfb60a0833954a3f208d52ed6495152c785a4a8ea47396ac85b581ced0657f7b51d313c2d4295e26d547b996ff4ca3
DIST rsyslog-doc-8.2108.0.tar.gz 6527584 BLAKE2B
b7974d2f723603017f1c725f820e03f355af1805d77143e6ff9eeb02e54a991ba4c143fc45b48b3e1625328e68113df36d71abd0763983a8db655081c5d81abc
SHA512
d4ca8c91cbdd7be458083ffec9d933e5d1e175dff93fdf9274f5ca444c9cfe8710349c16de6edfd3e12cf97fc889a9e71059ef1d0b85fda4ed335fb107b98a9f
@@ -12,3 +13,4 @@ DIST rsyslog-doc-8.2110.0.tar.gz 6533014 BLAKE2B
16670903ddbbc14ef5ebc726964d1fa
DIST rsyslog-doc-8.2112.0.tar.gz 6545985 BLAKE2B
4f6cfbbf8062a70faa67dd7168ad35bcbe2c81f80560ddb48229a332ce8ac861efe3bdaa1baeddbdd086c3e9ac8912746ba58bc64ab62f3caba8b8cc1b0014fd
SHA512
8588d5fd1a79fce785db85ba162ed2fa9e5375590ee8e6d8569e75334d36683a1b977e930c096a6b3dac15596c066b46fc3105fcc5e8232ab11cf43c6eed3a55
DIST rsyslog-doc-8.2204.0.tar.gz 6553264 BLAKE2B
b4691a6bba44ec37bf310c4f7b307f85bc5d30954296ad62f77ff0f5041badf5fc40fc5680b940f6f3929da8956928dea890f7f2547f7db5e1e4141ef0855b48
SHA512
361528b95c1f02cdc2b2ca8ba5252c8215996e81ef1602e08c46be4e1fd8c1c287dd7d52ae9b2b58c0ec7fe38d7079a89e10642ac3f34fe0b6c5737968999fb4
DIST rsyslog-doc-8.2206.0.tar.gz 6553532 BLAKE2B
51288f5e819393ad6b5af1acfa030b262c1a97c9cc791606c16792201eb8f7bbc9750bb004e7592a99fa1261b971911a6c2bbe6c0b82a6c3bb067b077ce22641
SHA512
23d686241bb6422146602420e21a53208ff82f39f76258d7147dc0b5c06863f8229e1e2df06bfcae63408d06e70b68f7a0b0d216671b78302527d436091a698a
+DIST rsyslog-doc-8.2208.0.tar.gz 6563848 BLAKE2B
ec68684f1d7d895833f656ba6224a8013213a12b1bc7a28a268f2f629c25a3fbac7c379091f17eae24b6d71278c087e4a4cbed1656554de743fe5616a96559bf
SHA512
428c2fe9e5025928d4a9d33f05f4eb20ac1bbde052b7fa2a8a0e45bfffe111eecc94eb2b6ec129de1011f0eabb106b4fb41d402b2a270e4148d3b1081e3b1da0
diff --git a/app-admin/rsyslog/rsyslog-8.2208.0.ebuild
b/app-admin/rsyslog/rsyslog-8.2208.0.ebuild
new file mode 100644
index 000000000000..28fb4cde75da
--- /dev/null
+++ b/app-admin/rsyslog/rsyslog-8.2208.0.ebuild
@@ -0,0 +1,492 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit autotools linux-info python-any-r1 systemd
+
+DESCRIPTION="An enhanced multi-threaded syslogd with database support and more"
+HOMEPAGE="https://www.rsyslog.com/";
+
+if [[ ${PV} == "9999" ]]; then
+ EGIT_REPO_URI="https://github.com/rsyslog/${PN}.git";
+
+ DOC_REPO_URI="https://github.com/rsyslog/${PN}-doc.git";
+
+ inherit git-r3
+else
+ KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~x86"
+
+ SRC_URI="
+ https://www.rsyslog.com/files/download/${PN}/${P}.tar.gz
+ doc? (
https://www.rsyslog.com/files/download/${PN}/${PN}-doc-${PV}.tar.gz )
+ "
+fi
+
+LICENSE="GPL-3 LGPL-3 Apache-2.0"
+SLOT="0"
+
+IUSE="clickhouse curl dbi debug doc elasticsearch +gcrypt gnutls imhttp"
+IUSE+=" impcap jemalloc kafka kerberos kubernetes mdblookup"
+IUSE+=" mongodb mysql normalize omhttp omhttpfs omudpspoof +openssl"
+IUSE+=" postgres rabbitmq redis relp rfc3195 rfc5424hmac snmp +ssl"
+IUSE+=" systemd test usertools +uuid xxhash zeromq"
+
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="
+ kubernetes? ( normalize )
+ ssl? ( || ( gnutls openssl ) )
+"
+
+BDEPEND=">=sys-devel/autoconf-archive-2015.02.24
+ virtual/pkgconfig
+ test? (
+ jemalloc? ( <sys-libs/libfaketime-0.9.7 )
+ !jemalloc? ( sys-libs/libfaketime )
+ ${PYTHON_DEPS}
+ )"
+
+RDEPEND="
+ >=dev-libs/libfastjson-0.99.8:=
+ >=dev-libs/libestr-0.1.9
+ >=sys-libs/zlib-1.2.5
+ curl? ( >=net-misc/curl-7.35.0 )
+ dbi? ( >=dev-db/libdbi-0.8.3 )
+ elasticsearch? ( >=net-misc/curl-7.35.0 )
+ gcrypt? ( >=dev-libs/libgcrypt-1.5.3:= )
+ imhttp? (
+ dev-libs/apr-util
+ www-servers/civetweb
+ virtual/libcrypt:=
+ )
+ impcap? ( net-libs/libpcap )
+ jemalloc? ( >=dev-libs/jemalloc-3.3.1:= )
+ kafka? ( >=dev-libs/librdkafka-0.9.0.99:= )
+ kerberos? ( virtual/krb5 )
+ kubernetes? ( >=net-misc/curl-7.35.0 )
+ mdblookup? ( dev-libs/libmaxminddb:= )
+ mongodb? ( >=dev-libs/mongo-c-driver-1.1.10:= )
+ mysql? ( dev-db/mysql-connector-c:= )
+ normalize? (
+ >=dev-libs/liblognorm-2.0.3:=
+ )
+ clickhouse? ( >=net-misc/curl-7.35.0 )
+ omhttpfs? ( >=net-misc/curl-7.35.0 )
+ omudpspoof? ( >=net-libs/libnet-1.1.6 )
+ postgres? ( >=dev-db/postgresql-8.4.20:= )
+ rabbitmq? ( >=net-libs/rabbitmq-c-0.3.0:= )
+ redis? (
+ >=dev-libs/hiredis-0.11.0:=
+ dev-libs/libevent[threads]
+ )
+ relp? ( >=dev-libs/librelp-1.2.17:= )
+ rfc3195? ( >=dev-libs/liblogging-1.0.1:=[rfc3195] )
+ rfc5424hmac? (
+ >=dev-libs/openssl-0.9.8y:0=
+ )
+ snmp? ( >=net-analyzer/net-snmp-5.7.2 )
+ ssl? (
+ gnutls? ( >=net-libs/gnutls-2.12.23:0= )
+ openssl? (
+ dev-libs/openssl:0=
+ )
+ )
+ systemd? ( >=sys-apps/systemd-234 )
+ uuid? ( sys-apps/util-linux:0= )
+ xxhash? ( dev-libs/xxhash:= )
+ zeromq? (
+ >=net-libs/czmq-4:=[drafts]
+ )"
+
+DEPEND="
+ ${RDEPEND}
+ elibc_musl? ( sys-libs/queue-standalone )
+"
+
+if [[ ${PV} == "9999" ]]; then
+ BDEPEND+=" doc? ( >=dev-python/sphinx-1.1.3-r7 )"
+ BDEPEND+=" >=sys-devel/flex-2.5.39-r1"
+ BDEPEND+=" >=sys-devel/bison-2.4.3"
+ BDEPEND+=" >=dev-python/docutils-0.12"
+fi
+
+CONFIG_CHECK="~INOTIFY_USER"
+WARNING_INOTIFY_USER="CONFIG_INOTIFY_USER isn't set. Imfile module on this
system will only support polling mode!"
+
+pkg_setup() {
+ use test && python-any-r1_pkg_setup
+}
+
+src_unpack() {
+ if [[ ${PV} == "9999" ]]; then
+ git-r3_fetch
+ git-r3_checkout
+ else
+ unpack ${P}.tar.gz
+ fi
+
+ if use doc; then
+ if [[ ${PV} == "9999" ]]; then
+ local _EGIT_BRANCH=
+ if [[ -n "${EGIT_BRANCH}" ]]; then
+ # Cannot use rsyslog commits/branches for
documentation repository
+ _EGIT_BRANCH=${EGIT_BRANCH}
+ unset EGIT_BRANCH
+ fi
+
+ git-r3_fetch "${DOC_REPO_URI}"
+ git-r3_checkout "${DOC_REPO_URI}" "${S}"/docs
+
+ if [[ -n "${_EGIT_BRANCH}" ]]; then
+ # Restore previous EGIT_BRANCH information
+ EGIT_BRANCH=${_EGIT_BRANCH}
+ fi
+ else
+ cd "${S}" || die "Cannot change dir into '${S}'"
+ mkdir docs || die "Failed to create docs directory"
+ cd docs || die "Failed to change dir into '${S}/docs'"
+ unpack ${PN}-doc-${PV}.tar.gz
+ fi
+ fi
+}
+
+src_prepare() {
+ default
+
+ # https://github.com/rsyslog/rsyslog/issues/3626
+ sed -i \
+ -e '\|^#!/bin/bash$|a exit 77' \
+ tests/mmkubernetes-cache-expir*.sh \
+ || die "Failed to disabled known test failure
mmkubernetes-cache-expir*.sh"
+
+ eautoreconf
+}
+
+src_configure() {
+ # Maintainer notes:
+ # * Guardtime support is missing because libgt isn't yet available
+ # in portage.
+ # * Hadoop's HDFS file system output module is currently not
+ # supported in Gentoo because nobody is able to test it
+ # (JAVA dependency).
+ # * dev-libs/hiredis doesn't provide pkg-config (see #504614,
+ # upstream PR 129 and 136) so we need to export HIREDIS_*
+ # variables because rsyslog's build system depends on pkg-config.
+
+ if use redis; then
+ export HIREDIS_LIBS="-L${EPREFIX}/usr/$(get_libdir) -lhiredis"
+ export HIREDIS_CFLAGS="-I${EPREFIX}/usr/include"
+ fi
+
+ local myeconfargs=(
+ --disable-debug-symbols
+ --disable-generate-man-pages
+ --without-valgrind-testbench
+ --disable-liblogging-stdlog
+ --disable-imfile-tests # Some imfile tests fail (noticed in
version 8.2208.0)
+ $(use_enable test testbench)
+ $(use_enable test libfaketime)
+ $(use_enable test extended-tests)
+ # Input Plugins without dependencies
+ --enable-imbatchreport
+ --enable-imdiag
+ --enable-imfile
+ --enable-improg
+ --enable-impstats
+ --enable-imptcp
+ # Message Modificiation Plugins without dependencies
+ --enable-mmanon
+ --enable-mmaudit
+ --enable-mmcount
+ --enable-mmfields
+ --enable-mmjsonparse
+ --enable-mmpstrucdata
+ --enable-mmrm1stspace
+ --enable-mmsequence
+ --enable-mmtaghostname
+ --enable-mmutf8fix
+ # Output Modification Plugins without dependencies
+ --enable-mail
+ --enable-omprog
+ --enable-omruleset
+ --enable-omstdout
+ --enable-omuxsock
+ # Misc
+ --enable-fmhash
+ --enable-fmunflatten
+ $(use_enable xxhash fmhash-xxhash)
+ --enable-pmaixforwardedfrom
+ --enable-pmciscoios
+ --enable-pmcisconames
+ --enable-pmdb2diag
+ --enable-pmlastmsg
+ $(use_enable normalize pmnormalize)
+ --enable-pmnull
+ --enable-pmpanngfw
+ --enable-pmsnare
+ # DB
+ $(use_enable dbi libdbi)
+ $(use_enable mongodb ommongodb)
+ $(use_enable mysql)
+ $(use_enable postgres pgsql)
+ $(use_enable redis imhiredis)
+ $(use_enable redis omhiredis)
+ # Debug
+ $(use_enable debug)
+ $(use_enable debug diagtools)
+ $(use_enable debug valgrind)
+ # Misc
+ $(use_enable clickhouse)
+ $(use_enable curl fmhttp)
+ $(use_enable elasticsearch)
+ $(use_enable gcrypt libgcrypt)
+ $(use_enable imhttp)
+ $(use_enable impcap)
+ $(use_enable jemalloc)
+ $(use_enable kafka imkafka)
+ $(use_enable kafka omkafka)
+ $(use_enable kerberos gssapi-krb5)
+ $(use_enable kubernetes mmkubernetes)
+ $(use_enable normalize mmnormalize)
+ $(use_enable mdblookup mmdblookup)
+ $(use_enable omhttp)
+ $(use_enable omhttpfs)
+ $(use_enable omudpspoof)
+ $(use_enable rabbitmq omrabbitmq)
+ $(use_enable relp)
+ $(use_enable rfc3195)
+ $(use_enable rfc5424hmac mmrfc5424addhmac)
+ $(use_enable snmp)
+ $(use_enable snmp mmsnmptrapd)
+ $(use_enable gnutls)
+ $(use_enable openssl)
+ $(use_enable systemd imjournal)
+ $(use_enable systemd omjournal)
+ $(use_enable usertools)
+ $(use_enable uuid)
+ $(use_enable zeromq imczmq)
+ $(use_enable zeromq omczmq)
+ --with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+ )
+
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ default
+
+ if use doc && [[ "${PV}" == "9999" ]]; then
+ einfo "Building documentation ..."
+ local doc_dir="${S}/docs"
+ cd "${doc_dir}" || die "Cannot chdir into \"${doc_dir}\"!"
+ sphinx-build -b html source build || die "Building
documentation failed!"
+ fi
+}
+
+src_test() {
+ local _has_increased_ulimit=
+
+ # Sometimes tests aren't executable (i.e. when added via patch)
+ einfo "Adjusting permissions of test scripts ..."
+ find "${S}"/tests -type f -name '*.sh' \! -perm -111 -exec chmod a+x
'{}' \; || \
+ die "Failed to adjust test scripts permission"
+
+ if ulimit -n 3072; then
+ _has_increased_ulimit="true"
+ fi
+
+ if ! emake --jobs 1 check; then
+ eerror "Test suite failed! :("
+
+ if [[ -z "${_has_increased_ulimit}" ]]; then
+ eerror "Probably because open file limit couldn't be
set to 3072."
+ fi
+
+ if has userpriv ${FEATURES}; then
+ eerror "Please try to reproduce the test suite failure
with FEATURES=-userpriv " \
+ "before you submit a bug report."
+ fi
+
+ fi
+}
+
+src_install() {
+ local DOCS=(
+ AUTHORS
+ ChangeLog
+ "${FILESDIR}"/README.gentoo
+ )
+
+ use doc && local HTML_DOCS=( "${S}/docs/build/." )
+
+ default
+
+ newconfd "${FILESDIR}/${PN}.confd-r1" ${PN}
+ newinitd "${FILESDIR}/${PN}.initd-r1" ${PN}
+
+ systemd_newunit "${FILESDIR}/${PN}.service" ${PN}.service
+
+ keepdir /var/empty/dev
+ keepdir /var/spool/${PN}
+ keepdir /etc/ssl/${PN}
+ keepdir /etc/${PN}.d
+
+ insinto /etc
+ newins "${FILESDIR}/${PN}.conf" ${PN}.conf
+
+ insinto /etc/rsyslog.d/
+ newins "${FILESDIR}/50-default-r1.conf" 50-default.conf
+
+ insinto /etc/logrotate.d/
+ newins "${FILESDIR}/${PN}-r1.logrotate" ${PN}
+
+ if use mysql; then
+ insinto /usr/share/${PN}/scripts/mysql
+ doins plugins/ommysql/createDB.sql
+ fi
+
+ if use postgres; then
+ insinto /usr/share/${PN}/scripts/pgsql
+ doins plugins/ompgsql/createDB.sql
+ fi
+
+ find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+ local advertise_readme=0
+
+ if [[ -z "${REPLACING_VERSIONS}" ]]; then
+ # This is a new installation
+
+ advertise_readme=1
+
+ if use mysql || use postgres; then
+ echo
+ elog "Sample SQL scripts for MySQL & PostgreSQL have
been installed to:"
+ elog " /usr/share/doc/${PF}/scripts"
+ fi
+
+ if use ssl; then
+ echo
+ elog "To create a default CA and certificates for your
server and clients, run:"
+ elog " emerge --config =${PF}"
+ elog "on your logging server. You can run it several
times,"
+ elog "once for each logging client. The client
certificates will be signed"
+ elog "using the CA certificate generated during the
first run."
+ fi
+ fi
+
+ if [[ ${advertise_readme} -gt 0 ]]; then
+ # We need to show the README file location
+
+ echo ""
+ elog "Please read"
+ elog ""
+ elog " ${EPREFIX}/usr/share/doc/${PF}/README.gentoo*"
+ elog ""
+ elog "for more details."
+ fi
+}
+
+pkg_config() {
+ if ! use ssl; then
+ einfo "There is nothing to configure for rsyslog unless you"
+ einfo "used USE=ssl to build it."
+ return 0
+ fi
+
+ if ! hash certtool &>/dev/null; then
+ die "certtool not found! Is net-libs/gnutls[tools] is
installed?"
+ fi
+
+ # Make sure the certificates directory exists
+ local CERTDIR="${EROOT}/etc/ssl/${PN}"
+ if [[ ! -d "${CERTDIR}" ]]; then
+ mkdir "${CERTDIR}" || die
+ fi
+ einfo "Your certificates will be stored in ${CERTDIR}"
+
+ # Create a default CA if needed
+ if [[ ! -f "${CERTDIR}/${PN}_ca.cert.pem" ]]; then
+ einfo "No CA key and certificate found in ${CERTDIR}, creating
them for you..."
+ certtool --generate-privkey \
+ --outfile "${CERTDIR}/${PN}_ca.privkey.pem" || die
+ chmod 400 "${CERTDIR}/${PN}_ca.privkey.pem"
+
+ cat > "${T}/${PF}.$$" <<- _EOF
+ cn = Portage automated CA
+ ca
+ cert_signing_key
+ expiration_days = 3650
+ _EOF
+
+ certtool --generate-self-signed \
+ --load-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
+ --outfile "${CERTDIR}/${PN}_ca.cert.pem" \
+ --template "${T}/${PF}.$$" || die
+ chmod 400 "${CERTDIR}/${PN}_ca.privkey.pem"
+
+ # Create the server certificate
+ echo
+ einfon "Please type the Common Name of the SERVER you wish to
create a certificate for: "
+ read -r CN
+
+ einfo "Creating private key and certificate for server ${CN}..."
+ certtool --generate-privkey \
+ --outfile "${CERTDIR}/${PN}_${CN}.key.pem" || die
+ chmod 400 "${CERTDIR}/${PN}_${CN}.key.pem"
+
+ cat > "${T}/${PF}.$$" <<- _EOF
+ cn = ${CN}
+ tls_www_server
+ dns_name = ${CN}
+ expiration_days = 3650
+ _EOF
+
+ certtool --generate-certificate \
+ --outfile "${CERTDIR}/${PN}_${CN}.cert.pem" \
+ --load-privkey "${CERTDIR}/${PN}_${CN}.key.pem" \
+ --load-ca-certificate "${CERTDIR}/${PN}_ca.cert.pem" \
+ --load-ca-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
+ --template "${T}/${PF}.$$" &>/dev/null
+ chmod 400 "${CERTDIR}/${PN}_${CN}.cert.pem"
+
+ else
+ einfo "Found existing ${CERTDIR}/${PN}_ca.cert.pem, skipping CA
and SERVER creation."
+ fi
+
+ # Create a client certificate
+ echo
+ einfon "Please type the Common Name of the CLIENT you wish to create a
certificate for: "
+ read -r CN
+
+ einfo "Creating private key and certificate for client ${CN}..."
+ certtool --generate-privkey \
+ --outfile "${CERTDIR}/${PN}_${CN}.key.pem" || die
+ chmod 400 "${CERTDIR}/${PN}_${CN}.key.pem"
+
+ cat > "${T}/${PF}.$$" <<- _EOF
+ cn = ${CN}
+ tls_www_client
+ dns_name = ${CN}
+ expiration_days = 3650
+ _EOF
+
+ certtool --generate-certificate \
+ --outfile "${CERTDIR}/${PN}_${CN}.cert.pem" \
+ --load-privkey "${CERTDIR}/${PN}_${CN}.key.pem" \
+ --load-ca-certificate "${CERTDIR}/${PN}_ca.cert.pem" \
+ --load-ca-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
+ --template "${T}/${PF}.$$" || die
+ chmod 400 "${CERTDIR}/${PN}_${CN}.cert.pem"
+
+ rm -f "${T}/${PF}.$$"
+
+ echo
+ einfo "Here is the documentation on how to encrypt your log traffic:"
+ einfo " https://www.rsyslog.com/doc/rsyslog_tls.html";
+}
