[gentoo-commits] repo/gentoo:master commit in: dev-python/pydantic/

[Michał Górny]

commit:     cc7b0f748e7e811bef7f6136b92c7699a405db56
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 25 07:22:00 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Aug 25 07:40:52 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cc7b0f74

dev-python/pydantic: Bump to 1.10.0_beta1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pydantic/Manifest                     |  1 +
 dev-python/pydantic/metadata.xml                 |  4 +-
 dev-python/pydantic/pydantic-1.10.0_beta1.ebuild | 77 ++++++++++++++++++++++++
 3 files changed, 80 insertions(+), 2 deletions(-)

diff --git a/dev-python/pydantic/Manifest b/dev-python/pydantic/Manifest
index 9b9cba2130e4..c8c0996e9820 100644
--- a/dev-python/pydantic/Manifest
+++ b/dev-python/pydantic/Manifest
@@ -1,2 +1,3 @@
+DIST pydantic-1.10.0b1.gh.tar.gz 886824 BLAKE2B 
f5ae306cf27143723bc2cb87608cdef3eee29ea9e45cde3f61412820858e7b8ab290ba74329317ac916dddb6bd03d011205a1f0d8cd9ba266e4a8655f24b9b61
 SHA512 
6f962e2983bd13bcd79da06d1a663da8c2cae39b7f80184d70e61a23a55661fe79f3bc7d00656f4e14f2aa5746cb889c8463473688dd7572ea825f461e263ec2
 DIST pydantic-1.9.1.tar.gz 306846 BLAKE2B 
c22e892f403b6ca5eff7f888c68f9df5c198fa03c8dab833edc556b3b1a4819fc28c9818a649bf5d9c4bb745b0bde826e164eda7760cd26f88e278c86776ad84
 SHA512 
19d2a50ef054b76cc7e8756759f3d67a14a58614dd6ff1b4f60e73354b0028e08743aa3bb5944da7ae357ab279134d3685c454d6affa6524b267c7cd9a40375e
 DIST pydantic-1.9.2.tar.gz 307957 BLAKE2B 
ee3b188dcf058fc81b5f8491a5e757114a3b39db4d9aee3265051559f6ac25cff01bfb3b0536d0f0425534bd9a5a6444b6e6f2ef84b91a6c11085e15ac25265a
 SHA512 
524595aea9401e82d2e985fdb5aa9b4a8b39edfed856d08e057695c786d65c3455991e4f57ce326902ff9cbed328bcb5e6f4133bda769fecea5affb68f3b4345

diff --git a/dev-python/pydantic/metadata.xml b/dev-python/pydantic/metadata.xml
index 1dd14ba69a2d..322f503dc045 100644
--- a/dev-python/pydantic/metadata.xml
+++ b/dev-python/pydantic/metadata.xml
@@ -7,8 +7,8 @@
        </maintainer>
        <upstream>
                <remote-id type="pypi">pydantic</remote-id>
-               <remote-id type="github">samuelcolvin/pydantic</remote-id>
-               
<bugs-to>https://github.com/samuelcolvin/pydantic/issues</bugs-to>
+               <remote-id type="github">pydantic/pydantic</remote-id>
+               <bugs-to>https://github.com/pydantic/pydantic/issues</bugs-to>
                <doc>https://pydantic-docs.helpmanual.io/</doc>
        </upstream>
 </pkgmetadata>

diff --git a/dev-python/pydantic/pydantic-1.10.0_beta1.ebuild 
b/dev-python/pydantic/pydantic-1.10.0_beta1.ebuild
new file mode 100644
index 000000000000..c666dfdb266a
--- /dev/null
+++ b/dev-python/pydantic/pydantic-1.10.0_beta1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+
+inherit distutils-r1
+
+MY_P=${P/_beta/b}
+DESCRIPTION="Data parsing and validation using Python type hints"
+HOMEPAGE="
+       https://github.com/pydantic/pydantic/
+       https://pypi.org/project/pydantic/
+"
+SRC_URI="
+       https://github.com/pydantic/pydantic/archive/v${PV/_beta/b}.tar.gz
+               -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 
~sparc ~x86"
+
+RDEPEND="
+       >=dev-python/typing-extensions-4.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       dev-python/cython[${PYTHON_USEDEP}]
+       test? (
+               dev-python/hypothesis[${PYTHON_USEDEP}]
+               dev-python/pytest-mock[${PYTHON_USEDEP}]
+               dev-python/python-dotenv[${PYTHON_USEDEP}]
+               >=dev-python/python-email-validator-1.2.1[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+       sed -i -e '/CFLAGS/d' setup.py || die
+       distutils-r1_src_prepare
+}
+
+python_compile() {
+       if [[ ${EPYTHON} == pypy3 ]]; then
+               # do not build extensions on PyPy to workaround
+               # https://github.com/cython/cython/issues/4763
+               local -x SKIP_CYTHON=1
+       fi
+       distutils-r1_python_compile
+}
+
+python_test() {
+       local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+       local -x PYTEST_PLUGINS=pytest_mock
+
+       local EPYTEST_DESELECT=(
+               # flaky test, known upstream
+               
tests/test_hypothesis_plugin.py::test_can_construct_models_with_all_fields
+       )
+       case ${EPYTHON} in
+               pypy3)
+                       EPYTEST_DESELECT+=(
+                               
tests/test_private_attributes.py::test_private_attribute
+                               
tests/test_private_attributes.py::test_private_attribute_annotation
+                               
tests/test_private_attributes.py::test_private_attribute_factory
+                               
tests/test_private_attributes.py::test_private_attribute_multiple_inheritance
+                               
tests/test_private_attributes.py::test_underscore_attrs_are_private
+                       )
+                       ;;
+       esac
+       rm -rf pydantic || die
+       epytest
+}