[gentoo-commits] repo/gentoo:master commit in: dev-util/cvise/

[Michał Górny]

commit:     4fc8181c3538d3f9092462411f1a245bfc436f86
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 30 10:03:31 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Aug 30 10:15:17 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4fc8181c

dev-util/cvise: Bump to 2.5.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-util/cvise/Manifest           |  1 +
 dev-util/cvise/cvise-2.5.0.ebuild | 72 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/dev-util/cvise/Manifest b/dev-util/cvise/Manifest
index 43450ada8961..808d8660d346 100644
--- a/dev-util/cvise/Manifest
+++ b/dev-util/cvise/Manifest
@@ -1 +1,2 @@
 DIST cvise-2.4.0.tar.gz 252810 BLAKE2B 
a95d1645192886d8871dcdf7f9cdfa5a2ac615a3bbc24782c0966d1872fe5f3ade7ddb82afabecfcdebfdac257e2e13e6cb99ab7320baee1a4b43ab360e6a0b2
 SHA512 
073e53039d2b077fed43b948e0c01dc662ef4f75b92d7f49d1786a35c36412fed02e1931c6a39ce902452056fe5c7d70daa35a9cae18b44009778837261cae19
+DIST cvise-2.5.0.tar.gz 255587 BLAKE2B 
ec33bcb0ac45bf89a66bd30b22386f5c0b994e774c1d30f7869e15bcd5bada2e511ad4028628af6c545a23fddde7bc43978fc63cc3b5168db8d038aec9310073
 SHA512 
8433d4daf0e0691b99ff78f4b5331da0d230d5872c214ffd4a7dee470d955c2a3d7541c19277555a6e97108f8cd3de589b3f724e2874c44e479e351777c671c4

diff --git a/dev-util/cvise/cvise-2.5.0.ebuild 
b/dev-util/cvise/cvise-2.5.0.ebuild
new file mode 100644
index 000000000000..05efec46a120
--- /dev/null
+++ b/dev-util/cvise/cvise-2.5.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit cmake llvm python-single-r1
+
+DESCRIPTION="Super-parallel Python port of the C-Reduce"
+HOMEPAGE="https://github.com/marxin/cvise/";
+SRC_URI="
+       https://github.com/marxin/cvise/archive/v${PV}.tar.gz -> ${P}.tar.gz
+"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+LLVM_MAX_SLOT=15
+DEPEND="
+       || (
+               sys-devel/clang:15
+               sys-devel/clang:14
+               sys-devel/clang:13
+       )
+       <sys-devel/clang-$(( LLVM_MAX_SLOT + 1 )):=
+"
+RDEPEND="
+       ${DEPEND}
+       ${PYTHON_DEPS}
+       $(python_gen_cond_dep '
+               dev-python/chardet[${PYTHON_USEDEP}]
+               dev-python/pebble[${PYTHON_USEDEP}]
+               dev-python/psutil[${PYTHON_USEDEP}]
+       ')
+       dev-util/unifdef
+       sys-devel/flex
+"
+BDEPEND="
+       ${PYTHON_DEPS}
+       sys-devel/flex
+       test? (
+               $(python_gen_cond_dep '
+                       dev-python/pebble[${PYTHON_USEDEP}]
+                       dev-python/pytest[${PYTHON_USEDEP}]
+               ')
+       )
+"
+
+llvm_check_deps() {
+       has_version "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+       python-single-r1_pkg_setup
+       llvm_pkg_setup
+}
+
+src_test() {
+       cd "${BUILD_DIR}" || die
+       epytest
+}
+
+src_install() {
+       cmake_src_install
+
+       python_fix_shebang "${ED}"/usr/bin/cvise
+}