[gentoo-commits] repo/gentoo:master commit in: dev-libs/libjcat/

[Marek Szuba]

commit:     bbbb38158eeea02915f2a941dbbd6145eed81e73
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 16 08:05:47 2022 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Fri Sep 16 09:12:38 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bbbb3815

dev-libs/libjcat: add 0.1.12

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 dev-libs/libjcat/Manifest              |  1 +
 dev-libs/libjcat/libjcat-0.1.12.ebuild | 68 ++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/dev-libs/libjcat/Manifest b/dev-libs/libjcat/Manifest
index f624be8488f9..b03b373eae2f 100644
--- a/dev-libs/libjcat/Manifest
+++ b/dev-libs/libjcat/Manifest
@@ -1 +1,2 @@
 DIST libjcat-0.1.11.tar.gz 68455 BLAKE2B 
7414fcff85237a2a95ea50569470a0f35d18e201b351f2a67ca83276b76975983c23b1dc3ee0090e582713d120635bd9c92b43389a7f78529e22bd18ff88dfb9
 SHA512 
02c5cd1e8d7e59a171ee878bd2538858830f0b4f7b27c337db77d84a30f66cae83f1a4832750550c1f5ba31a312837a383e0af489aae476c2f54687cd28064e4
+DIST libjcat-0.1.12.tar.gz 68536 BLAKE2B 
88328645dc38432d7988b87004e450459bebe3159f41074209f18fa9e8d0158025199e6add8b6ee531ac22ac3c87f227524ad741de6ec76ade4b39fd67b0b830
 SHA512 
cf60e86ad97ed786e6e7daefbb17b32d4725f3eab769f7cc480e9085b3a864fd2aad4e1db97b7b5e54352d17b84178631a4224aad3d5bc19cdac204b2fed844a

diff --git a/dev-libs/libjcat/libjcat-0.1.12.ebuild 
b/dev-libs/libjcat/libjcat-0.1.12.ebuild
new file mode 100644
index 000000000000..13c2bc26003e
--- /dev/null
+++ b/dev-libs/libjcat/libjcat-0.1.12.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson python-any-r1 vala xdg-utils
+
+DESCRIPTION="Library and tool for reading and writing Jcat files"
+HOMEPAGE="https://github.com/hughsie/libjcat";
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+gpg gtk-doc +introspection +man +pkcs7 test vala"
+
+RDEPEND="dev-libs/glib:2
+       dev-libs/json-glib:=
+       gpg? (
+               app-crypt/gpgme:=
+               dev-libs/libgpg-error
+       )
+       introspection? ( dev-libs/gobject-introspection:= )
+       pkcs7? ( net-libs/gnutls )
+       vala? ( dev-lang/vala:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+       $(python_gen_any_dep '
+               dev-python/setuptools[${PYTHON_USEDEP}]
+       ')
+       gtk-doc? ( dev-util/gtk-doc )
+       man? ( sys-apps/help2man )
+       test? ( net-libs/gnutls[tools] )"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+       "${FILESDIR}"/${PN}-0.1.11-disable_installed_tests.patch
+)
+
+python_check_deps() {
+       has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+       use vala && vala_setup
+}
+
+src_prepare() {
+       xdg_environment_reset
+       default
+}
+
+src_configure() {
+       local emesonargs=(
+               $(meson_use gtk-doc gtkdoc)
+               $(meson_use gpg)
+               $(meson_use introspection)
+               $(meson_use man)
+               $(meson_use pkcs7)
+               $(meson_use test tests)
+               $(meson_use vala vapi)
+       )
+       meson_src_configure
+}