commit: f45b9efae1d6efa704d28a062d216238aed86cdb
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 5 07:48:27 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Oct 5 09:41:06 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f45b9efa
dev-python/django: Bump to 4.0.8
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/django/Manifest | 2 +
dev-python/django/django-4.0.8.ebuild | 110 ++++++++++++++++++++++++++++++++++
2 files changed, 112 insertions(+)
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 8bfd890d0470..378e43579ca3 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -2,6 +2,8 @@ DIST Django-3.2.15.checksum.txt 2560 BLAKE2B
35a4f28005a07cee0b667ec55838d846cb7
DIST Django-3.2.15.tar.gz 9833828 BLAKE2B
4b914b1e3c192340d9a1bbd68b7d3bf3d1c1b3f41da6e4a67149e811a2312f646e2ced83af23ae035cf590e526dad00537aa5b4aee14a657f6952675eca94b30
SHA512
fccdad52d39c8757972d5e987b94b13d8ce5ce08ad480ef79407b0d9b88cff69336770409cbe18ce9529bf10966ad63105a0b0f1ffe39b681a41be3718ec886b
DIST Django-4.0.7.checksum.txt 2551 BLAKE2B
6fa44707d33af485d3c55096dcc650b4e2384421c57c30cedee9f9577488783836a3ad8261dceaf5c718c1a5fcbe5852b081596525b22639c310c9aa6e86c639
SHA512
4b2453be8090c2a9d48bbe34f6e5dd55859b9debc3a116519c69da39d04ecca202e6da62ae9114790a9da8c55cfcfe176a972bb25576305a8e23736e2e063e3e
DIST Django-4.0.7.tar.gz 10407810 BLAKE2B
77c994d042ace329699aa33e14098cbcd4f24fa4db880dd78ed87828b02c25298a1c1664511547de53eb80ebade7bdfb16412a615027e512ded437ae7de79b54
SHA512
51574ab7423a3948318a5985f74bd781269bf1c95dc77838c11e8f9d5e9233f0a3be5dfa4798d523473b9f1fd3196d4c10284e3a28d9543084b2a63179167731
+DIST Django-4.0.8.checksum.txt 2552 BLAKE2B
af7551bddb966e8e6d338b486c3d2aa5139b28571b77765fe3ca77c0a1a9c310c3286a98fea9d7748c00d1ed7f1afaaa98ef8d78f1a314fda4dd6d2f2b83882f
SHA512
3838fc2369cd8010f06dcfed113106d6b32de3ab4da25580434efc7690c2f73323d60ad2da1b4992ffe6bab1ee8b334533ff7a5653f5a41430df858abe2e93a2
+DIST Django-4.0.8.tar.gz 10427857 BLAKE2B
cbbba3b3044d60fcd6d240e1a181c00d65c1122dc464c86391e39a1eaa866703f41310401f3de291e427eb075dc141fbbc503f414e3627e16715e87f2c10e5c8
SHA512
6357cfc673eb0b993d88b6bed5e43bfea8e0c71d31b141033d06cfe45e91591739ac5c6c57a82cde0216104acb7b21c8c32c1c1bfacad3f62737c8ad10ee175a
DIST Django-4.1.1.checksum.txt 2548 BLAKE2B
aee8b104cf680645aabef0f2a18c029414435093b40eaf8f61dfecda3745b364a64e340136cc35c416708b150074d7fa18d65ab9619ed7e477d94dbfcb3d769c
SHA512
62c542e4f6574ef82563ba8b5389d1408506cc4f48eb3781109d00ddaeb92f93d28536e913c120171bdbe979834baf4c28a14bc934b0540a75d1a5b7dba97d5e
DIST Django-4.1.1.tar.gz 10474304 BLAKE2B
5349e095824db2aadfd8962932916ec2d01fa5f25287cc3b2184d921b9dd6c8d1e52a4648dc8f4cd87da03a261a0406fe7ef521667513a734bd1dae0754ed18f
SHA512
49d0003b1a582cb27163df4bb30eda21d4e3bb101eb5ca0dab3ec1d5b4d99b6481b2edb4fd0e89ba8a06d0266d24ca70c92cd51b9e4c4eab818d68098e8ef4d8
DIST Django-4.1.2.checksum.txt 2552 BLAKE2B
3786a5824ce981fa66e4173b4fe985ccca4084c3bf2a67cce05d527768c54afec69efb2cd79578fff3dfdcf6dcf26536208dc1ae203348e0648a1d2b27373469
SHA512
01bd342832d626efc03f0704b2e7a8287830cf8ccde53b0d8b9d20c10eb10b6d799611e143196f121b43967e72e08a2db032fec81638c3d58e541ccbd598bb1e
diff --git a/dev-python/django/django-4.0.8.ebuild
b/dev-python/django/django-4.0.8.ebuild
new file mode 100644
index 000000000000..4a5d2cef60a3
--- /dev/null
+++ b/dev-python/django/django-4.0.8.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+ https://www.djangoproject.com/
+ https://github.com/django/django/
+ https://pypi.org/project/Django/
+"
+SRC_URI="
+ https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+ verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-python/asgiref-3.4.1[${PYTHON_USEDEP}]
+ >=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/backports-zoneinfo[${PYTHON_USEDEP}]
+ ' 3.8)
+"
+BDEPEND="
+ test? (
+ $(python_gen_impl_dep sqlite)
+ ${RDEPEND}
+ dev-python/docutils[${PYTHON_USEDEP}]
+ dev-python/jinja[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pillow[webp,${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/selenium[${PYTHON_USEDEP}]
+ dev-python/tblib[${PYTHON_USEDEP}]
+ sys-devel/gettext
+ !!<dev-python/ipython-7.21.0-r1
+ !!=dev-python/ipython-7.22.0-r0
+ )
+ verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-4.0-bashcomp.patch
+ "${FILESDIR}"/django-4.0.5-py311.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+ if use verify-sig; then
+ cd "${DISTDIR}" || die
+ verify-sig_verify_signed_checksums \
+ "${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+ cd "${WORKDIR}" || die
+ fi
+
+ default
+}
+
+src_prepare() {
+ # TODO: this suddenly started failing
+ sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die
+
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ # Tests have non-standard assumptions about PYTHONPATH,
+ # and don't work with ${BUILD_DIR}/lib.
+ PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2
||
+ die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+ newbashcomp extras/django_bash_completion ${PN}-admin
+ bashcomp_alias ${PN}-admin django-admin.py
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature_header "Additional Backend support can be enabled via:"
+ optfeature "MySQL backend support" dev-python/mysqlclient
+ optfeature "PostgreSQL backend support" dev-python/psycopg:2
+ optfeature_header
+ optfeature "GEO Django" "sci-libs/gdal[geos]"
+ optfeature "Memcached support" dev-python/pylibmc
dev-python/python-memcached
+ optfeature "ImageField Support" dev-python/pillow
+ optfeature "Password encryption" dev-python/bcrypt
+ optfeature "High-level abstractions for Django forms"
dev-python/django-formtools
+}
