commit: 0f762edc6c87dce5e19bc2ab3c98be1ca125947c
Author: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 11 11:05:06 2022 +0000
Commit: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Tue Oct 11 11:05:23 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0f762edc
games-board/pysolfc: add 2.18.0
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>
games-board/pysolfc/Manifest | 1 +
games-board/pysolfc/pysolfc-2.18.0.ebuild | 68 +++++++++++++++++++++++++++++++
2 files changed, 69 insertions(+)
diff --git a/games-board/pysolfc/Manifest b/games-board/pysolfc/Manifest
index 49bd059d17ae..5823c20e6772 100644
--- a/games-board/pysolfc/Manifest
+++ b/games-board/pysolfc/Manifest
@@ -1,3 +1,4 @@
DIST PySolFC-2.16.0.tar.xz 6391048 BLAKE2B
94f25033cf5b15af002d924cd2bfff5f90a1165ac9c23ba72a204d424e1678d904c37b13f16695f60c26d9e93a0b00f33e3f59d4b5bf4846d2570ed8c19d7725
SHA512
8f327b621d7c964abcf3e64a866e4a0153f4d6c2347f06eda1535df4effec1d7b7391e55c9ff42a1da6764473a246c0d646a589a4aa6b225076f97fd22381acd
+DIST PySolFC-2.18.0.tar.xz 9134632 BLAKE2B
68d777afa058ce73d6888b40e5fef060257f7449e3c1dbf2ec02c4ab35c5917000be3d2ec815e02b2353b793d6a7e010721f498098786f7f172181cda01039a0
SHA512
6e8b46cf3271f8695da6b6fd3090a32839beeed237d35a77f47ad95dfe1690ea471f35e722af65dba9d908f74ace109d1c06d7dd37889962ca0d610c62215397
DIST PySolFC-Cardsets--Minimal-2.1.0.tar.xz 28484652 BLAKE2B
a7537557ce978d296d1a11253a5bfa80a19fc67b495948e35d43d64bcc1283812e753ccf9ee1828461b723e6a21070b3003435f046a590507a7fa6f95bae09c2
SHA512
cc83a26470c2fb13e70741bd8caccb8bd3b0491672eae0caf7437cf38d57e324d225186dde3be49c091d6960dbaefaa23814bcdd7326b07f0f1e32dda15b251c
DIST PySolFC-Cardsets-2.1.tar.bz2 61214563 BLAKE2B
06bf69f22fdcdfbd652bbe75f05722a452609da435a688a04227d235f7a4bd618cb3832e9143d224571eb20c1948014a456d697923623354c81ec12eff365bd9
SHA512
64909dec3d7f0a683e3c0d536f2c3435d0b021b390e411bcd6c9774562483413864105837e57c3210168330f17eda779055a1ec3b52d91aa05f405b990bd6fca
diff --git a/games-board/pysolfc/pysolfc-2.18.0.ebuild
b/games-board/pysolfc/pysolfc-2.18.0.ebuild
new file mode 100644
index 000000000000..d7a6144a6a87
--- /dev/null
+++ b/games-board/pysolfc/pysolfc-2.18.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="tk"
+inherit distutils-r1 xdg
+
+MY_PN="PySolFC"
+MY_P="${MY_PN}-${PV}"
+PS_CARD_P="${MY_PN}-Cardsets-2.1"
+PS_CARD_MIN_P="${MY_PN}-Cardsets--Minimal-2.1.0"
+
+DESCRIPTION="Exciting collection of more than 1000 solitaire card games"
+HOMEPAGE="https://pysolfc.sourceforge.io/";
+SRC_URI="mirror://sourceforge/pysolfc/${MY_P}.tar.xz
+ extra-cardsets? ( mirror://sourceforge/pysolfc/${PS_CARD_P}.tar.bz2 )
+ !extra-cardsets? ( mirror://sourceforge/pysolfc/${PS_CARD_MIN_P}.tar.xz
)"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3+ GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="extra-cardsets minimal +sound"
+
+RDEPEND="
+ $(python_gen_cond_dep '
+ dev-python/attrs[${PYTHON_USEDEP}]
+ dev-python/configobj[${PYTHON_USEDEP}]
+ dev-python/pysol_cards[${PYTHON_USEDEP}]
+ dev-python/random2[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]
+ sound? ( dev-python/pygame[${PYTHON_USEDEP}] )
+ !minimal? ( dev-python/pillow[jpeg,tk,${PYTHON_USEDEP}] )')
+ !minimal? ( dev-tcltk/tktable )"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # make pip check happier, pycotap is not needed
+ sed -i "/'pycotap'/d" setup.py || die
+
+ if use extra-cardsets; then
+ find ../${PS_CARD_P} -type d -name .thumbnails -exec rm -r {} +
|| die
+ fi
+}
+
+python_install_all() {
+ local DOCS=( AUTHORS.md NEWS.asciidoc README.md )
+ distutils-r1_python_install_all
+
+ doman docs/pysol{,fc}.6
+
+ insinto /usr/share/${MY_PN}
+ doins -r ../$(usex extra-cardsets ${PS_CARD_P} ${PS_CARD_MIN_P})/.
+
+ # html files are used at runtime, keep at default location
+ dosym -r /usr/share/{${MY_PN},doc/${PF}}/html
+
+ # russian translation is not currently displaying right
+ # https://forums.gentoo.org/viewtopic-t-1142910.html
+ rm "${ED}"/usr/share/locale/ru/LC_MESSAGES/pysol.mo || die
+}
