[gentoo-commits] repo/gentoo:master commit in: kde-plasma/plasma-firewall/

[Andreas Sturmlechner]

commit:     54681dac428e245e99aaf18072559ff159f68944
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Oct  8 18:15:52 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Oct 11 12:39:53 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=54681dac

kde-plasma/plasma-firewall: add 5.26.0

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/plasma-firewall/Manifest                |  1 +
 .../plasma-firewall/plasma-firewall-5.26.0.ebuild  | 64 ++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/kde-plasma/plasma-firewall/Manifest 
b/kde-plasma/plasma-firewall/Manifest
index ff0aceee8fe9..dc6812f68929 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1 +1,2 @@
 DIST plasma-firewall-5.25.5.tar.xz 357380 BLAKE2B 
37dcd280306a4b7674a78ce8a74f01ea804a136174725d228370427567b851dff6eeed01aaa687014d565c19694908f0f9aba4f811da8c7d8d2208b6d0250581
 SHA512 
b6059e732f34af49263ff0beecb9f11894420166a60ef0ebdce38fff9bb472c1c6d058f4ae6d3cae8194c5b6efe127971e6057564e887317250a4691df73e1e0
+DIST plasma-firewall-5.26.0.tar.xz 358416 BLAKE2B 
eee92edd9cc2e766d5e01991921b35af4edb4d662b7b3c76dd54bbddbeecfb53197d93baa4f12ad8f09e9b1291150efad80153d5fa0f243ccfed82fd6a2caecb
 SHA512 
38078dc4039424f09a879663b8129ba91725bb52e3a599a30618b129d01281c0538bb37995d43e6e00055961700e91d6caa78eadc51ff5262d1e4c19cd047dca

diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.26.0.ebuild 
b/kde-plasma/plasma-firewall/plasma-firewall-5.26.0.ebuild
new file mode 100644
index 000000000000..20e58abb34bd
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.26.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+KFMIN=5.99.0
+QTMIN=5.15.5
+inherit ecm plasma.kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall";
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+       >=dev-qt/qtdbus-${QTMIN}:5
+       >=dev-qt/qtdeclarative-${QTMIN}:5
+       >=dev-qt/qtgui-${QTMIN}:5
+       >=dev-qt/qtnetwork-${QTMIN}:5
+       >=dev-qt/qtx11extras-${QTMIN}:5
+       >=dev-qt/qtxml-${QTMIN}:5
+       >=kde-frameworks/kauth-${KFMIN}:5
+       >=kde-frameworks/kcmutils-${KFMIN}:5
+       >=kde-frameworks/kconfig-${KFMIN}:5
+       >=kde-frameworks/kcoreaddons-${KFMIN}:5
+       >=kde-frameworks/kdeclarative-${KFMIN}:5
+       >=kde-frameworks/ki18n-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+       ${PYTHON_DEPS}
+       firewalld? ( net-firewall/firewalld )
+       ufw? ( net-firewall/ufw )
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
+
+src_prepare() {
+       ecm_src_prepare
+       # this kind of cmake magic doesn't work for us at all.
+       sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+               -i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+               -DBUILD_UFW_BACKEND=$(usex ufw)
+       )
+       ecm_src_configure
+}
+
+pkg_postinst () {
+       ecm_pkg_postinst
+
+       if ! has_version sys-apps/systemd; then
+               ewarn "${PN} is not functional without sys-apps/systemd at this 
point."
+               ewarn "See also: https://bugs.gentoo.org/778527";
+       fi
+}