commit: 30e2f63113a2d140f69c79ca504bfe9d4aca457e
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 15 06:58:11 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Oct 15 08:04:05 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=30e2f631
net-wireless/blueman: Bump to 2.3.4
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
net-wireless/blueman/Manifest | 1 +
net-wireless/blueman/blueman-2.3.4.ebuild | 156 ++++++++++++++++++++++++++++++
2 files changed, 157 insertions(+)
diff --git a/net-wireless/blueman/Manifest b/net-wireless/blueman/Manifest
index 76e149b9bcd4..40025274836b 100644
--- a/net-wireless/blueman/Manifest
+++ b/net-wireless/blueman/Manifest
@@ -1,2 +1,3 @@
DIST blueman-2.3.2.tar.xz 1575412 BLAKE2B
25fbed432e103a46840dc10d73bce4e8e7a5e7ea623dbb3a50c420d166af7eb0eff046d0fd9986869055fbb4c3f8563920fb840f8f74f37a05b6680434f13dc5
SHA512
13760def19951bcb4582dbe142259256826a0f50e6c34e56c61c6f890f4e2e08085733f2480ad4c95ee52ec616cbb7ddd3a946634f042d80692cd37b57207cc0
DIST blueman-2.3.3.tar.xz 1575852 BLAKE2B
618f789b7e411adccb986704922cf2cbe283197878232210a933530c54caf0ca3c21f08c7b2192389451988623280b63dff23c9b56a696970ec4b7f773cb47a3
SHA512
2c2290a5b0fb78eccd35c33ac10c5ef38f01f4074796a62fb3aeded1f5db76104d60bc02968a8144c5dae3ec8fd425d7b33beaf2a81e401a09dd3b550e2d0d2d
+DIST blueman-2.3.4.tar.xz 1575488 BLAKE2B
382bf6c995477b31527c2702bb22c3657fc5b36476cd8dd32fb8e0e78359f8b427aeae781ca7022e58f644a3ca3c67a7e644e8dd16492fb7037d4619489c73fb
SHA512
8bca916567a1d72fd7c539cc200177b20723e38ec55e30358141b4dff6f7b889d5eae689ef61618fdc23ebb4d8bfbbe2d0447d04a58b769c2d898ff017001f76
diff --git a/net-wireless/blueman/blueman-2.3.4.ebuild
b/net-wireless/blueman/blueman-2.3.4.ebuild
new file mode 100644
index 000000000000..62b0322489b5
--- /dev/null
+++ b/net-wireless/blueman/blueman-2.3.4.ebuild
@@ -0,0 +1,156 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=no
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit autotools distutils-r1 gnome2-utils linux-info systemd xdg-utils
+
+DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
+HOMEPAGE="https://github.com/blueman-project/blueman/";
+
+if [[ ${PV} == "9999" ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/blueman-project/blueman.git";
+else
+ SRC_URI="
+
https://github.com/blueman-project/blueman/releases/download/${PV/_/.}/${P/_/.}.tar.xz
+ "
+ S=${WORKDIR}/${P/_/.}
+ KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+# icons are GPL-2
+# source files are mixed GPL-3+ and GPL-2+
+LICENSE="GPL-3+ GPL-2"
+SLOT="0"
+IUSE="network nls policykit pulseaudio"
+
+DEPEND="
+ $(python_gen_cond_dep '
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ ')
+ >=net-wireless/bluez-5:=
+"
+BDEPEND="
+ $(python_gen_cond_dep '
+ dev-python/cython[${PYTHON_USEDEP}]
+ ')
+ virtual/pkgconfig
+ nls? ( sys-devel/gettext )
+"
+RDEPEND="
+ ${DEPEND}
+ $(python_gen_cond_dep '
+ dev-python/pycairo[${PYTHON_USEDEP}]
+ ')
+ sys-apps/dbus
+ x11-libs/gtk+:3[introspection,X]
+ x11-libs/libnotify[introspection]
+ || (
+ x11-themes/adwaita-icon-theme
+ x11-themes/faenza-icon-theme
+ x11-themes/mate-icon-theme
+ )
+ network? (
+ net-firewall/iptables
+ || (
+ sys-apps/net-tools
+ sys-apps/iproute2
+ )
+ || (
+ net-dns/dnsmasq
+ net-misc/dhcp
+ >=net-misc/networkmanager-0.8[introspection]
+ )
+ )
+ policykit? (
+ sys-auth/polkit
+ )
+ pulseaudio? (
+ || (
+ media-sound/pulseaudio-daemon[bluetooth]
+ media-video/pipewire[bluetooth]
+ <media-sound/pulseaudio-15.99.1[bluetooth]
+ media-sound/pulseaudio-modules-bt
+ )
+ )
+"
+
+pkg_pretend() {
+ if use network; then
+ local CONFIG_CHECK="
+ ~BRIDGE
+ ~IP_NF_IPTABLES
+ ~IP_NF_NAT
+ ~IP_NF_TARGET_MASQUERADE
+ "
+ check_extra_config
+ fi
+}
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ if [[ ${PV} == 9999 ]]; then
+ eautoreconf
+ else
+ # remove this when upstream switches to automake with .pyc fix
+ eautomake
+ fi
+ distutils-r1_src_prepare
+}
+
+python_configure() {
+ local myconf=(
+ --disable-runtime-deps-check
+ --disable-static
+ --with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+ --with-systemduserunitdir="$(systemd_get_userunitdir)"
+ --with-dhcp-config="/etc/dhcp/dhcpd.conf"
+ $(use_enable policykit polkit)
+ $(use_enable nls)
+ $(use_enable pulseaudio)
+ # thunar integration is a single data file with no extra deps
+ # so install it unconditionally
+ --enable-thunar-sendto
+ )
+ econf "${myconf[@]}"
+}
+
+python_compile() {
+ default
+}
+
+python_test() {
+ # import tests are not very valuable and fail if /dev/rfkill
+ # does not exist
+ "${EPYTHON}" -m unittest -v test/test_gobject.py || die
+}
+
+python_install() {
+ default
+
+ if use policykit; then
+ # Allow users in plugdev group to modify connections
+ insinto /usr/share/polkit-1/rules.d
+ doins "${FILESDIR}/01-org.blueman.rules"
+ fi
+
+ find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+ xdg_icon_cache_update
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+ gnome2_schemas_update
+}
