commit: 531d91c742daf01ff0bdb82e78ca7e811f380b94
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 9 07:30:40 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Nov 9 08:38:04 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=531d91c7
dev-python/fakeredis: Bump to 1.10.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/fakeredis/Manifest | 1 +
dev-python/fakeredis/fakeredis-1.10.1.ebuild | 87 ++++++++++++++++++++++++++++
2 files changed, 88 insertions(+)
diff --git a/dev-python/fakeredis/Manifest b/dev-python/fakeredis/Manifest
index 001a1a961b8d..eb47e9e52350 100644
--- a/dev-python/fakeredis/Manifest
+++ b/dev-python/fakeredis/Manifest
@@ -1,2 +1,3 @@
DIST fakeredis-py-1.10.0.gh.tar.gz 88305 BLAKE2B
71ffec7f872c8021914e24ee83f250e1e27bf2117fabb3513b54ad635692f43cefaf565090d3829ee189844a83ccc517016d8a4f9c31da82b2188d8d951c4dcf
SHA512
8fb32917c70931de50ef90526854ee7c0d888c04582a284864c19956868961cd689db0a7b3ad39e783f53741efde5a33cc600faf09fdeac7046fe29e9cd75933
+DIST fakeredis-py-1.10.1.gh.tar.gz 91420 BLAKE2B
a88711b5d167aafcf6a74dc538b809a0410c60bff95c82fe81c1236b743d9fc0cacbc9057bcd5df20ed87b22c12b2e9346342e0991556caa51f4e88038fabcb5
SHA512
2a139dde02c00e516959173fbfe5ecae26d20ee56158de9ae7bc57360dabc58e4e919f11ba7979079019d981af8a2cbd17a1d8ac795003e26a7cbcbedd5588a8
DIST fakeredis-py-1.9.4.gh.tar.gz 87232 BLAKE2B
b02b14960071ed38f6144b60d845d31d0d102f4d061dd2f156610f90385f35ff3128ab293fbf24049fd1f18a7558e9e13cc2f7179230a9837313acb2a7121053
SHA512
2fe74c5cc798edeef391136f8b09a651381faa04b7dd1e5a07007e6f89596e45970977b435e6fbdad03b73e9826a439da2e105ca9592fb3733547789d106182e
diff --git a/dev-python/fakeredis/fakeredis-1.10.1.ebuild
b/dev-python/fakeredis/fakeredis-1.10.1.ebuild
new file mode 100644
index 000000000000..a75d02ef0771
--- /dev/null
+++ b/dev-python/fakeredis/fakeredis-1.10.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+
+inherit distutils-r1
+
+MY_P=fakeredis-py-${PV}
+DESCRIPTION="Fake implementation of redis API for testing purposes"
+HOMEPAGE="
+ https://github.com/cunla/fakeredis-py/
+ https://pypi.org/project/fakeredis/
+"
+SRC_URI="
+ https://github.com/cunla/fakeredis-py/archive/v${PV}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+ >=dev-python/redis-py-4.2[${PYTHON_USEDEP}]
+ <dev-python/redis-py-4.5[${PYTHON_USEDEP}]
+ >=dev-python/sortedcontainers-2.4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-db/redis
+ dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ # unpin redis
+ sed -i -e '/redis/s:<[0-9.]*:*:' pyproject.toml || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # also lupa
+ test/test_aioredis2.py::test_failed_script_error
+ # TODO
+ "test/test_fakeredis.py::test_set_get_nx[StrictRedis]"
+ "test/test_fakeredis.py::test_lpop_count[StrictRedis]"
+ "test/test_fakeredis.py::test_rpop_count[StrictRedis]"
+ "test/test_fakeredis.py::test_zadd_minus_zero[StrictRedis]"
+ )
+ local EPYTEST_IGNORE=(
+ # these tests fail a lot...
+ test/test_hypothesis.py
+ )
+ local args=(
+ # tests requiring lupa (lua support)
+ -k 'not test_eval and not test_lua and not test_script'
+ )
+ epytest "${args[@]}"
+}
+
+src_test() {
+ local redis_pid="${T}"/redis.pid
+ local redis_port=6379
+
+ einfo "Spawning Redis"
+ einfo "NOTE: Port ${redis_port} must be free"
+ "${EPREFIX}"/usr/sbin/redis-server - <<- EOF || die "Unable to start
redis server"
+ daemonize yes
+ pidfile ${redis_pid}
+ port ${redis_port}
+ bind 127.0.0.1
+ EOF
+
+ # Run the tests
+ distutils-r1_src_test
+
+ # Clean up afterwards
+ kill "$(<"${redis_pid}")" || die
+}
