[gentoo-commits] repo/gentoo:master commit in: dev-python/pycryptodome/

[Michał Górny]

commit:     2030a2648a5259dd6c349b38f67d3822e179badf
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 27 16:33:43 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Nov 27 16:53:32 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2030a264

dev-python/pycryptodome: Bump to 3.16.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pycryptodome/Manifest                   |  1 +
 dev-python/pycryptodome/pycryptodome-3.16.0.ebuild | 58 ++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-python/pycryptodome/Manifest b/dev-python/pycryptodome/Manifest
index cdc906ff3b58..98b6b1d43c2f 100644
--- a/dev-python/pycryptodome/Manifest
+++ b/dev-python/pycryptodome/Manifest
@@ -1 +1,2 @@
 DIST pycryptodome-3.15.0.gh.tar.gz 16547902 BLAKE2B 
ce1a6eaca4946d656c08f960f67537e61b9c82a69777fcb0b01b91a9a649c605dcc66a2a6d9fdc5533521a669544c7695e83db856dfcf8e4b2ba7301654b5555
 SHA512 
fc611174cfb4ca89fb457cc0d1220326ac813de5a83a959a95c1928a5220dc8c652655ac0a2b7d116b60cb4a8317959d8c2b2f3595e19b9b359a32beb042b58c
+DIST pycryptodome-3.16.0.gh.tar.gz 16548063 BLAKE2B 
4adf1c3027fe593e9a01eb0ea3da1f81ddcedd731a284a3f98dd02f07ba9eaa80e906bbcea1432fe64f08f0857033cfdbe43acd415fb3081718a301fbbb5ca16
 SHA512 
945c5bda213a08ba12a0ace8e4bf76730461f8dfce94fa426a97dfab846234ea06e121b176ae823d0f7da9316de50aafde6507a2f17efec4d4a0629d4d68d870

diff --git a/dev-python/pycryptodome/pycryptodome-3.16.0.ebuild 
b/dev-python/pycryptodome/pycryptodome-3.16.0.ebuild
new file mode 100644
index 000000000000..9aa00023e3d2
--- /dev/null
+++ b/dev-python/pycryptodome/pycryptodome-3.16.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="A self-contained cryptographic library for Python"
+HOMEPAGE="
+       https://www.pycryptodome.org/
+       https://github.com/Legrandin/pycryptodome/
+       https://pypi.org/project/pycryptodome/
+"
+SRC_URI="
+       https://github.com/Legrandin/pycryptodome/archive/v${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD-2 Unlicense"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv 
~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris 
~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+DEPEND="
+       dev-libs/gmp:0=
+       >=dev-libs/libtomcrypt-1.18.2-r1:=
+"
+BDEPEND="
+       virtual/python-cffi[${PYTHON_USEDEP}]
+"
+RDEPEND="
+       ${DEPEND}
+       ${BDEPEND}
+       !dev-python/pycrypto
+"
+
+PATCHES=(
+       "${FILESDIR}/pycryptodome-3.10.1-system-libtomcrypt.patch"
+)
+
+python_prepare_all() {
+       # make sure we're unbundling it correctly
+       rm -r src/libtom || die
+
+       distutils-r1_python_prepare_all
+}
+
+python_test() {
+       local -x PYTHONPATH=${S}/test_vectors:${PYTHONPATH}
+       "${EPYTHON}" - <<-EOF || die
+               import sys
+               from Crypto import SelfTest
+               SelfTest.run(verbosity=2, stream=sys.stdout)
+       EOF
+}