commit: f9c8da5a68d40663af652e601283266644eb3aa5
Author: Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 30 01:58:38 2022 +0000
Commit: Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Wed Nov 30 02:00:01 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f9c8da5a
dev-libs/newt: add 0.52.23
Also drop tcl patch which appears to be unnecessary
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>
dev-libs/newt/Manifest | 1 +
dev-libs/newt/newt-0.52.23.ebuild | 103 ++++++++++++++++++++++++++++++++++++++
2 files changed, 104 insertions(+)
diff --git a/dev-libs/newt/Manifest b/dev-libs/newt/Manifest
index da5523561fab..2aa740bbbda1 100644
--- a/dev-libs/newt/Manifest
+++ b/dev-libs/newt/Manifest
@@ -1,2 +1,3 @@
DIST newt-0.52.21_p20210816.tar.gz 128555 BLAKE2B
97c791d7301b657bec68045f2cd9bbe16eef0b099a6304e2336414837b36492bd794be04d0bbcd9eadc6fcd000ba2563a5ab90be5d61249390a6ea5435091f97
SHA512
06c1d5634d88a6126de5eddd1c4d436639a4d739b100f391638b0429a3941eabcaa0ff7398f498d735ec0af5e88deb14178110ab11bf5301ef661f7953692bc4
DIST newt-0.52.22.tar.gz 128543 BLAKE2B
103ebe43ccd186068ffd468e56698e9f6f90ab5d687a14a27d454cfd68feb4ccd11710b6c472c07905a4aeb915efefd4f3b90c3c7822db7cdd5923c53996b7ae
SHA512
2881340f97afccb8be02b2915a6f1de26de6c1e7c7b97776b8d2c87386e3f3611697a47b7e9b1a043f334d72b6d2bdcb7fd3ff128a7d994fcb437f456873016c
+DIST newt-0.52.23.tar.gz 128884 BLAKE2B
283809ac259475588b2f277e6c14ddc2981204f8d6c4963aa9ca7bf87376d2025e9edcc3194804bd6928f75deef706758e1868ba730fd06856ed0a95e534be00
SHA512
8040b01178311532c31642daae5bffc9c0f1917d28957164a02b3f5bd402e6561ff6faee75a936f72485eb71004238ede78c1973a970451fb5aaccff231887c7
diff --git a/dev-libs/newt/newt-0.52.23.ebuild
b/dev-libs/newt/newt-0.52.23.ebuild
new file mode 100644
index 000000000000..ce783dca0ed0
--- /dev/null
+++ b/dev-libs/newt/newt-0.52.23.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit autotools python-r1 toolchain-funcs
+
+MY_PV="r$(ver_rs 1- -)"
+
+DESCRIPTION="Redhat's Newt windowing toolkit development files"
+HOMEPAGE="https://pagure.io/newt";
+SRC_URI="https://github.com/mlichvar/newt/archive/${MY_PV}.tar.gz ->
${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64
~riscv ~sparc ~x86"
+IUSE="gpm nls tcl"
+RESTRICT="test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+ ${PYTHON_DEPS}
+ >=dev-libs/popt-1.6
+ =sys-libs/slang-2*
+ gpm? ( sys-libs/gpm )
+ tcl? ( >=dev-lang/tcl-8.5:0 )
+ "
+DEPEND="${RDEPEND}"
+BDEPEND="sys-devel/gettext"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-0.52.22-gold.patch
+# "${FILESDIR}"/${PN}-0.52.14-tcl.patch
+ "${FILESDIR}"/${PN}-0.52.21-python-sitedir.patch
+)
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+src_prepare() {
+ sed -i Makefile.in \
+ -e 's|$(SHCFLAGS) -o|$(LDFLAGS) &|g' \
+ -e 's|-g -o|$(CFLAGS) $(LDFLAGS) -o|g' \
+ -e 's|-shared -o|$(CFLAGS) $(LDFLAGS) &|g' \
+ -e 's|instroot|DESTDIR|g' \
+ -e 's| make | $(MAKE) |g' \
+ -e "s| ar | $(tc-getAR) |g" \
+ || die "sed Makefile.in"
+
+ if [[ -n ${LINGUAS} ]]; then
+ local lang langs
+ for lang in ${LINGUAS}; do
+ test -r po/${lang}.po && langs="${langs} ${lang}.po"
+ done
+ sed -i po/Makefile \
+ -e "/^CATALOGS = /cCATALOGS = ${langs}" \
+ || die "sed po/Makefile"
+ fi
+
+ default
+ eautoreconf
+
+ # can't build out-of-source
+ python_copy_sources
+}
+
+src_configure() {
+ configuring() {
+ econf \
+ PYTHONVERS="${PYTHON}" \
+ $(use_with gpm gpm-support) \
+ $(use_with tcl) \
+ $(use_enable nls)
+ }
+ python_foreach_impl run_in_build_dir configuring
+}
+
+src_compile() {
+ building() {
+ emake PYTHONVERS="${EPYTHON}"
+ }
+ python_foreach_impl run_in_build_dir building
+}
+
+src_install() {
+ installit() {
+ emake \
+ DESTDIR="${D}" \
+ PYTHON_SITEDIR="$(python_get_sitedir)" \
+ PYTHONVERS="${EPYTHON}" \
+ install
+ python_optimize
+ }
+ python_foreach_impl run_in_build_dir installit
+ dodoc peanuts.py popcorn.py tutorial.sgml
+ doman whiptail.1
+ einstalldocs
+
+ # don't want static archives
+ rm "${ED}"/usr/$(get_libdir)/libnewt.a || die
+}
