commit: ee54c4a385f5d4bbfedffb9d8ff5a85206d38727
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 28 18:58:00 2022 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Wed Dec 28 19:11:26 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ee54c4a3
dev-python/tox: add 4.0.19
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
dev-python/tox/Manifest | 1 +
dev-python/tox/tox-4.0.19.ebuild | 91 ++++++++++++++++++++++++++++++++++++++++
2 files changed, 92 insertions(+)
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index a86b2bc96599..ee227995b6d7 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -3,3 +3,4 @@ DIST tox-3.28.0.gh.tar.gz 309472 BLAKE2B
9896411426f6aebb3efa468c01696ecc5f17ec3
DIST tox-4.0.16.gh.tar.gz 283676 BLAKE2B
b9b8149dcfa141518cb18a0ac3263c65f4928fc068357d7a513971d7037cc60cb4b3627d61d3e3479622b9fcbdc235356ca97cde993ab47db7abf4755854b17d
SHA512
db4428b576dd3b669969b2390203ba6a0efa85f60073374b32c7ff1273745dde59ef0ffd404a7db98ca9056c5d5b5bd1811b51af7b475c116816c150c4d88c4c
DIST tox-4.0.17.gh.tar.gz 284062 BLAKE2B
65055fd793fa5d4006d0082a89d7f42452cc5b3d1507a87875175db334bf177efeefa8b3e671d9042b795d8f21898ea1b1650cb1337bb9581a3b83ce8b42fec7
SHA512
065f4b91c32902fc8a65b5529e615af428a5ee8f8ad5cebee6c4ba14ceea315844cda8c6d2a882ba34baf7369d5676f210752d89d1cb3f9e2c7d7af790481193
DIST tox-4.0.18.gh.tar.gz 284137 BLAKE2B
b507b0a15664656f381bc06356adb04c5fdfbe52deeef673e4ccc3d7a45d8cec10de80f6fe141a35bf529b020d5d8579c4dd6e4e3aa323bad320c7fcc6c34d18
SHA512
cd10cd4194002644d57fc63295099fccf6ffdaa2eeaf7bfe2f47c85d76dc115f9faa78ce0cfc43603b11ec04abaf4d41fe653fa48bff71e71ab7d102356ec5b8
+DIST tox-4.0.19.gh.tar.gz 284319 BLAKE2B
f0ed3d300e0fadfaa5725589cea91511ed0c37937dc3761b203cfd1f0a5cf4033b6006e693521c932d3af64feb150951c046f5853a8b9bb9e37dcf3c5db4de95
SHA512
27d01b96acf4f7650b5a4a3ad80293ea884ee6791ff2e734cb64c94551943af1fb91804944f7ae82937fe4172522c0d5e4f24e84d35012d11657adc49702fc88
diff --git a/dev-python/tox/tox-4.0.19.ebuild b/dev-python/tox/tox-4.0.19.ebuild
new file mode 100644
index 000000000000..98dc8a8f2545
--- /dev/null
+++ b/dev-python/tox/tox-4.0.19.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+ https://tox.readthedocs.io/
+ https://github.com/tox-dev/tox/
+ https://pypi.org/project/tox/
+"
+SRC_URI="
+ https://github.com/tox-dev/tox/archive/${PV/_}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc"
+
+RDEPEND="
+ >=dev-python/cachetools-5.2[${PYTHON_USEDEP}]
+ >=dev-python/chardet-5.1[${PYTHON_USEDEP}]
+ >=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+ >=dev-python/filelock-3.8.2[${PYTHON_USEDEP}]
+ >=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+ >=dev-python/platformdirs-2.6[${PYTHON_USEDEP}]
+ >=dev-python/pluggy-1[${PYTHON_USEDEP}]
+ >=dev-python/pyproject-api-1.2.1[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+ ' 3.8 3.9 3.10)
+ >=dev-python/virtualenv-20.17.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ >=dev-python/hatch-vcs-0.3[${PYTHON_USEDEP}]
+ test? (
+ dev-python/build[${PYTHON_USEDEP}]
+ >=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+ >=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+ >=dev-python/psutil-5.9.4[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ >=dev-python/pytest-xdist-3.1[${PYTHON_USEDEP}]
+ >=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/time-machine-2.8.2[${PYTHON_USEDEP}]
+ ' 'python*')
+ )
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+ # the minimal bounds in tox are entirely meaningless and new packaging
+ # breaks setuptools
+ sed -i -e '/packaging/s:>=22::' pyproject.toml || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ # devpi_process is not packaged, and has lots of dependencies
+ cat > "${T}"/devpi_process.py <<-EOF || die
+ def IndexServer(*args, **kwargs): raise NotImplementedError()
+ EOF
+
+ local -x PYTHONPATH=${T}:${PYTHONPATH}
+ local EPYTEST_DESELECT=(
+ # Internet
+
tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+ )
+ local EPYTEST_IGNORE=(
+ # requires devpi*
+ tests/test_provision.py
+ )
+ if ! has_version "dev-python/time_machine[${PYTHON_USEDEP}]"; then
+ EPYTEST_IGNORE+=(
+ tests/util/test_spinner.py
+ )
+ fi
+
+ epytest
+}
