[gentoo-commits] repo/gentoo:master commit in: dev-python/platformdirs/

[Michał Górny]

commit:     3426025df58d68d178a707584ef47c18a759cce1
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 16 12:58:01 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jan 16 18:21:38 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3426025d

dev-python/platformdirs: Port to flit_core to resolve bootstrap

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../platformdirs/platformdirs-2.6.2-r1.ebuild      | 53 ++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/dev-python/platformdirs/platformdirs-2.6.2-r1.ebuild 
b/dev-python/platformdirs/platformdirs-2.6.2-r1.ebuild
new file mode 100644
index 000000000000..dbbb346e5305
--- /dev/null
+++ b/dev-python/platformdirs/platformdirs-2.6.2-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A small Python module for determining appropriate 
platform-specific dirs"
+HOMEPAGE="
+       https://pypi.org/project/platformdirs/
+       https://github.com/platformdirs/platformdirs/
+"
+SRC_URI="
+       https://github.com/platformdirs/platformdirs/archive/${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 
~sparc ~x86"
+
+BDEPEND="
+       test? (
+               dev-python/appdirs[${PYTHON_USEDEP}]
+               dev-python/pytest-mock[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_tests pytest
+
+src_configure() {
+       grep -q 'build-backend = "hatchling' pyproject.toml ||
+               die "Upstream changed build-backend, recheck"
+       # write a custom pyproject.toml to ease setuptools bootstrap
+       cat > pyproject.toml <<-EOF || die
+               [build-system]
+               requires = ["flit_core >=3.2,<4"]
+               build-backend = "flit_core.buildapi"
+
+               [project]
+               name = "${PN}"
+               version = "${PV}"
+               description = 'A small Python package for determining 
appropriate platform-specific dirs, e.g. a "user data dir".'
+       EOF
+       # sigh
+       cat > src/platformdirs/version.py <<-EOF || die
+               __version__ = version = '${PV}'
+               __version_tuple__ = version_tuple = (${PV//./, })
+       EOF
+}