commit: ff3bc692dc1cf301df41fda2af7aefbd7aa7fd70
Author: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 2 15:51:59 2023 +0000
Commit: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Feb 2 15:52:52 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff3bc692
media-sound/jack2: add 1.9.22
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>
media-sound/jack2/Manifest | 1 +
media-sound/jack2/jack2-1.9.22.ebuild | 102 ++++++++++++++++++++++++++++++++++
2 files changed, 103 insertions(+)
diff --git a/media-sound/jack2/Manifest b/media-sound/jack2/Manifest
index dcc6789ee295..4be5b0f4194a 100644
--- a/media-sound/jack2/Manifest
+++ b/media-sound/jack2/Manifest
@@ -1 +1,2 @@
DIST jack2-1.9.21.tar.gz 1006157 BLAKE2B
052486300bd17860964115427d4b5755ce7a4e4607bf9eb4e2b94d5b0cc61cf6a6b56d3a3eae9e91a1195a3316dd1f1ec1357275803805957e4b6f7a76424e24
SHA512
0e9ce581fca3c5d9ffb1de22b45cae6d94085c6f92ff3554892e25727baf66a2269f10d338d95d991e8380c4be5e0cc1e1453b9f878c7dc2e8a990f3bd458557
+DIST jack2-1.9.22.tar.gz 933448 BLAKE2B
8c42cb996e132f711ad8b7071d44601e21bfc8fe24802113825b8434abc8734c981daa2b09f10a7ecb1492a51d631255a99649d6d76343622b5e38da07e0c598
SHA512
d93cb2bcc57b72b6815eed143de1092d14fe22542ae9a1f8480d9ed5f44b59c50f81279d18bdd84ff6276ddd71ca1aa64a1e46d61199a5eda0d873a356194ab4
diff --git a/media-sound/jack2/jack2-1.9.22.ebuild
b/media-sound/jack2/jack2-1.9.22.ebuild
new file mode 100644
index 000000000000..8fa6ca5113f5
--- /dev/null
+++ b/media-sound/jack2/jack2-1.9.22.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="threads(+)"
+inherit flag-o-matic python-single-r1 waf-utils multilib-minimal
+
+if [[ ${PV} == 9999 ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/jackaudio/${PN}.git";
+else
+
SRC_URI="https://github.com/jackaudio/jack2/archive/refs/tags/v${PV}.tar.gz ->
${P}.tar.gz"
+ KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Jackdmp jack implemention for multi-processor machine"
+HOMEPAGE="https://jackaudio.org/";
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="2"
+IUSE="+alsa +classic dbus doc ieee1394 libsamplerate metadata opus pam +tools
systemd"
+REQUIRED_USE="
+ ${PYTHON_REQUIRED_USE}
+ || ( classic dbus )"
+
+DEPEND="
+ alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
+ dbus? (
+ dev-libs/expat[${MULTILIB_USEDEP}]
+ sys-apps/dbus[${MULTILIB_USEDEP}]
+ )
+ libsamplerate? ( media-libs/libsamplerate[${MULTILIB_USEDEP}] )
+ ieee1394? ( media-libs/libffado[${MULTILIB_USEDEP}] )
+ metadata? ( sys-libs/db:=[${MULTILIB_USEDEP}] )
+ opus? ( media-libs/opus[custom-modes,${MULTILIB_USEDEP}] )
+ systemd? ( classic? ( sys-apps/systemd:= ) )"
+RDEPEND="
+ ${DEPEND}
+ dbus? (
+ ${PYTHON_DEPS}
+ $(python_gen_cond_dep '
+ dev-python/dbus-python[${PYTHON_USEDEP}]
+ ')
+ )
+ pam? ( sys-auth/realtime-base )
+ !media-sound/jack-audio-connection-kit
+ !media-video/pipewire[jack-sdk(-)]"
+BDEPEND="
+ ${PYTHON_DEPS}
+ virtual/pkgconfig
+ doc? ( app-doc/doxygen )"
+# tools were formerly provided here, pull to maintain expectations
+PDEPEND="tools? ( media-sound/jack-example-tools )"
+
+DOCS=( AUTHORS.rst ChangeLog.rst README.rst README_NETJACK2 )
+
+src_prepare() {
+ default
+
+ python_fix_shebang waf
+ multilib_copy_sources
+}
+
+multilib_src_configure() {
+ # clients crash if built with lto
+ # https://github.com/jackaudio/jack2/issues/485
+ filter-lto
+
+ local wafargs=(
+ --mandir="${EPREFIX}"/usr/share/man/man1 # override eclass' for
man1
+
+ --alsa=$(usex alsa)
+ --celt=no
+ $(usev classic --classic)
+ --db=$(usex metadata)
+ $(usev dbus --dbus)
+ --doxygen=$(multilib_native_usex doc)
+ --firewire=$(usex ieee1394)
+ --iio=no
+ --opus=$(usex opus)
+ --portaudio=no
+ --samplerate=$(usex libsamplerate)
+ --systemd=$(multilib_native_usex systemd $(usex classic))
+ --winmme=no
+ )
+
+ waf-utils_src_configure "${wafargs[@]}"
+}
+
+multilib_src_compile() {
+ waf-utils_src_compile
+}
+
+multilib_src_install() {
+ waf-utils_src_install
+}
+
+multilib_src_install_all() {
+ use dbus && python_fix_shebang "${ED}"/usr/bin/jack_control
+}
