commit: 7448b828be59596f038ca736c0756be0b9ad0f1f
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 4 17:48:53 2023 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Apr 4 19:13:14 2023 +0000
URL: https://gitweb.gentoo.org/proj/kde.git/commit/?id=7448b828
kde-frameworks/purpose: 5.105.0 version bump
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
kde-frameworks/purpose/purpose-5.105.0.ebuild | 69 +++++++++++++++++++++++++++
1 file changed, 69 insertions(+)
diff --git a/kde-frameworks/purpose/purpose-5.105.0.ebuild
b/kde-frameworks/purpose/purpose-5.105.0.ebuild
new file mode 100644
index 0000000000..166c267df1
--- /dev/null
+++ b/kde-frameworks/purpose/purpose-5.105.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_QTHELP="false"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.5
+inherit ecm frameworks.kde.org optfeature xdg-utils
+
+DESCRIPTION="Library for providing abstractions to get the developer's
purposes fulfilled"
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="bluetooth +kaccounts"
+
+# requires running environment
+RESTRICT="test"
+
+DEPEND="
+ >=dev-qt/qtdeclarative-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtnetwork-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ =kde-frameworks/kcoreaddons-${PVCUT}*:5
+ =kde-frameworks/ki18n-${PVCUT}*:5
+ =kde-frameworks/kio-${PVCUT}*:5
+ =kde-frameworks/kirigami-${PVCUT}*:5
+ =kde-frameworks/knotifications-${PVCUT}*:5
+ =kde-frameworks/prison-${PVCUT}*:5
+ kaccounts? (
+ >=kde-apps/kaccounts-integration-19.04.3:5
+ net-libs/accounts-qt
+ )
+"
+RDEPEND="${DEPEND}
+ >=dev-qt/qtquickcontrols-${QTMIN}:5
+ >=dev-qt/qtquickcontrols2-${QTMIN}:5
+ >=kde-frameworks/kdeclarative-${PVCUT}:5
+ bluetooth? ( =kde-frameworks/bluez-qt-${PVCUT}*:5 )
+ kaccounts? ( net-libs/accounts-qml )
+"
+
+src_prepare() {
+ ecm_src_prepare
+
+ use bluetooth ||
+ cmake_run_in src/plugins cmake_comment_add_subdirectory
bluetooth
+}
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake_use_find_package kaccounts KAccounts)
+ )
+
+ ecm_src_configure
+}
+
+pkg_postinst() {
+ if [[ -z "${REPLACING_VERSIONS}" ]]; then
+ optfeature "Send through KDE Connect" kde-misc/kdeconnect
+ fi
+ ecm_pkg_postinst
+ xdg_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+}
