commit: 767b8ab97efa89238425d326f89825e5dfcefc26
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 5 04:29:56 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jun 5 05:06:59 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=767b8ab9
dev-python/autobahn: Bump to 23.6.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/autobahn/Manifest | 1 +
dev-python/autobahn/autobahn-23.6.1.ebuild | 116 +++++++++++++++++++++++++++++
2 files changed, 117 insertions(+)
diff --git a/dev-python/autobahn/Manifest b/dev-python/autobahn/Manifest
index 73afde7a83c4..77aef7d12b0c 100644
--- a/dev-python/autobahn/Manifest
+++ b/dev-python/autobahn/Manifest
@@ -1 +1,2 @@
DIST autobahn-23.1.2.tar.gz 480717 BLAKE2B
cc92dc114ef0931be72fa9bf06cfb5646d8dac7a8da3ed3b8d28c4dad67c47465ba3fb03008b70b81ad36210ee014a148f69e5f13b74ef4993b344f9e6887374
SHA512
cd69d901ad7ec8c5f995ca15d803d1de1985294b48707bc0edabfc37733295c3bf9fd7965f930e8b4fa1c7c12c6e02dcbf2ff169edf464eadc774ae6f9185175
+DIST autobahn-23.6.1.tar.gz 476460 BLAKE2B
ee7cd664ac578f61376936560f65e45a3c46c1fdcb042932a1457f5c66bd6748c882bfe5e20a84bf7feb4bce8fbad720867ff5828fc4904e891c5a1e306313c5
SHA512
d621d747494e66b9ab503519b16ca38046c7e166cd6e7883bcac219c63700ee0795a76d836ea3d8a2b3d983a4937464cbb716ccbcd40f3f54f20f089d25dc803
diff --git a/dev-python/autobahn/autobahn-23.6.1.ebuild
b/dev-python/autobahn/autobahn-23.6.1.ebuild
new file mode 100644
index 000000000000..ee9d53b4652b
--- /dev/null
+++ b/dev-python/autobahn/autobahn-23.6.1.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="WebSocket and WAMP for Twisted and Asyncio"
+HOMEPAGE="
+ https://crossbar.io/autobahn/
+ https://github.com/crossbario/autobahn-python/
+ https://pypi.org/project/autobahn/
+"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~sparc ~x86"
+IUSE="test xbr"
+RESTRICT="!test? ( test )"
+
+# The order of deps is based on their appearance in setup.py
+# All extra deps should be included in test and in optfeature
+RDEPEND="
+ >=dev-python/zope-interface-5.2.0[${PYTHON_USEDEP}]
+ >=dev-python/twisted-20.3.0[${PYTHON_USEDEP}]
+ >=dev-python/attrs-20.3.0[${PYTHON_USEDEP}]
+ >=dev-python/txaio-21.2.1[${PYTHON_USEDEP}]
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ >=dev-python/hyperlink-21.0.0[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ ${RDEPEND}
+ >=dev-python/wsaccel-0.6.3[${PYTHON_USEDEP}]
+ >=dev-python/python-snappy-0.6.0[${PYTHON_USEDEP}]
+ >=dev-python/msgpack-1.0.2[${PYTHON_USEDEP}]
+ >=dev-python/ujson-4.0.2[${PYTHON_USEDEP}]
+ >=dev-python/cbor2-5.2.0[${PYTHON_USEDEP}]
+ >=dev-python/py-ubjson-0.16.1[${PYTHON_USEDEP}]
+ >=dev-python/flatbuffers-22.12.06[${PYTHON_USEDEP}]
+ >=dev-python/pyopenssl-20.0.1[${PYTHON_USEDEP}]
+ >=dev-python/service_identity-18.1.0[${PYTHON_USEDEP}]
+ >=dev-python/pynacl-1.4.0[${PYTHON_USEDEP}]
+ >=dev-python/pytrie-0.4[${PYTHON_USEDEP}]
+ >=dev-python/cffi-1.14.5[${PYTHON_USEDEP}]
+ >=dev-python/argon2-cffi-20.1.0[${PYTHON_USEDEP}]
+ >=dev-python/passlib-1.7.4[${PYTHON_USEDEP}]
+
+ dev-python/pytest[${PYTHON_USEDEP}]
+ dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+ dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+ )
+"
+
+python_prepare_all() {
+ if use xbr ; then
+ eerror "***************"
+ eerror "Required xbr dependencies are incomplete in Gentoo."
+ eerror "So this functionality will not yet work"
+ eerror "Please file a bug if this feature is needed"
+ eerror "***************"
+ else
+ # remove xbr components
+ export AUTOBAHN_STRIP_XBR="True"
+ fi
+
+ # avoid useless rust dependency
+ sed -i -e '/cryptography/s:>=3.4.6::' setup.py || die
+
+ # remove twisted plugin cache regen in setup.py
+ # to fix tinderbox sandbox issue
+ sed -e '/import/s:reactor:__importmustfail__:' \
+ -i setup.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ rm -rf autobahn || die
+
+ einfo "Testing all, cryptosign using twisted"
+ local -x USE_TWISTED=true
+ "${EPYTHON}" -m twisted.trial autobahn || die "Tests failed with
${EPYTHON}"
+ unset USE_TWISTED
+
+ einfo "RE-testing cryptosign and component_aio using asyncio"
+ local -x USE_ASYNCIO=true
+ epytest --pyargs autobahn.wamp.test.test_wamp_{cryptosign,component_aio}
+ unset USE_ASYNCIO
+
+ rm -f twisted/plugins/dropin.cache || die
+}
+
+pkg_postinst() {
+ optfeature "C-based WebSocket acceleration" "dev-python/wsaccel"
+ optfeature "non-standard WebSocket compression support" \
+ "dev-python/python-snappy"
+ optfeature "accelerated WAMP serialization support" \
+ "dev-python/msgpack dev-python/ujson dev-python/cbor2
dev-python/flatbuffers dev-python/py-ubjson"
+ optfeature "TLS transport encryption" \
+ "dev-python/pyopenssl dev-python/pynacl dev-python/pytrie
dev-python/qrcode dev-python/service_identity"
+ optfeature "WAMP-SCRAM authentication" \
+ "dev-python/cffi dev-python/argon2-cffi dev-python/passlib"
+ optfeature "native SIMD acceleration" "dev-python/cffi"
+
+ python_foreach_impl twisted-regen-cache
+}
+
+pkg_postrm() {
+ python_foreach_impl twisted-regen-cache
+}
