[gentoo-commits] repo/gentoo:master commit in: dev-python/pdm-backend/

[Michał Górny]

commit:     58701fcfb21ee4decee18e74c87cff332edb7163
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Jun  8 10:14:02 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Jun  8 10:21:34 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=58701fcf

dev-python/pdm-backend: Bump to 2.1.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pdm-backend/Manifest                 |  1 +
 dev-python/pdm-backend/pdm-backend-2.1.0.ebuild | 71 +++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/dev-python/pdm-backend/Manifest b/dev-python/pdm-backend/Manifest
index 185672dc645f..1ff3f48744ba 100644
--- a/dev-python/pdm-backend/Manifest
+++ b/dev-python/pdm-backend/Manifest
@@ -1 +1,2 @@
 DIST pdm-backend-2.0.7.gh.tar.gz 131573 BLAKE2B 
69750ccada51e09886d39b37fe00f842ccc70d1b7fd301ce2a72601f72e6d8d01ed0eef43ce7d9a6d9094e2c547965e91013dec7e7692479a5c9e2d0b7025c83
 SHA512 
7bfbdd52af739d6b6c85468888b44144fbc4fe542e758b62a09a85d7a503a980a82ef3450ac5c234005bbd7dd399ab7ddbe9b7948820b7ba7e8558c5b0fd9581
+DIST pdm-backend-2.1.0.gh.tar.gz 134050 BLAKE2B 
941795a8e108442d8ab651cee2c87f72d01c55e16634d9028f6e6300576ae7c67eaff90cbd6bcd4e24131ddabe92626583cbaf3af1807fd03490650d85653376
 SHA512 
999940464a467e5a8a6cb232cb8602846461cf7e146256be5f745743e47bfeab7b2b8157dc49ba7b03cff46051d080efe2097c450cfab037e0594ffa5fc3802b

diff --git a/dev-python/pdm-backend/pdm-backend-2.1.0.ebuild 
b/dev-python/pdm-backend/pdm-backend-2.1.0.ebuild
new file mode 100644
index 000000000000..af9e6d47c21b
--- /dev/null
+++ b/dev-python/pdm-backend/pdm-backend-2.1.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+       https://pypi.org/project/pdm-backend/
+       https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+       https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+       >=dev-python/packaging-22.0[${PYTHON_USEDEP}]
+       >=dev-python/pyproject-metadata-0.7.1[${PYTHON_USEDEP}]
+       >=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+
+       $(python_gen_cond_dep '
+               >=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+       ' 3.{9..10})
+       $(python_gen_cond_dep '
+               >=dev-python/importlib-metadata-3.6[${PYTHON_USEDEP}]
+       ' 3.9)
+"
+BDEPEND="
+       ${RDEPEND}
+       test? (
+               dev-python/setuptools[${PYTHON_USEDEP}]
+               dev-vcs/git
+       )
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+       rm -r src/pdm/backend/_vendor || die
+       find -name '*.py' -exec sed \
+               -e 's:from pdm\.backend\._vendor\.:from :' \
+               -e 's:from pdm\.backend\._vendor ::' \
+               -e 's:import pdm\.backend\._vendor\.:import :' \
+               -i {} + || die
+       distutils-r1_src_prepare
+}
+
+src_compile() {
+       # this must not be set during src_test()
+       local -x PDM_BUILD_SCM_VERSION=${PV}
+       distutils-r1_src_compile
+}
+
+src_test() {
+       git config --global user.email "t...@example.com" || die
+       git config --global user.name "Test User" || die
+       distutils-r1_src_test
+}