commit: bdfaf76aa966ad2285c8c226a27daab39e2cc918
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 3 04:10:47 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jul 3 04:10:47 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bdfaf76a
dev-python/trio: Bump to 0.22.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/trio/Manifest | 1 +
dev-python/trio/trio-0.22.1.ebuild | 74 ++++++++++++++++++++++++++++++++++++++
2 files changed, 75 insertions(+)
diff --git a/dev-python/trio/Manifest b/dev-python/trio/Manifest
index 0e67e82819ce..d4f6545d23b0 100644
--- a/dev-python/trio/Manifest
+++ b/dev-python/trio/Manifest
@@ -1,2 +1,3 @@
DIST trio-0.22.0.gh.tar.gz 517482 BLAKE2B
ab1fcb22d8f0ed9c8de831a9384b55ab433811863974cb767cb0ea4eb3a0df7372b5ea2c2d4c2af3ca1d3c8c3144d5546ad8cc68276b17ecb3d20ea1858ba9e0
SHA512
45b813d6cc65f8d49f70cb0ea7f33593fed0cc5989c60ba449f0b38c4759604aa7360cd016758fd364438b92516be549edf1efd583c7f5ee2de8813334f182bc
+DIST trio-0.22.1.gh.tar.gz 536365 BLAKE2B
a2b8b672de5ffed99cb2d93888414526749a836dcb4a5101f6de9358c2e231fec56bd7fd80ff2300489931f8b516265ff0881bbde8721c09eed6f48eabcf2f8c
SHA512
28f3248627dcfa06333ec41f17b7419f1192dd0f041ae56f78582a2a781875805e55981a62a1dc2dba191460a67d03e89f0497bb98ef265a37842aae93488be1
DIST trio-93c1d96a535cca565e1b1ba552cb9c4798b3f852.gh.tar.gz 528405 BLAKE2B
b6db1413259c7aa4aa9055eb8d0d810ca7866e312ed81395c7bd2d69cad56dec9cd1422513ee4018077eca0a3b55b4fe74178d4af3599e8ba8b7ad124d820066
SHA512
e5bdc6f918cac8d8eed5d459cfed368336eec301890bd6b579bdf3b2bca7d78246b5b06fb6259fadba0fef45b782e8b03c85884b96d8a961056f7720cd28b944
diff --git a/dev-python/trio/trio-0.22.1.ebuild
b/dev-python/trio/trio-0.22.1.ebuild
new file mode 100644
index 000000000000..c7b8024a8f70
--- /dev/null
+++ b/dev-python/trio/trio-0.22.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="
+ https://github.com/python-trio/trio/
+ https://pypi.org/project/trio/
+"
+SRC_URI="
+ https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+ >=dev-python/attrs-20.1.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/exceptiongroup-1.0.0_rc9[${PYTHON_USEDEP}]
+ ' 3.{9..10})
+ dev-python/idna[${PYTHON_USEDEP}]
+ dev-python/outcome[${PYTHON_USEDEP}]
+ dev-python/sniffio[${PYTHON_USEDEP}]
+ dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ >=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+ >=dev-python/immutables-0.6[${PYTHON_USEDEP}]
+ dev-python/pyopenssl[${PYTHON_USEDEP}]
+ dev-python/trustme[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+ dev-python/immutables \
+ dev-python/sphinxcontrib-trio \
+ dev-python/sphinx-rtd-theme \
+ dev-python/towncrier
+
+python_test() {
+ local EPYTEST_IGNORE=(
+ # these tests require internet access
+ trio/tests/test_ssl.py
+ trio/tests/test_highlevel_ssl_helpers.py
+ )
+
+ local EPYTEST_DESELECT=(
+ # Times out on slower arches (ia64 in this case)
+ # https://github.com/python-trio/trio/issues/1753
+
trio/tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
+
+ # incompatible ipython version?
+ trio/_core/tests/test_multierror.py::test_ipython_exc_handler
+ )
+ if [[ ${EPYTHON} == python3.12 ]]; then
+ EPYTEST_DESELECT+=(
+
trio/_core/_tests/test_run.py::test_nursery_cancel_doesnt_create_cyclic_garbage
+ )
+ fi
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p trio._tests.pytest_plugin -m "not
redistributors_should_skip"
+}
