commit: ef5da4da2fc575b8b0b54bc342433144c79248a7
Author: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 24 19:54:20 2023 +0000
Commit: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Tue Jul 25 00:01:10 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ef5da4da
dev-python/PyQtWebEngine: enable py3.12, use distutils-r1+PEP517
Also add the missing dependencies on qtnetwork:5 and qtwidgets:5
while revbumping. They technically cannot be missed as they are
pulled by PyQt5[network,widgets], but this is to be proper given
it's directly linked with these.
Note these could be optional (like they are in PyQt6-WebEngine behind
IUSE=+widgets), but not going to bother changing this at this point
unless someone needs this.
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>
.../PyQtWebEngine/PyQtWebEngine-5.15.6-r1.ebuild | 52 ++++++++++++++++++++++
1 file changed, 52 insertions(+)
diff --git a/dev-python/PyQtWebEngine/PyQtWebEngine-5.15.6-r1.ebuild
b/dev-python/PyQtWebEngine/PyQtWebEngine-5.15.6-r1.ebuild
new file mode 100644
index 000000000000..16f5be7a1a78
--- /dev/null
+++ b/dev-python/PyQtWebEngine/PyQtWebEngine-5.15.6-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=sip
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 flag-o-matic multiprocessing pypi qmake-utils
+
+DESCRIPTION="Python bindings for QtWebEngine"
+HOMEPAGE="
+ https://www.riverbankcomputing.com/software/pyqtwebengine/
+ https://pypi.org/project/PyQtWebEngine/
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="debug"
+
+DEPEND="
+
>=dev-python/PyQt5-5.15.5[gui,network,printsupport,ssl,webchannel,widgets,${PYTHON_USEDEP}]
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtwebengine:5[widgets]
+"
+RDEPEND="
+ ${DEPEND}
+ >=dev-python/PyQt5-sip-12.9:=[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ >=dev-python/PyQt-builder-1.10[${PYTHON_USEDEP}]
+ >=dev-python/sip-6.2[${PYTHON_USEDEP}]
+ dev-qt/qtcore:5
+"
+
+python_configure_all() {
+ append-cxxflags ${CPPFLAGS} # respect CPPFLAGS notably for
DISTUTILS_EXT=1
+
+ DISTUTILS_ARGS=(
+ --jobs="$(makeopts_jobs)"
+ --qmake="$(qt5_get_bindir)"/qmake
+ --qmake-setting="$(qt5_get_qmake_args)"
+ --verbose
+ $(usev debug '--debug --qml-debug --tracing')
+ )
+}
