commit: 6b90c1f4ad5b756518fb065c4a525d060a3010af
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 20 16:22:29 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Aug 20 17:41:03 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6b90c1f4
dev-python/fonttools: Bump to 4.42.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/fonttools/Manifest | 1 +
dev-python/fonttools/fonttools-4.42.1.ebuild | 68 ++++++++++++++++++++++++++++
2 files changed, 69 insertions(+)
diff --git a/dev-python/fonttools/Manifest b/dev-python/fonttools/Manifest
index 79c89ddac3d9..1258ab443a59 100644
--- a/dev-python/fonttools/Manifest
+++ b/dev-python/fonttools/Manifest
@@ -1 +1,2 @@
DIST fonttools-4.42.0.gh.tar.gz 3764057 BLAKE2B
ef6340a58d1b8dc0fa87a6514792da76c63ee39fa7c0f420e637bb008ae4d6078722b695625bbba72481bfb47f239cd734288b6f5f89d57fcb1acca1e732f460
SHA512
c5b6963d420dd8bf2bae776880bf23c9e91aeb04f62fb3231cfb0af00008b82a19814138311c2b06cc8df1dbb83c0cd1fc1312a540918a3727407cee81d19116
+DIST fonttools-4.42.1.gh.tar.gz 3767442 BLAKE2B
902eb47cfea3c113cab7e6ccf9a0b768782bd7243690cafdde9c6c76f057bc425fd17b0c1e62a43b0c40c2c26969ead1fc9e842a8dca74f063a29c3333f9250f
SHA512
0bf48873c3fb8389851de44425f7b949b1de4ae7d2f46b5041225890ce3b853351f69b0d22cb647090568947b4f09ccd4450d022fd918d92ddd0dd9325397100
diff --git a/dev-python/fonttools/fonttools-4.42.1.ebuild
b/dev-python/fonttools/fonttools-4.42.1.ebuild
new file mode 100644
index 000000000000..a65b02e28c6a
--- /dev/null
+++ b/dev-python/fonttools/fonttools-4.42.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
+HOMEPAGE="
+ https://github.com/fonttools/fonttools/
+ https://pypi.org/project/fonttools/
+"
+SRC_URI="
+ https://github.com/fonttools/fonttools/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+ >=dev-python/fs-2.4.9[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ dev-python/cython[${PYTHON_USEDEP}]
+ test? (
+ app-arch/brotli[python,${PYTHON_USEDEP}]
+ app-arch/zopfli
+ )
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ # When dev-python/pytest-shutil is installed, we get weird import
errors.
+ # This is due to incomplete nesting in the Tests/ tree:
+ #
+ # Tests/feaLib/__init__.py
+ # Tests/ufoLib/__init__.py
+ # Tests/svgLib/path/__init__.py
+ # Tests/otlLib/__init__.py
+ # Tests/varLib/__init__.py
+ #
+ # This tree requires an __init__.py in Tests/svgLib/ too, bug #701148.
+ touch Tests/svgLib/__init__.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+src_configure() {
+ export FONTTOOLS_WITH_CYTHON=1
+}
+
+src_test() {
+ # virtualx used when matplotlib is installed causing plot module tests
to run
+ virtx distutils-r1_src_test
+}
+
+python_test() {
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest Tests fontTools || die "Tests failed with ${EPYTHON}"
+}
