[gentoo-commits] proj/kde:master commit in: kde-plasma/plasma-welcome/

[Andreas Sturmlechner]

commit:     2596701faf43bb9d1b76650197b6fcd00973d24f
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 24 18:08:06 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Oct 24 18:39:24 2023 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=2596701f

kde-plasma/plasma-welcome: 5.27.9 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../plasma-welcome/plasma-welcome-5.27.9.ebuild    | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/kde-plasma/plasma-welcome/plasma-welcome-5.27.9.ebuild 
b/kde-plasma/plasma-welcome/plasma-welcome-5.27.9.ebuild
new file mode 100644
index 0000000000..e61d70604e
--- /dev/null
+++ b/kde-plasma/plasma-welcome/plasma-welcome-5.27.9.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm plasma.kde.org
+
+DESCRIPTION="A friendly onboarding wizard for Plasma"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="discover +kaccounts telemetry"
+
+DEPEND="
+       >=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+       >=dev-qt/qtgui-${QTMIN}:5
+       >=dev-qt/qtnetwork-${QTMIN}:5
+       >=dev-qt/qtquickcontrols2-${QTMIN}:5
+       >=dev-qt/qtsvg-${QTMIN}:5
+       >=dev-qt/qtwidgets-${QTMIN}:5
+       >=kde-frameworks/kconfig-${KFMIN}:5
+       >=kde-frameworks/kconfigwidgets-${KFMIN}:5
+       >=kde-frameworks/kcoreaddons-${KFMIN}:5
+       >=kde-frameworks/kdbusaddons-${KFMIN}:5
+       >=kde-frameworks/ki18n-${KFMIN}:5
+       >=kde-frameworks/kio-${KFMIN}:5
+       >=kde-frameworks/kirigami-${KFMIN}:5
+       >=kde-frameworks/knewstuff-${KFMIN}:5
+       >=kde-frameworks/knotifications-${KFMIN}:5
+       >=kde-frameworks/kservice-${KFMIN}:5
+       >=kde-frameworks/kwindowsystem-${KFMIN}:5
+       >=kde-frameworks/plasma-${KFMIN}:5
+       kaccounts? ( kde-apps/kaccounts-integration:5 )
+       telemetry? ( dev-libs/kuserfeedback:5 )
+"
+RDEPEND="${DEPEND}
+       discover? ( kde-plasma/discover:5 )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.27.4.1-kaccounts-optional.patch" )
+
+src_prepare() {
+       ecm_src_prepare
+
+       if ! use discover; then
+               sed -e "s:pageStack.push(discover);:// & disabled by 
IUSE=discover:" \
+                       -i src/contents/ui/main.qml || die
+       fi
+}
+
+src_configure() {
+       local mycmakeargs=(
+               $(cmake_use_find_package kaccounts KAccounts)
+               $(cmake_use_find_package telemetry KUserFeedback)
+       )
+       ecm_src_configure
+}