commit: ff8bd2e20b5f5a946a16c9a23978dd7171dfc839
Author: Sergey Torokhov <torokhov-s-a <AT> yandex <DOT> ru>
AuthorDate: Tue Oct 24 21:13:13 2023 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Oct 27 02:30:51 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff8bd2e2
dev-python/graphviz: 0.20.1-r1, fix setup.cfg 'license_file' warning
Signed-off-by: Sergey Torokhov <torokhov-s-a <AT> yandex.ru>
Signed-off-by: Sam James <sam <AT> gentoo.org>
dev-python/graphviz/graphviz-0.20.1-r1.ebuild | 49 +++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
diff --git a/dev-python/graphviz/graphviz-0.20.1-r1.ebuild
b/dev-python/graphviz/graphviz-0.20.1-r1.ebuild
new file mode 100644
index 000000000000..8a9f297fb539
--- /dev/null
+++ b/dev-python/graphviz/graphviz-0.20.1-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Simple Python interface for Graphviz"
+HOMEPAGE="
+ https://graphviz.readthedocs.io/
+ https://github.com/xflr6/graphviz/
+ https://pypi.org/project/graphviz/
+"
+SRC_URI="
+ https://github.com/xflr6/graphviz/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+KEYWORDS="amd64 ~riscv x86 ~amd64-linux ~x86-linux"
+SLOT="0"
+
+RDEPEND="
+ media-gfx/graphviz
+"
+BDEPEND="
+ test? (
+ >=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+ >=dev-python/pytest-mock-1.8[${PYTHON_USEDEP}]
+ media-gfx/graphviz[gts,pdf]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ sed -e 's:license_file:license_files:' \
+ -e 's:--cov --cov-report=term --cov-report=html::' \
+ -i setup.cfg || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ "${EPYTHON}" run-tests.py -vv -ra -l -Wdefault -p no:xdoctest ||
+ die "Tests failed with ${EPYTHON}"
+}
