commit: 6c9ef890b74ee246705b6fc2a9017742ea62d6fe
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 31 17:47:46 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Oct 31 19:12:27 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6c9ef890
dev-python/poetry-core: Bump to 1.8.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/poetry-core/Manifest | 1 +
dev-python/poetry-core/poetry-core-1.8.1.ebuild | 73 +++++++++++++++++++++++++
2 files changed, 74 insertions(+)
diff --git a/dev-python/poetry-core/Manifest b/dev-python/poetry-core/Manifest
index 91bc6c8879e2..4f986d45a023 100644
--- a/dev-python/poetry-core/Manifest
+++ b/dev-python/poetry-core/Manifest
@@ -1 +1,2 @@
DIST poetry-core-1.7.0.gh.tar.gz 459637 BLAKE2B
af42d3e44ccecfa2746fcde1f7c48a4a6376d3391ebd9b660658593c32058bc812460ed1df4999f18c929724c2750a13b8ca44d92791c34cef8544862e8c061a
SHA512
cbad311ed53a4b39b027674e8c76cf8822b0cc33b69eca3d79a31e910111efba5021b156d95f51327dca24d584bd96ec1a8cde23b3912e4ed6ca66b11e1bce9b
+DIST poetry-core-1.8.1.gh.tar.gz 367396 BLAKE2B
0305e4022d91632a5cf68e57df61ee27ff1c7faf53d1be6d63e8f30183af828c5fe8126dbd6326ed7a8b428c107878632c26cc1dc2468161b2b79cfdfa0599f8
SHA512
25b4787f45da88142d8cbdad22a518335a82f24ccdba34112ab0f9be8eb130251211969d9da9422bc89fa3c5990adb4e2cde2e3b6f7a4f57f81c6d2b21cf722f
diff --git a/dev-python/poetry-core/poetry-core-1.8.1.ebuild
b/dev-python/poetry-core/poetry-core-1.8.1.ebuild
new file mode 100644
index 000000000000..f9b96f26200c
--- /dev/null
+++ b/dev-python/poetry-core/poetry-core-1.8.1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( pypy3 python3_{10..12} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+DESCRIPTION="Poetry PEP 517 Build Backend"
+HOMEPAGE="
+ https://github.com/python-poetry/poetry-core/
+ https://pypi.org/project/poetry-core/
+"
+SRC_URI="
+ https://github.com/python-poetry/poetry-core/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+# check inside vendors/pyproject.toml
+# (note that some are indirect deps)
+RDEPEND="
+ >=dev-python/fastjsonschema-2.18.0[${PYTHON_USEDEP}]
+ dev-python/lark[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/tomli[${PYTHON_USEDEP}]
+ ' 3.9 3.10)
+"
+BDEPEND="
+ ${RDEPEND}
+ test? (
+ $(python_gen_cond_dep '
+ dev-python/build[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ dev-python/tomli-w[${PYTHON_USEDEP}]
+ >=dev-python/virtualenv-20.21[${PYTHON_USEDEP}]
+ dev-vcs/git
+ ' "${PYTHON_TESTED[@]}")
+ )
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+ # These "fail" bacause of glob file path resulting from newer versions
+ # in our tree than vendored. But those don't affect anything.
+ tests/masonry/builders/test_sdist.py::test_default_with_excluded_data
+
tests/masonry/builders/test_wheel.py::test_default_src_with_excluded_data
+)
+
+src_prepare() {
+ # remove vendoring of dependencies
+ rm -r src/poetry/core/_vendor || die
+ sed -e '/__vendor_site__/d' -i src/poetry/core/__init__.py || die
+
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ if ! has "${EPYTHON/./_}" "${PYTHON_TESTED[@]}"; then
+ einfo "Skipping tests on ${EPYTHON} (unported deps)"
+ return
+ fi
+
+ epytest
+}
