commit: 073b2326383ab95da4790e4b8fb678452af89285
Author: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Sun Jan 7 20:03:50 2024 +0000
Commit: Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Sun Jan 7 20:05:50 2024 +0000
URL: https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=073b2326
dev-util/find-work: new package, add 0.1.1
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>
dev-util/find-work/Manifest | 1 +
dev-util/find-work/find-work-0.1.1.ebuild | 65 +++++++++++++++++++++++++++++++
dev-util/find-work/metadata.xml | 17 ++++++++
3 files changed, 83 insertions(+)
diff --git a/dev-util/find-work/Manifest b/dev-util/find-work/Manifest
new file mode 100644
index 0000000000..d6adf0550e
--- /dev/null
+++ b/dev-util/find-work/Manifest
@@ -0,0 +1 @@
+DIST find_work-0.1.1.tar.gz 10530 BLAKE2B
51294e6b9e21c72fcd2da77c4ecd0c0cb3614d631b7d4840dbc3d774d83aa910a5b83277c7be2c16adb3f0827b5841e5ad24107ac7a546380d4c056e9a8e275a
SHA512
b0f06689554ec2a8d27da270874c89fc31683c0f211d0bacbbe7fee8482a0115107f21836c7ebdaf13ea297030d0870bc53919a90e68ccf10da615eeb9111c5f
diff --git a/dev-util/find-work/find-work-0.1.1.ebuild
b/dev-util/find-work/find-work-0.1.1.ebuild
new file mode 100644
index 0000000000..5686117f50
--- /dev/null
+++ b/dev-util/find-work/find-work-0.1.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=hatchling
+inherit distutils-r1 pypi shell-completion
+
+DESCRIPTION="Personal advice utility for Gentoo package maintainers"
+HOMEPAGE="
+ https://find-work.sysrq.in/
+ https://pypi.org/project/find-work/
+"
+
+LICENSE="WTFPL"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+ <app-portage/gentoopm-2[${PYTHON_USEDEP}]
+ >=dev-python/aiohttp-3[${PYTHON_USEDEP}]
+ <dev-python/aiohttp-4[${PYTHON_USEDEP}]
+ dev-python/click[${PYTHON_USEDEP}]
+ dev-python/click-aliases[${PYTHON_USEDEP}]
+ >=dev-python/pydantic-2[${PYTHON_USEDEP}]
+ <dev-python/pydantic-3[${PYTHON_USEDEP}]
+ >=dev-python/repology-client-0.0.2[${PYTHON_USEDEP}]
+ <dev-python/repology-client-2[${PYTHON_USEDEP}]
+ dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+ dev-python/insipid-sphinx-theme \
+ dev-python/sphinx-prompt
+
+src_prepare() {
+ distutils-r1_src_prepare
+ mkdir completions || die
+}
+
+python_compile() {
+ distutils-r1_python_compile
+
+ local -x PATH="${BUILD_DIR}/install${EPREFIX}/usr/bin:${PATH}"
+ local -x PYTHONPATH="${BUILD_DIR}/lib:${PYTHONPATH}"
+ emake completions/find-work.{bash,zsh,fish}
+}
+
+src_install() {
+ distutils-r1_src_install
+
+ local mymakeargs=(
+ DESTDIR="${D}"
+ PREFIX="${EPREFIX}"/usr
+
+ BASHCOMPDIR="$(get_bashcompdir)"
+ ZSHCOMPDIR="$(get_zshcompdir)"
+ FISHCOMPDIR="$(get_fishcompdir)"
+ )
+
+ emake "${mymakeargs[@]}" install-data
+}
diff --git a/dev-util/find-work/metadata.xml b/dev-util/find-work/metadata.xml
new file mode 100644
index 0000000000..3817d6d4e2
--- /dev/null
+++ b/dev-util/find-work/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd";>
+<pkgmetadata>
+ <maintainer type="person">
+ <email>[email protected]</email>
+ <name>Anna</name>
+ </maintainer>
+ <upstream>
+ <maintainer>
+ <name>Anna</name>
+ <email>[email protected]</email>
+ </maintainer>
+ <remote-id type="pypi">find-work</remote-id>
+
<bugs-to>https://bugs.sysrq.in/enter_bug.cgi?product=Software&component=find-work</bugs-to>
+
<changelog>https://find-work.sysrq.in/release-notes.html</changelog>
+ </upstream>
+</pkgmetadata>
