[gentoo-commits] repo/gentoo:master commit in: dev-python/oslo-config/

[Michał Górny]

commit:     4d181d6fbde88e7807a9f38b556db9bb5e6c48e3
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 10 17:56:06 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jan 10 21:11:55 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4d181d6f

dev-python/oslo-config: Bump to 9.3.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/oslo-config/Manifest                 |  1 +
 dev-python/oslo-config/oslo-config-9.3.0.ebuild | 58 +++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-python/oslo-config/Manifest b/dev-python/oslo-config/Manifest
index b501381d7c71..3c42c9d062bc 100644
--- a/dev-python/oslo-config/Manifest
+++ b/dev-python/oslo-config/Manifest
@@ -1 +1,2 @@
 DIST oslo.config-9.2.0.tar.gz 161235 BLAKE2B 
186b79bab199db9369dd53952a9c6f54fafe17f950d7b66ed753f173a24726a6dbd06b794c73387f5ea6e77aa54a4d5bd0ef4752a5c564dfeea4e729fdf151e7
 SHA512 
69d8461f4ed5d4988fe527e4022c528244e9ecf76913a7af572e8073c0218987a69e6094edc56ff14eaf1b05fc5ffe7d81bb26ff17f87e4bd29a78d7959a3935
+DIST oslo.config-9.3.0.tar.gz 161132 BLAKE2B 
4971a9974f68db25080a70160636bf9c81effb8a817598d4c09aa2337fe69e9bdac4d2b19948d17f225bfcb20bbc65e1ddeb6a24e51792a8246033b5290e3fe1
 SHA512 
5472c44839724b11a1b4b31113c36716ce2c3dbb5e6500cb743cbfb7c73dc6ef878b4219b17d3178d7d8c2b7a46377a2d083cb21768dc82878078d3faed74514

diff --git a/dev-python/oslo-config/oslo-config-9.3.0.ebuild 
b/dev-python/oslo-config/oslo-config-9.3.0.ebuild
new file mode 100644
index 000000000000..4d5e415463a5
--- /dev/null
+++ b/dev-python/oslo-config/oslo-config-9.3.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Oslo Configuration API"
+HOMEPAGE="
+       https://opendev.org/openstack/oslo.config/
+       https://github.com/openstack/oslo.config/
+       https://pypi.org/project/oslo.config/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+       >=dev-python/pbr-1.3[${PYTHON_USEDEP}]
+       >=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+       >=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+       >=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+       >=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+       >=dev-python/rfc3986-1.2.0[${PYTHON_USEDEP}]
+       >=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+       >=dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       >=dev-python/pbr-1.3[${PYTHON_USEDEP}]
+       test? (
+               >=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+               >=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+               >=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+               >=dev-python/requests-mock-1.5.0[${PYTHON_USEDEP}]
+               >=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+               >=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+       # broken by some dep upgrade
+       sed -i -e '/DeprecationWarningTestsNoOsloLog/,$d' \
+               oslo_config/tests/test_cfg.py || die
+       distutils-r1_src_prepare
+}
+
+python_test() {
+       local -x COLUMNS=80
+       eunittest -b
+}