commit: ec216127dc272e5206b0f848afe85435857730b7
Author: Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 13 14:26:08 2024 +0000
Commit: Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Sat Jan 13 14:39:16 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ec216127
net-wireless/iwd: add 2.13
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>
net-wireless/iwd/Manifest | 1 +
net-wireless/iwd/iwd-2.13.ebuild | 167 +++++++++++++++++++++++++++++++++++++++
2 files changed, 168 insertions(+)
diff --git a/net-wireless/iwd/Manifest b/net-wireless/iwd/Manifest
index 3c88b7889f9f..9ac44af15b93 100644
--- a/net-wireless/iwd/Manifest
+++ b/net-wireless/iwd/Manifest
@@ -1,3 +1,4 @@
DIST iwd-2.12.tar.xz 1081424 BLAKE2B
e1e99a607dc0de2a84a3da0b989e953889cbcc3fd789d753a5bc0dde1323d801609e167622386b7c7436a9c6bc5460c9c3afe260a8c3065c2703e4b5890ea28a
SHA512
3a3d31f00b5b10631eb45d503913af2771f2f80966b9eb6f29d0ba1d533ca7e63ed1d0b95d99ee46e60c3468e794f7692819593b23ab0c6e9cb193605c6c22b3
+DIST iwd-2.13.tar.xz 1081288 BLAKE2B
d888a67bdb8ea86d1e8f1c2ad74a062aa4e8b0559c79764729d5d536d6f18e21432c022c2c3284af2e5f666595c0ab9962c3442e555ad7656961ec1fa41d0a6f
SHA512
2ad082579445c2c95d91dbbb3fc6d5e7afc15db000c42ab21b766340ba9e5e9e0e61756410ae537376f67542f1046a86bad2cb943eeb16ff732e3dbac4c0304f
DIST iwd-2.3.tar.xz 1061732 BLAKE2B
d22bb6bd2a1672536872f5642ed31361681fb16e08f3efe7241d15f456c80e37b5acfd5ef18d28affd308ce893b4c798b9ee1b4fc67c97b1de3fad920753e164
SHA512
f320feb2b9ac9cb719d4afa87e8935663aa13ebd5e9ef7bcd3a11a0553df4352a700d76faf0c9189cc3000c05545aed2286fb1051b4f732766f822a68736efd5
DIST iwd-2.8.tar.xz 1067700 BLAKE2B
ac691dfff675bd331a7af9e02179a5df61f0e20299c4a2851bd31950cbd0b696369069bd4a635cb25d24aec75996190bf8e47c2626eeff43b7ab37af5f932989
SHA512
bd208dc5ff391dccfe1b4a12f4b587ca8cedc1c1a7a2ddb34999c23acfad0e590e0463ac1ddc5093cb6489eb8ab8a090c01bcf06d679cfaf59c4b81469631795
diff --git a/net-wireless/iwd/iwd-2.13.ebuild b/net-wireless/iwd/iwd-2.13.ebuild
new file mode 100644
index 000000000000..bbb79d5e4e66
--- /dev/null
+++ b/net-wireless/iwd/iwd-2.13.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit flag-o-matic linux-info systemd
+
+#Set this variable to the required external ell version
+ELL_REQ="0.61"
+
+if [[ ${PV} == *9999* ]]; then
+ inherit autotools git-r3
+
IWD_EGIT_REPO_URI="https://git.kernel.org/pub/scm/network/wireless/iwd.git";
+ ELL_EGIT_REPO_URI="https://git.kernel.org/pub/scm/libs/ell/ell.git";
+else
+
SRC_URI="https://mirrors.edge.kernel.org/pub/linux/network/wireless/${P}.tar.xz";
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv
~sparc ~x86"
+ MYRST2MAN="RST2MAN=:"
+fi
+
+DESCRIPTION="Wireless daemon for linux"
+HOMEPAGE="https://git.kernel.org/pub/scm/network/wireless/iwd.git/";
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+client cpu_flags_x86_aes cpu_flags_x86_ssse3 +monitor ofono selinux
standalone systemd wired"
+
+DEPEND="
+ sys-apps/dbus
+ client? ( sys-libs/readline:0= )
+"
+
+[[ -z "${ELL_REQ}" ]] || DEPEND+=" >=dev-libs/ell-${ELL_REQ}"
+
+RDEPEND="
+ ${DEPEND}
+ acct-group/netdev
+ net-wireless/wireless-regdb
+ selinux? ( sec-policy/selinux-networkmanager )
+ standalone? (
+ systemd? ( sys-apps/systemd )
+ !systemd? ( virtual/resolvconf )
+ )
+"
+
+BDEPEND="
+ virtual/pkgconfig
+"
+
+[[ ${PV} == *9999* ]] && BDEPEND+=" dev-python/docutils"
+
+pkg_setup() {
+ CONFIG_CHECK="
+ ~ASYMMETRIC_KEY_TYPE
+ ~ASYMMETRIC_PUBLIC_KEY_SUBTYPE
+ ~CFG80211
+ ~CRYPTO_AES
+ ~CRYPTO_CBC
+ ~CRYPTO_CMAC
+ ~CRYPTO_DES
+ ~CRYPTO_ECB
+ ~CRYPTO_HMAC
+ ~CRYPTO_MD4
+ ~CRYPTO_MD5
+ ~CRYPTO_RSA
+ ~CRYPTO_SHA1
+ ~CRYPTO_SHA256
+ ~CRYPTO_SHA512
+ ~CRYPTO_USER_API_HASH
+ ~CRYPTO_USER_API_SKCIPHER
+ ~KEY_DH_OPERATIONS
+ ~PKCS7_MESSAGE_PARSER
+ ~RFKILL
+ ~X509_CERTIFICATE_PARSER
+ "
+
+ if use amd64;then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_DES3_EDE_X86_64"
+ WARNING_CRYPTO_DES3_EDE_X86_64="CRYPTO_DES3_EDE_X86_64: enable
for increased performance"
+ fi
+
+ if use cpu_flags_x86_aes;then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_AES_NI_INTEL"
+ WARNING_CRYPTO_AES_NI_INTEL="CRYPTO_AES_NI_INTEL: enable for
increased performance"
+ fi
+
+ if use cpu_flags_x86_ssse3 && use amd64; then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_SHA1_SSSE3
~CRYPTO_SHA256_SSSE3 ~CRYPTO_SHA512_SSSE3"
+ WARNING_CRYPTO_SHA1_SSSE3="CRYPTO_SHA1_SSSE3: enable for
increased performance"
+ WARNING_CRYPTO_SHA256_SSSE3="CRYPTO_SHA256_SSSE3: enable for
increased performance"
+ WARNING_CRYPTO_SHA512_SSSE3="CRYPTO_SHA512_SSSE3: enable for
increased performance"
+ fi
+
+ if use kernel_linux && kernel_is -ge 4 20; then
+ CONFIG_CHECK="${CONFIG_CHECK} ~PKCS8_PRIVATE_KEY_PARSER"
+ fi
+
+ check_extra_config
+}
+
+src_unpack() {
+ if [[ ${PV} == *9999* ]] ; then
+ EGIT_REPO_URI=${IWD_EGIT_REPO_URI} git-r3_src_unpack
+ EGIT_REPO_URI=${ELL_EGIT_REPO_URI}
EGIT_CHECKOUT_DIR=${WORKDIR}/ell git-r3_src_unpack
+ else
+ default
+ fi
+}
+
+src_prepare() {
+ default
+ if [[ ${PV} == *9999* ]] ; then
+ eautoreconf
+ fi
+
+ sed -e "s:Exec=/bin/false:Exec=${EPREFIX}/usr/libexec/iwd:g" -i
src/net.connman.iwd.service || die
+}
+
+src_configure() {
+ append-cflags "-fsigned-char"
+ local myeconfargs=(
+ --sysconfdir="${EPREFIX}"/etc/iwd
--localstatedir="${EPREFIX}"/var
+ "$(use_enable client)"
+ "$(use_enable monitor)"
+ "$(use_enable ofono)"
+ "$(use_enable wired)"
+ --enable-systemd-service
+ --with-systemd-unitdir="$(systemd_get_systemunitdir)"
+ --with-systemd-modloaddir="${EPREFIX}/usr/lib/modules-load.d"
+ --with-systemd-networkdir="$(systemd_get_utildir)/network"
+ )
+ [[ ${PV} == *9999* ]] || myeconfargs+=(--enable-external-ell)
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ emake "${MYRST2MAN}"
+}
+
+src_install() {
+ emake DESTDIR="${D}" "${MYRST2MAN}" install
+ keepdir "/var/lib/${PN}"
+
+ newinitd "${FILESDIR}/iwd.initd-r1" iwd
+
+ if use wired;then
+ newinitd "${FILESDIR}/ead.initd" ead
+ fi
+
+ if [[ ${PV} == *9999* ]] ; then
+ exeinto /usr/share/iwd/scripts/
+ doexe test/*
+ fi
+
+ if use standalone ; then
+ local iwdconf="${ED}/etc/iwd/main.conf"
+ dodir /etc/iwd
+ cat << EOF > "${iwdconf}"
+[General]
+EnableNetworkConfiguration=true
+
+[Network]
+NameResolvingService=$(usex systemd systemd resolvconf)
+EOF
+ dodir /etc/conf.d
+ echo "rc_provide=\"net\"" > "${ED}"/etc/conf.d/iwd
+ fi
+}
