commit: fa3a9f6530c8dc851df792e11dd9f7f9539f2320
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 1 19:47:17 2024 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Thu Feb 1 19:49:41 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fa3a9f65
dev-util/intel_clc: Version bump to 23.3.5
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
dev-util/intel_clc/Manifest | 1 +
dev-util/intel_clc/intel_clc-23.3.5.ebuild | 116 +++++++++++++++++++++++++++++
2 files changed, 117 insertions(+)
diff --git a/dev-util/intel_clc/Manifest b/dev-util/intel_clc/Manifest
index 05aeb4dfb67d..c6c31c7c923f 100644
--- a/dev-util/intel_clc/Manifest
+++ b/dev-util/intel_clc/Manifest
@@ -1,3 +1,4 @@
DIST mesa-23.3.1.tar.xz 19337988 BLAKE2B
73696281868e5eba6493cc34786a6c30eaf256bed2495444be9a1a5ebf1a0d4b8f00bcc3fb91ce9de3ac8ff23663e41cab17b8fe42b1048366c8e9b95aefa905
SHA512
0861fb5083e37439ad8cc0a0d8372a7c84d8665ea298dc784e2dd893162e20ae072f5ef0b860be88ecf74bc123714acbc1dec312e139b892ff40ef1887c5f4a5
DIST mesa-23.3.3.tar.xz 19379484 BLAKE2B
6b57e99356abccf398c5fb84953fc1490ddf516dbeed1feca8d16344a04c1c15183325752717447a34a61dd4cdda897147e3194f869d8dbadfa5c45a0c95dab5
SHA512
bed23e8324b026edd5d2b16a381ec563cf2fa9be9c8fbe8d9fb907cab9d87eef91f493fb9d4e3973d4b679e271d2a85ce48af491585638ab97f087532fc63c30
DIST mesa-23.3.4.tar.xz 19415668 BLAKE2B
85687793853675a43da5135f41d0512cb4729f3dd824e2ad28d9bda129258adb00dd7da1e75e76cae71c1148e6a2ede84e1efda640c11aff233e5e12b0cea554
SHA512
026c424989a594dd840dc158ca09e0f57e604f0b1bd2a3981110b4b2b5a47c6cd9c7241c7f48957a781e2dd9f9760cc9db79b2fb7c7fe39b64eddb18dcf18412
+DIST mesa-23.3.5.tar.xz 19429564 BLAKE2B
69c7434ae9c503c14b5bf9abad9a3a26a1dd402461b098dcdb01b9da7a7e8652f897fd9681c809aa70d3ace77c448289d22400deca3854844a355eb0ac095583
SHA512
1ad29f524caee0000ef51abe58d29d9687de5fbc5168f7e677bb4e69c5e9a94918d5fbf6e10c6757fe7ce6d47bab109e452f0fa2e26aad2e6f8bfb744383b5ea
diff --git a/dev-util/intel_clc/intel_clc-23.3.5.ebuild
b/dev-util/intel_clc/intel_clc-23.3.5.ebuild
new file mode 100644
index 000000000000..0df8ae0fd528
--- /dev/null
+++ b/dev-util/intel_clc/intel_clc-23.3.5.ebuild
@@ -0,0 +1,116 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit llvm meson python-any-r1
+
+MY_PV="${PV/_/-}"
+
+DESCRIPTION="intel_clc tool used for building OpenCL C to SPIR-V"
+HOMEPAGE="https://mesa3d.org/";
+
+if [[ ${PV} == 9999 ]]; then
+ S="${WORKDIR}/intel_clc-${MY_PV}"
+ EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/mesa.git";
+ inherit git-r3
+else
+ S="${WORKDIR}/mesa-${MY_PV}"
+ SRC_URI="https://archive.mesa3d.org/mesa-${MY_PV}.tar.xz";
+ KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT SGI-B-2.0"
+SLOT="0"
+IUSE="debug"
+
+RDEPEND="
+ dev-libs/libclc
+ dev-util/spirv-tools
+ >=sys-libs/zlib-1.2.8:=
+ x11-libs/libdrm
+"
+DEPEND="${RDEPEND}
+ dev-libs/expat
+"
+BDEPEND="
+ ${PYTHON_DEPS}
+ $(python_gen_any_dep ">=dev-python/mako-0.8.0[\${PYTHON_USEDEP}]")
+ virtual/pkgconfig
+"
+
+# Please keep the LLVM dependency block separate. Since LLVM is slotted,
+# we need to *really* make sure we're not pulling one than more slot
+# simultaneously.
+#
+# How to use it:
+# 1. Specify LLVM_MAX_SLOT (inclusive), e.g. 17.
+# 2. Specify LLVM_MIN_SLOT (inclusive), e.g. 15.
+LLVM_MAX_SLOT="17"
+LLVM_MIN_SLOT="15"
+PER_SLOT_DEPSTR="
+ (
+ dev-util/spirv-llvm-translator:@SLOT@
+ sys-devel/clang:@SLOT@
+ sys-devel/llvm:@SLOT@
+ )
+"
+LLVM_DEPSTR="
+ || (
+ $(for ((slot=LLVM_MAX_SLOT; slot>=LLVM_MIN_SLOT; slot--)); do
+ echo "${PER_SLOT_DEPSTR//@SLOT@/${slot}}"
+ done)
+ )
+ <sys-devel/clang-$((LLVM_MAX_SLOT + 1)):=
+ <sys-devel/llvm-$((LLVM_MAX_SLOT + 1)):=
+"
+RDEPEND="${RDEPEND}
+ ${LLVM_DEPSTR}
+"
+unset LLVM_MIN_SLOT {LLVM,PER_SLOT}_DEPSTR
+
+llvm_check_deps() {
+ has_version "dev-util/spirv-llvm-translator:${LLVM_SLOT}" &&
+ has_version "sys-devel/clang:${LLVM_SLOT}" &&
+ has_version "sys-devel/llvm:${LLVM_SLOT}"
+}
+
+python_check_deps() {
+ python_has_version -b ">=dev-python/mako-0.8.0[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ llvm_pkg_setup
+ python-any-r1_pkg_setup
+}
+
+src_configure() {
+ PKG_CONFIG_PATH="$(get_llvm_prefix
"${LLVM_MAX_SLOT}")/$(get_libdir)/pkgconfig"
+
+ local emesonargs=(
+ -Dllvm=enabled
+ -Dshared-llvm=enabled
+ -Dintel-clc=enabled
+
+ -Dgallium-drivers=''
+ -Dvulkan-drivers=''
+
+ # Set platforms empty to avoid the default "auto" setting. If
+ # platforms is empty meson.build will add surfaceless.
+ -Dplatforms=''
+
+ -Dglx=disabled
+ -Dlibunwind=disabled
+ -Dzstd=disabled
+
+ --buildtype $(usex debug debug plain)
+ -Db_ndebug=$(usex debug false true)
+ )
+ meson_src_configure
+}
+
+src_install() {
+ dobin "${BUILD_DIR}"/src/intel/compiler/intel_clc
+}
