commit: 79e235d3cc74368f4f175c6b400583ff0fd01633
Author: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Sun Feb 4 19:10:50 2024 +0000
Commit: Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Sun Feb 4 19:11:01 2024 +0000
URL: https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=79e235d3
phosh-base/phosh-shell: add 0.36.0
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>
phosh-base/phosh-shell/Manifest | 1 +
phosh-base/phosh-shell/metadata.xml | 5 +
phosh-base/phosh-shell/phosh-shell-0.36.0.ebuild | 132 +++++++++++++++++++++++
profiles/package.use.mask | 4 +
4 files changed, 142 insertions(+)
diff --git a/phosh-base/phosh-shell/Manifest b/phosh-base/phosh-shell/Manifest
index d0e5e6c20d..fc2bcfea44 100644
--- a/phosh-base/phosh-shell/Manifest
+++ b/phosh-base/phosh-shell/Manifest
@@ -1,3 +1,4 @@
DIST libcall-ui-acfbb136bbf74514e0b9801ce6c1e8acf36350b6.tar.gz 159337 BLAKE2B
47cd388043514baf568914adea281e884d0fa04375d8cc116cabd6a1061fcfb5e224a8065afffd2957513657ff5970d1dead33cea99f36117bb80b35d6f34513
SHA512
b79e3d8ac9889109e0fe20f149ffb14bde198f7a364152a60c7175228c283f18a7abe2049b01935d11fd005e14ef4da9c23ada6c651801364c79bc2dca1e71f2
DIST libgnome-volume-control-ae1a34aafce7026b8c0f65a43c9192d756fe1057.tar.gz
45164 BLAKE2B
c6807f855e7d4f45b58c7776cd497077b4adf8d577f9af014a8631a054c47374dfe5caa5652be208c6e566bfb8af70a0bb5e164f345b7612cb8786039625a191
SHA512
723334bff55927363dab47ef22c71dcaf94263fe76e49c40f1cbfbd5f86383e68fd4bf2182eb5777dda8e2ede4ee4710e1a7ab1379d3ca40d68f68ff30c62e21
+DIST phosh-0.36.0.tar.xz 839440 BLAKE2B
a6aa1c6fc2356055b0a451cb66fcfcbf3329059ab620aa56122e63e5eafc7f43ff1b1e4842fcadd7506f4724dbbab6e4785c6fb9b9e669e888c427be9163f0ab
SHA512
e108423c97343917b4be1827c44642e90738027b543bdc4bf2f45073101383227a157771a9efdf0b65a9adf30a09d1111210be21d35043ced8a9046fe70588e2
DIST phosh-v0.17.0.tar.gz 726863 BLAKE2B
6a4c6bc6b3f645b7805445be21a4d8df13b786ee8cf104cf202a88a8333c5123cf34e5c136fa21d13476c71a51240d87388587bca84a37487e4984434fd32c53
SHA512
020a0cc5659d5c1a5f4291baed231f3f7b698dc41f027173cc59f3429a1a43bbf6f2213f2fb79d7d2c175518cb6a892c419a3b0ad902e51cca2c313f5bbc84bf
diff --git a/phosh-base/phosh-shell/metadata.xml
b/phosh-base/phosh-shell/metadata.xml
index dbc793aa3f..9858884bbc 100644
--- a/phosh-base/phosh-shell/metadata.xml
+++ b/phosh-base/phosh-shell/metadata.xml
@@ -12,6 +12,11 @@
</longdescription>
<upstream>
<bugs-to>https://gitlab.gnome.org/World/Phosh/phosh/-/issues</bugs-to>
+
<doc>https://gitlab.gnome.org/World/Phosh/phosh/-/wikis/Home</doc>
<remote-id type="gnome-gitlab">World/Phosh/phosh</remote-id>
</upstream>
+ <use>
+ <flag name="lockscreen-plugins">Build lockscreen plugins and
widgets</flag>
+ <flag name="test-full">Run integration tests</flag>
+ </use>
</pkgmetadata>
diff --git a/phosh-base/phosh-shell/phosh-shell-0.36.0.ebuild
b/phosh-base/phosh-shell/phosh-shell-0.36.0.ebuild
new file mode 100644
index 0000000000..ea8fd4b3cb
--- /dev/null
+++ b/phosh-base/phosh-shell/phosh-shell-0.36.0.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson pam systemd virtualx xdg
+
+MY_PN="${PN%-shell}"
+MY_P="${MY_PN}-${PV}"
+DESCRIPTION="Pure Wayland shell for mobile devices"
+HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phosh/";
+SRC_URI="https://sources.phosh.mobi/releases/${MY_PN}/${MY_P}.tar.xz";
+S="${WORKDIR}/${MY_P}"
+
+KEYWORDS="~amd64 ~arm64"
+LICENSE="CC0-1.0 CC-BY-SA-4.0 GPL-2+ GPL-3+ LGPL-2+ LGPL-2.1+ MIT"
+SLOT="0"
+IUSE="elogind gtk-doc +lockscreen-plugins man test test-full"
+REQUIRED_USE="test-full? ( lockscreen-plugins )"
+
+COMMON_DEPEND="
+ >=app-crypt/gcr-3.7.5:0
+ app-crypt/libsecret
+ >=dev-libs/feedbackd-0.2.0
+ dev-libs/fribidi
+ >=dev-libs/glib-2.76:2
+ >=dev-libs/json-glib-1.6.2
+ dev-libs/libgudev:=
+ >=dev-libs/wayland-1.14
+ >=gnome-base/gnome-desktop-3.26:3
+ >=gnome-base/gsettings-desktop-schemas-42
+ >=gnome-extra/evolution-data-server-3.33.1:=
+ >=gui-libs/libhandy-1.1.90:1
+ media-libs/libpulse[glib]
+ media-sound/callaudiod
+ >=net-misc/networkmanager-1.14
+ sys-apps/dbus
+ >=sys-auth/polkit-0.105
+ sys-libs/pam
+ >=sys-power/upower-0.99.1:=
+ >=x11-libs/gtk+-3.22:3[wayland]
+ elogind? ( >=sys-auth/elogind-241 )
+ !elogind? ( >=sys-apps/systemd-241:= )
+ lockscreen-plugins? (
+ app-text/evince:=
+ gui-libs/gtk:4
+ gui-libs/libadwaita:1
+ )
+"
+RUNTIME_DEPEND="
+ gnome-base/gnome-shell
+ virtual/freedesktop-icon-theme
+ x11-themes/gnome-themes-standard
+"
+
+DEPEND="
+ ${COMMON_DEPEND:?}
+ >=dev-libs/wayland-protocols-1.12
+ test-full? ( ${RUNTIME_DEPEND:?} )
+"
+RDEPEND="
+ ${COMMON_DEPEND:?}
+ ${RUNTIME_DEPEND:?}
+ !elogind? ( sys-libs/libcap )
+"
+BDEPEND="
+ dev-libs/glib:2
+ dev-libs/libxml2
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ dev-util/wayland-scanner
+ sys-devel/gettext
+ gtk-doc? ( dev-util/gi-docgen )
+ man? ( dev-python/docutils )
+ test-full? ( gui-wm/phoc )
+"
+
+src_configure() {
+ local emesonargs=(
+ -Dcompositor="${EPREFIX}"/usr/bin/phoc
+ -Dsystemd=true
+ -Dtools=true
+ $(meson_use gtk-doc gtk_doc)
+ $(meson_use lockscreen-plugins)
+ $(meson_use man)
+ $(meson_use test tests)
+ $(meson_feature test-full phoc_tests)
+ )
+ meson_src_configure
+}
+
+src_test() {
+ local -x LC_ALL="C.UTF-8"
+ local -x WLR_RENDERER="pixman"
+
+ virtx meson_src_test --suite unit
+ if use test-full; then
+ virtx meson_src_test --suite integration
+ fi
+}
+
+src_install() {
+ meson_src_install
+ pamd_mimic system-local-login phosh auth account session
+ systemd_douserunit data/phosh.service
+
+ if use gtk-doc; then
+ mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+ mv "${ED}"/usr/share/doc/${MY_PN}-${SLOT}
"${ED}"/usr/share/gtk-doc/html/ || die
+ fi
+}
+
+phosh_giomodule_cache_update() {
+ local plugins_dir
+ plugins_dir=$(pkg-config --variable=lockscreen_plugins_dir
phosh-plugins) || return 1
+
+ ebegin "Updating GIO modules cache"
+ gio-querymodules "${plugins_dir}"
+ eend $?
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+ phosh_giomodule_cache_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+ phosh_giomodule_cache_update
+}
diff --git a/profiles/package.use.mask b/profiles/package.use.mask
index 6329d2d591..e83680ac1a 100644
--- a/profiles/package.use.mask
+++ b/profiles/package.use.mask
@@ -3,6 +3,10 @@
# New entries go on top.
+# Anna Vyalkova <[email protected]> (2024-02-04)
+# "/phosh/drag-surface" fails in our test environment.
+phosh-base/phosh-shell test-full
+
# Anna Vyalkova <[email protected]> (2023-11-21)
# Build failure.
# https://gitlab.com/famedly/conduit/-/issues/385
