commit: 9918e16373bc3ed541b7b605ab278d14feca9c5f
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 3 16:00:25 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Mar 3 16:00:25 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9918e163
app-cdr/gcdemu: EAPI 8, py3.12
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
app-cdr/gcdemu/gcdemu-3.2.6-r1.ebuild | 60 +++++++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
diff --git a/app-cdr/gcdemu/gcdemu-3.2.6-r1.ebuild
b/app-cdr/gcdemu/gcdemu-3.2.6-r1.ebuild
new file mode 100644
index 000000000000..10f7298db619
--- /dev/null
+++ b/app-cdr/gcdemu/gcdemu-3.2.6-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit cmake gnome2-utils python-single-r1 xdg-utils
+
+DESCRIPTION="Gtk+ GUI for controlling cdemu-daemon"
+HOMEPAGE="https://cdemu.sourceforge.io";
+SRC_URI="https://download.sourceforge.net/cdemu/gcdemu/${P}.tar.xz";
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# librsvg for pixbuf-loader
+RDEPEND="
+ ${PYTHON_DEPS}
+ app-cdr/cdemu-daemon:0/7
+ $(python_gen_cond_dep '
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ ')
+ gnome-base/librsvg:2
+ x11-libs/gdk-pixbuf[introspection]
+ x11-libs/gtk+:3[introspection]
+ x11-libs/libnotify[introspection]
+"
+BDEPEND="
+ ${PYTHON_DEPS}
+ dev-util/desktop-file-utils
+ >=dev-util/intltool-0.21
+ sys-devel/gettext
+ virtual/pkgconfig
+"
+
+DOCS=( AUTHORS README )
+
+src_prepare() {
+ cmake_src_prepare
+ python_fix_shebang src/gcdemu
+}
+
+src_configure() {
+ local mycmakeargs=( -DPOST_INSTALL_HOOKS=OFF )
+ cmake_src_configure
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ gnome2_schemas_update
+}
