commit: ed33d5beb5fde0723f50417b8469891fe2e70747
Author: Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 4 15:30:27 2024 +0000
Commit: Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Mon Mar 4 15:30:49 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ed33d5be
net-wireless/iwd: add 2.16
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>
net-wireless/iwd/Manifest | 1 +
net-wireless/iwd/iwd-2.16.ebuild | 167 +++++++++++++++++++++++++++++++++++++++
2 files changed, 168 insertions(+)
diff --git a/net-wireless/iwd/Manifest b/net-wireless/iwd/Manifest
index 261449308e1e..2425a1deddf1 100644
--- a/net-wireless/iwd/Manifest
+++ b/net-wireless/iwd/Manifest
@@ -1,4 +1,5 @@
DIST iwd-2.13.tar.xz 1081288 BLAKE2B
d888a67bdb8ea86d1e8f1c2ad74a062aa4e8b0559c79764729d5d536d6f18e21432c022c2c3284af2e5f666595c0ab9962c3442e555ad7656961ec1fa41d0a6f
SHA512
2ad082579445c2c95d91dbbb3fc6d5e7afc15db000c42ab21b766340ba9e5e9e0e61756410ae537376f67542f1046a86bad2cb943eeb16ff732e3dbac4c0304f
DIST iwd-2.14.tar.xz 1082236 BLAKE2B
ae50866ad0b3f0139352467f50b9babf054a91ec3c6298ac79842fa91f6df6802ea2b1e51688dce8d6487210b923a84b546a0afe996df7be9bad5eeb13129a7b
SHA512
6af763d8dda4a8e99d96a6c94a72c16d298274fb224cc11912b4ec9eb8c80b599b49145b0fc979f213d14f6af100eb03477b6140272d303277d851eb8c8f9e07
DIST iwd-2.15.tar.xz 1082944 BLAKE2B
3a9733efa53fa1b82a48ebd44e4974db83dbd5b17abf614ea422fbf96f58c6e4384ddccffd9c345b96d64ca15c10124c592bd2942eb950937da535f1a73fe821
SHA512
c97ceb714e42831316b5e66e304a7664589312991704bd855767eb2db5dcb5f3b865e03419445942255764d4518f02f1b387b335e21866663bbb75b2d244b6d1
+DIST iwd-2.16.tar.xz 1083684 BLAKE2B
d744e85812128274984efe196678866ecdc500c6e5a2f72f01ebae83fd2afe120f789eef46cdc2383f3e67c3206723f2d40eee9073e5424c1cef86609af418da
SHA512
29888542f4c92f5cad213bc8dce58fcd74f04659a50a207fc5a550f5c875d649447d7caca7ff322dec3e1e29d9ec50923b2607ac6bd726e59e5a116408e77eb5
DIST iwd-2.8.tar.xz 1067700 BLAKE2B
ac691dfff675bd331a7af9e02179a5df61f0e20299c4a2851bd31950cbd0b696369069bd4a635cb25d24aec75996190bf8e47c2626eeff43b7ab37af5f932989
SHA512
bd208dc5ff391dccfe1b4a12f4b587ca8cedc1c1a7a2ddb34999c23acfad0e590e0463ac1ddc5093cb6489eb8ab8a090c01bcf06d679cfaf59c4b81469631795
diff --git a/net-wireless/iwd/iwd-2.16.ebuild b/net-wireless/iwd/iwd-2.16.ebuild
new file mode 100644
index 000000000000..9fdd8eb4495d
--- /dev/null
+++ b/net-wireless/iwd/iwd-2.16.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit flag-o-matic linux-info systemd
+
+#Set this variable to the required external ell version
+ELL_REQ="0.63"
+
+if [[ ${PV} == *9999* ]]; then
+ inherit autotools git-r3
+
IWD_EGIT_REPO_URI="https://git.kernel.org/pub/scm/network/wireless/iwd.git";
+ ELL_EGIT_REPO_URI="https://git.kernel.org/pub/scm/libs/ell/ell.git";
+else
+
SRC_URI="https://mirrors.edge.kernel.org/pub/linux/network/wireless/${P}.tar.xz";
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv
~sparc ~x86"
+ MYRST2MAN="RST2MAN=:"
+fi
+
+DESCRIPTION="Wireless daemon for linux"
+HOMEPAGE="https://git.kernel.org/pub/scm/network/wireless/iwd.git/";
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+client cpu_flags_x86_aes cpu_flags_x86_ssse3 +monitor ofono selinux
standalone systemd wired"
+
+DEPEND="
+ sys-apps/dbus
+ client? ( sys-libs/readline:0= )
+"
+
+[[ -z "${ELL_REQ}" ]] || DEPEND+=" >=dev-libs/ell-${ELL_REQ}"
+
+RDEPEND="
+ ${DEPEND}
+ acct-group/netdev
+ net-wireless/wireless-regdb
+ selinux? ( sec-policy/selinux-networkmanager )
+ standalone? (
+ systemd? ( sys-apps/systemd )
+ !systemd? ( virtual/resolvconf )
+ )
+"
+
+BDEPEND="
+ virtual/pkgconfig
+"
+
+[[ ${PV} == *9999* ]] && BDEPEND+=" dev-python/docutils"
+
+pkg_setup() {
+ CONFIG_CHECK="
+ ~ASYMMETRIC_KEY_TYPE
+ ~ASYMMETRIC_PUBLIC_KEY_SUBTYPE
+ ~CFG80211
+ ~CRYPTO_AES
+ ~CRYPTO_CBC
+ ~CRYPTO_CMAC
+ ~CRYPTO_DES
+ ~CRYPTO_ECB
+ ~CRYPTO_HMAC
+ ~CRYPTO_MD4
+ ~CRYPTO_MD5
+ ~CRYPTO_RSA
+ ~CRYPTO_SHA1
+ ~CRYPTO_SHA256
+ ~CRYPTO_SHA512
+ ~CRYPTO_USER_API_HASH
+ ~CRYPTO_USER_API_SKCIPHER
+ ~KEY_DH_OPERATIONS
+ ~PKCS7_MESSAGE_PARSER
+ ~RFKILL
+ ~X509_CERTIFICATE_PARSER
+ "
+
+ if use amd64;then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_DES3_EDE_X86_64"
+ WARNING_CRYPTO_DES3_EDE_X86_64="CRYPTO_DES3_EDE_X86_64: enable
for increased performance"
+ fi
+
+ if use cpu_flags_x86_aes;then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_AES_NI_INTEL"
+ WARNING_CRYPTO_AES_NI_INTEL="CRYPTO_AES_NI_INTEL: enable for
increased performance"
+ fi
+
+ if use cpu_flags_x86_ssse3 && use amd64; then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_SHA1_SSSE3
~CRYPTO_SHA256_SSSE3 ~CRYPTO_SHA512_SSSE3"
+ WARNING_CRYPTO_SHA1_SSSE3="CRYPTO_SHA1_SSSE3: enable for
increased performance"
+ WARNING_CRYPTO_SHA256_SSSE3="CRYPTO_SHA256_SSSE3: enable for
increased performance"
+ WARNING_CRYPTO_SHA512_SSSE3="CRYPTO_SHA512_SSSE3: enable for
increased performance"
+ fi
+
+ if use kernel_linux && kernel_is -ge 4 20; then
+ CONFIG_CHECK="${CONFIG_CHECK} ~PKCS8_PRIVATE_KEY_PARSER"
+ fi
+
+ check_extra_config
+}
+
+src_unpack() {
+ if [[ ${PV} == *9999* ]] ; then
+ EGIT_REPO_URI=${IWD_EGIT_REPO_URI} git-r3_src_unpack
+ EGIT_REPO_URI=${ELL_EGIT_REPO_URI}
EGIT_CHECKOUT_DIR=${WORKDIR}/ell git-r3_src_unpack
+ else
+ default
+ fi
+}
+
+src_prepare() {
+ default
+ if [[ ${PV} == *9999* ]] ; then
+ eautoreconf
+ fi
+
+ sed -e "s:Exec=/bin/false:Exec=${EPREFIX}/usr/libexec/iwd:g" -i
src/net.connman.iwd.service || die
+}
+
+src_configure() {
+ append-cflags "-fsigned-char"
+ local myeconfargs=(
+ --sysconfdir="${EPREFIX}"/etc/iwd
--localstatedir="${EPREFIX}"/var
+ "$(use_enable client)"
+ "$(use_enable monitor)"
+ "$(use_enable ofono)"
+ "$(use_enable wired)"
+ --enable-systemd-service
+ --with-systemd-unitdir="$(systemd_get_systemunitdir)"
+ --with-systemd-modloaddir="${EPREFIX}/usr/lib/modules-load.d"
+ --with-systemd-networkdir="$(systemd_get_utildir)/network"
+ )
+ [[ ${PV} == *9999* ]] || myeconfargs+=(--enable-external-ell)
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ emake "${MYRST2MAN}"
+}
+
+src_install() {
+ emake DESTDIR="${D}" "${MYRST2MAN}" install
+ keepdir "/var/lib/${PN}"
+
+ newinitd "${FILESDIR}/iwd.initd-r1" iwd
+
+ if use wired;then
+ newinitd "${FILESDIR}/ead.initd" ead
+ fi
+
+ if [[ ${PV} == *9999* ]] ; then
+ exeinto /usr/share/iwd/scripts/
+ doexe test/*
+ fi
+
+ if use standalone ; then
+ local iwdconf="${ED}/etc/iwd/main.conf"
+ dodir /etc/iwd
+ cat << EOF > "${iwdconf}"
+[General]
+EnableNetworkConfiguration=true
+
+[Network]
+NameResolvingService=$(usex systemd systemd resolvconf)
+EOF
+ dodir /etc/conf.d
+ echo "rc_provide=\"net\"" > "${ED}"/etc/conf.d/iwd
+ fi
+}
