commit: 944c268c7ad8727ce81cf9734d205121615f8e47
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 9 14:26:10 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Mar 9 15:11:44 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=944c268c
dev-python/pytest: Bump to 8.1.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pytest/Manifest | 1 +
dev-python/pytest/pytest-8.1.1.ebuild | 113 ++++++++++++++++++++++++++++++++++
2 files changed, 114 insertions(+)
diff --git a/dev-python/pytest/Manifest b/dev-python/pytest/Manifest
index 7b01ba3e81b5..c2f1a7b4cc8b 100644
--- a/dev-python/pytest/Manifest
+++ b/dev-python/pytest/Manifest
@@ -3,3 +3,4 @@ DIST pytest-8.0.0.tar.gz 1395242 BLAKE2B
99d0dce33a2a9c0c421777779584b6f74950e27
DIST pytest-8.0.1.tar.gz 1396338 BLAKE2B
feb21b576e1c82376481493d4c7c345f16ac7c818c13b88d37a2b5c3ecdbb6fa7397243f8672df320657a4a6fd654267760a278313fd0cba069da950834fdb55
SHA512
ce1fa9fa2a78f73320e1692681930c7bee5f6bd66b592d6f8b7e6c958cbdc180d9b1f39ecad2556c0811c5337e7fa28b84a093f064ac46f7fd3c4a6d94b3e73a
DIST pytest-8.0.2.tar.gz 1396924 BLAKE2B
ad95d246f5592cfe54faea6c96e38cb60d3e2713070d1ff7cab6c42aea312883c5d97c99a930dbcbd8493e966c4b8351320f6494b4ab904afbf21d7e1dd004a7
SHA512
c495943baad05e09b467d23c7afadb3edff7ae93ee96290d6db9e64739236888148b63dff7e8e25b331b11bd48c55fb0ca8901cf823d69b1a922e94915bab2f1
DIST pytest-8.1.0.tar.gz 1407129 BLAKE2B
38118dc5d5ab11d14a40c3e0a304218f376ea4b31ee451bf8dbe29081d5faf9a1f57d2f47d1a14a344cb5855a1aec5f37ea6098b88d83f7b79822499fa8285a5
SHA512
9c527946dcf27924e1c9dd7e4e129bd1a6d46f07e75bba97dba6e980d3404b9542b2a5088623d45a9879e7bafc9f2377bda144ff4fae21a6888ac6583b027e2c
+DIST pytest-8.1.1.tar.gz 1409703 BLAKE2B
8e382c87af1bbbc235f9b27f8bb892d08393e0a9821f32373ee2546112c24dc6f90e1990f10ef799a94a1426a83a2bc3de0be9e7efde90cbf4eac5a0c9ee375c
SHA512
f1a9f69cd4eca3ab36c36bc666bf70b099125ed6e17b89d13554c3f13b100d05abfd0b35516660d00ca4fb9eca81164ab02bc8f7a9a8d90fd4302bf399cd88c0
diff --git a/dev-python/pytest/pytest-8.1.1.ebuild
b/dev-python/pytest/pytest-8.1.1.ebuild
new file mode 100644
index 000000000000..f57a5169cba9
--- /dev/null
+++ b/dev-python/pytest/pytest-8.1.1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_TESTED=( python3_{10..12} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple powerful testing with Python"
+HOMEPAGE="
+ https://pytest.org/
+ https://github.com/pytest-dev/pytest/
+ https://pypi.org/project/pytest/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos
~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-python/iniconfig[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ <dev-python/pluggy-2[${PYTHON_USEDEP}]
+ >=dev-python/pluggy-1.4[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+ >=dev-python/tomli-1[${PYTHON_USEDEP}]
+ ' 3.10)
+ !!<=dev-python/flaky-3.7.0-r5
+"
+BDEPEND="
+ >=dev-python/setuptools-scm-6.2.3[${PYTHON_USEDEP}]
+ test? (
+ ${RDEPEND}
+ $(python_gen_cond_dep '
+ dev-python/argcomplete[${PYTHON_USEDEP}]
+ >=dev-python/attrs-19.2[${PYTHON_USEDEP}]
+ >=dev-python/hypothesis-3.56[${PYTHON_USEDEP}]
+ dev-python/mock[${PYTHON_USEDEP}]
+ >=dev-python/pygments-2.7.2[${PYTHON_USEDEP}]
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/xmlschema[${PYTHON_USEDEP}]
+ ' "${PYTHON_TESTED[@]}")
+ )
+"
+
+src_test() {
+ # workaround new readline defaults
+ echo "set enable-bracketed-paste off" > "${T}"/inputrc || die
+ local -x INPUTRC="${T}"/inputrc
+ distutils-r1_src_test
+}
+
+python_test() {
+ if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+ einfo "Skipping tests on ${EPYTHON}"
+ return
+ fi
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x COLUMNS=80
+
+ local EPYTEST_DESELECT=(
+ # broken by epytest args
+ testing/test_warnings.py::test_works_with_filterwarnings
+
+ # tend to be broken by random pytest plugins
+ # (these tests patch PYTEST_DISABLE_PLUGIN_AUTOLOAD out)
+ testing/test_helpconfig.py::test_version_less_verbose
+ testing/test_helpconfig.py::test_version_verbose
+ testing/test_junitxml.py::test_random_report_log_xdist
+ testing/test_junitxml.py::test_runs_twice_xdist
+
testing/test_terminal.py::TestProgressOutputStyle::test_xdist_normal
+
testing/test_terminal.py::TestProgressOutputStyle::test_xdist_normal_count
+
testing/test_terminal.py::TestProgressOutputStyle::test_xdist_verbose
+
testing/test_terminal.py::TestProgressWithTeardown::test_xdist_normal
+
testing/test_terminal.py::TestTerminalFunctional::test_header_trailer_info
+
testing/test_terminal.py::TestTerminalFunctional::test_no_header_trailer_info
+
+ # unstable with xdist
+
testing/test_terminal.py::TestTerminalFunctional::test_verbose_reporting_xdist
+
+ # TODO (XPASS)
+
testing/test_debugging.py::TestDebuggingBreakpoints::test_pdb_not_altered
+
testing/test_debugging.py::TestPDB::test_pdb_interaction_capturing_simple
+
testing/test_debugging.py::TestPDB::test_pdb_interaction_capturing_twice
+
testing/test_debugging.py::TestPDB::test_pdb_with_injected_do_debug
+ testing/test_debugging.py::test_pdb_suspends_fixture_capturing
+
+ # setuptools warnings
+
testing/acceptance_test.py::TestInvocationVariants::test_cmdline_python_namespace_package
+
+ # times out
+
testing/test_debugging.py::TestPDB::test_pdb_interaction_exception
+
testing/test_debugging.py::TestPDB::test_pdb_with_caplog_on_pdb_invocation
+ )
+
+ [[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+ # regressions on pypy3.9
+ # https://github.com/pytest-dev/pytest/issues/9787
+ testing/test_skipping.py::test_errors_in_xfail_skip_expressions
+ testing/test_unraisableexception.py
+ )
+
+ local EPYTEST_XDIST=1
+ epytest
+}
