commit: 5b453e397bbc005900ff41603a447bf552a256eb
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 24 15:56:17 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Mar 24 16:22:35 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5b453e39
dev-python/hypothesis: Bump to 6.99.12
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/hypothesis/Manifest | 1 +
dev-python/hypothesis/hypothesis-6.99.12.ebuild | 90 +++++++++++++++++++++++++
2 files changed, 91 insertions(+)
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index a230acbd6cc0..558d66275d2c 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -1,2 +1,3 @@
DIST hypothesis-6.98.18.gh.tar.gz 9434436 BLAKE2B
45861775caa1657d06469fc8cd0062aee1b408c3b02a58ff4d50b9de9ce62d8fd351c6b8f4b1b7f543fe70d6b8f2c663ad8e9252b833d5c567d3c28449fc3eaf
SHA512
cff5cad9308e7b030e38f09a9544ed84f468bc4bd6391a2347777bb7781b116bd64f41338ad32535d427ebda507ce3f0f5bafc0af5a8179976c17d36762679e9
DIST hypothesis-6.99.11.gh.tar.gz 9449844 BLAKE2B
272f794344d9747033ad67af666ba9c807e77239a09a70df713f8c9157ae65d47b7f1756dc57441537dfa367827433ee9464d24fc49e2ed6437df48a0d290bd4
SHA512
bac29bec1718b66de9168630db51e73068d44dfa5bae4022f341476fc7838a16e848241035fce292832a9b695066626994f9aee03ffcfabed182154adc4f9a08
+DIST hypothesis-6.99.12.gh.tar.gz 9449923 BLAKE2B
530be55c2d0f95d5ba1556bf3daa72ec04e057051491e5f7070560568fb11f035a95370f73989c1e016256ed031ab71a3fb8588b7870374d899d08db49555ea8
SHA512
923d2638e2d43f8e9c42488292383a5c51007d53faea0779383308777aa59e47c443ba94ca76bc3f6fe39a0ace53a2731475269f18166b055af6a36fd38aac3f
diff --git a/dev-python/hypothesis/hypothesis-6.99.12.ebuild
b/dev-python/hypothesis/hypothesis-6.99.12.ebuild
new file mode 100644
index 000000000000..f7f366381e4f
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.99.12.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{10..12} )
+PYTHON_COMPAT=( "${CLI_COMPAT[@]}" pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+ https://github.com/HypothesisWorks/hypothesis/
+ https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+ https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+ >=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+ >=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+ ' 3.9 3.10)
+ cli? (
+ $(python_gen_cond_dep '
+ dev-python/black[${PYTHON_USEDEP}]
+ dev-python/click[${PYTHON_USEDEP}]
+ ' "${CLI_COMPAT[@]}")
+ )
+"
+BDEPEND="
+ test? (
+ dev-python/pexpect[${PYTHON_USEDEP}]
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ !!<dev-python/requests-toolbelt-0.10.1
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ # subtests are broken by warnings from random plugins
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+ local -x HYPOTHESIS_NO_PLUGINS=1
+
+ # NB: paths need to be relative to pytest.ini,
+ # i.e. start with hypothesis-python/
+ local EPYTEST_DESELECT=()
+ case ${EPYTHON} in
+ pypy3)
+ EPYTEST_DESELECT+=(
+ # failing due to warnings from numpy/cython
+
hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+ )
+ ;;
+ esac
+
+ epytest -o filterwarnings= -n "$(makeopts_jobs)" --dist=worksteal \
+ tests/cover tests/pytest tests/quality
+}
+
+python_install() {
+ distutils-r1_python_install
+ if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+ rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+ fi
+}
+
+pkg_postinst() {
+ optfeature "datetime support" dev-python/pytz
+ optfeature "dateutil support" dev-python/python-dateutil
+ optfeature "numpy support" dev-python/numpy
+ optfeature "django support" dev-python/django dev-python/pytz
+ optfeature "pandas support" dev-python/pandas
+ optfeature "pytest support" dev-python/pytest
+}
