commit: e242f7958729e068412490fe6065d5559d971987
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 28 05:44:30 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Mar 28 05:55:37 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e242f795
dev-python/kombu: Bump to 5.3.6
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/kombu/Manifest | 1 +
dev-python/kombu/kombu-5.3.6.ebuild | 83 +++++++++++++++++++++++++++++++++++++
2 files changed, 84 insertions(+)
diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index 3d2808d954b8..723a11704982 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
DIST kombu-5.3.5.tar.gz 438460 BLAKE2B
c59c8b8213f5dc2726a281176f2a034a3ab175523c8aca95ea3f5b502b70de74668ca88925b78800968001573d2e0fffb16aed470880ec5fc5f47e2857170f07
SHA512
58b75b5f62cf116ca68d296c9379c10b1e3c3cb115dffd35416f87ecd4783e5230fe280f7b67f4853798056c39a46a6deefdf058ed4fe3eaa7716fa053874b47
+DIST kombu-5.3.6.tar.gz 439311 BLAKE2B
6be4f7b1459f9f48ba933075871a8f34c3817b5a7fa31875f4370b88abc8271a86ff628e94cbe5a1474f9fa01b99ecd98dfa6ada8dfcfaa26e518d15e83e1b6e
SHA512
22712b3f105a87790103e8df3565d9bfa30bfadc706d7f8d8dc7eb908575603b8f3f596cc04b428bd69ff63b484509aadf0f031a792e315883d3dc878705a79e
diff --git a/dev-python/kombu/kombu-5.3.6.ebuild
b/dev-python/kombu/kombu-5.3.6.ebuild
new file mode 100644
index 000000000000..1dc983b25728
--- /dev/null
+++ b/dev-python/kombu/kombu-5.3.6.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+ https://github.com/celery/kombu/
+ https://pypi.org/project/kombu/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+ >=dev-python/amqp-5.1.1[${PYTHON_USEDEP}]
+ <dev-python/amqp-6.0.0[${PYTHON_USEDEP}]
+ dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ app-arch/brotli[python,${PYTHON_USEDEP}]
+ >=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+ dev-python/hypothesis[${PYTHON_USEDEP}]
+ >=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+ dev-python/pycurl[${PYTHON_USEDEP}]
+ >=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+ dev-python/pytest-freezegun[${PYTHON_USEDEP}]
+ dev-python/zstandard[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ >=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+ >=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
+ dev-python/sqlalchemy[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+ dev-python/sphinx-celery
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO
+
t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
+ )
+ local EPYTEST_IGNORE=(
+ # obsolete Pyro4
+ t/unit/transport/test_pyro.py
+ # unpackaged azure
+ t/unit/transport/test_azurestoragequeues.py
+ )
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest
+}
+
+python_install_all() {
+ if use examples; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r examples/.
+ fi
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+ optfeature "Etcd backend" dev-python/python-etcd
+ optfeature "MongoDB backend" dev-python/pymongo
+ optfeature "Redis backend" dev-python/redis
+ optfeature "sqlalchemy backend" dev-python/sqlalchemy
+ optfeature "yaml backend" dev-python/pyyaml
+ optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+ optfeature "brotli compression" "app-arch/brotli[python]"
+ optfeature "zstd compression" dev-python/zstandard
+}
