commit: 587d3d90d7c0d6d87720ab1b9b22a20f08803c05
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 9 18:53:17 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Apr 9 19:38:21 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=587d3d90
net-wireless/blueman: Bump to 2.4.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
net-wireless/blueman/Manifest | 1 +
net-wireless/blueman/blueman-2.4.1.ebuild | 150 ++++++++++++++++++++++++++++++
2 files changed, 151 insertions(+)
diff --git a/net-wireless/blueman/Manifest b/net-wireless/blueman/Manifest
index ca6f14ad677d..e30411108172 100644
--- a/net-wireless/blueman/Manifest
+++ b/net-wireless/blueman/Manifest
@@ -1,2 +1,3 @@
DIST blueman-2.3.5.tar.xz 1544232 BLAKE2B
454a5369cecd429dcbff84108ef5440c61e3740d54de30e85cef941f9bd55ef3f032aa4774b161cd145eecc53061d2d104ea6d6ec12516beb2f2b3579c074ccb
SHA512
678261dc0a795ca79b43614f4fc6ad436b44690d0ce4dbf15f55dba4834a25a5c1956bf658d568a3318828863b3bb089689d0dc4fef8963ed2b27cf0f1144580
+DIST blueman-2.4.1.tar.xz 1540776 BLAKE2B
0d191d9c3af673b0b74ee6a5a3242312670229853f47ccc044cf7f1a091d6a0b677f1c818c76ca372f535d5527c26eeaf0588729694176461b5b2afbfca33391
SHA512
154ad7bece4f513d523d2fcefa8ea2b6bd8a2ac991c1b4b86d81b7d25107cad9cdd5cbd21d25145e944fa2731575f0fd023b40ab0a3a6ba408741fad314c6b37
DIST blueman-2.4.tar.xz 1493924 BLAKE2B
5c777d1707fad5a8a4a89e73c555bb5592ca491b3e7760634f5b22ec3bc305fe1c6e3b11b25e4eb6fe381ef3b59695241d3c278497466645500e5b94147dca4e
SHA512
2c3866291c30cbceaaa6427b006c1155aaa6e84bbbaa370d8a99d95a01ea04120efe9a5b36c17e4fc43b583e98f0123f1a4f116e6572674157dd169c986ab080
diff --git a/net-wireless/blueman/blueman-2.4.1.ebuild
b/net-wireless/blueman/blueman-2.4.1.ebuild
new file mode 100644
index 000000000000..bec135aa318c
--- /dev/null
+++ b/net-wireless/blueman/blueman-2.4.1.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=no
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit autotools distutils-r1 gnome2-utils linux-info systemd xdg-utils
+
+DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
+HOMEPAGE="https://github.com/blueman-project/blueman/";
+
+if [[ ${PV} == "9999" ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/blueman-project/blueman.git";
+else
+ SRC_URI="
+
https://github.com/blueman-project/blueman/releases/download/${PV/_/.}/${P/_/.}.tar.xz
+ "
+ S=${WORKDIR}/${P/_/.}
+ KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+# icons are GPL-2
+# source files are mixed GPL-3+ and GPL-2+
+LICENSE="GPL-3+ GPL-2"
+SLOT="0"
+IUSE="network nls policykit pulseaudio"
+
+DEPEND="
+ $(python_gen_cond_dep '
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ ')
+ >=net-wireless/bluez-5:=
+"
+BDEPEND="
+ $(python_gen_cond_dep '
+ dev-python/cython[${PYTHON_USEDEP}]
+ ')
+ virtual/pkgconfig
+ nls? ( sys-devel/gettext )
+"
+RDEPEND="
+ ${DEPEND}
+ $(python_gen_cond_dep '
+ dev-python/pycairo[${PYTHON_USEDEP}]
+ ')
+ sys-apps/dbus
+ x11-libs/gtk+:3[introspection,X]
+ x11-libs/libnotify[introspection]
+ || (
+ x11-themes/adwaita-icon-theme
+ x11-themes/faenza-icon-theme
+ x11-themes/mate-icon-theme
+ )
+ network? (
+ net-firewall/iptables
+ || (
+ sys-apps/net-tools
+ sys-apps/iproute2
+ )
+ || (
+ net-dns/dnsmasq
+ net-misc/dhcp
+ >=net-misc/networkmanager-0.8[introspection]
+ )
+ )
+ policykit? (
+ sys-auth/polkit
+ )
+ pulseaudio? (
+ || (
+ media-sound/pulseaudio-daemon[bluetooth]
+ media-video/pipewire[bluetooth]
+ <media-sound/pulseaudio-15.99.1[bluetooth]
+ )
+ )
+"
+
+pkg_pretend() {
+ if use network; then
+ local CONFIG_CHECK="
+ ~BRIDGE
+ ~IP_NF_IPTABLES
+ ~IP_NF_NAT
+ ~IP_NF_TARGET_MASQUERADE
+ "
+ check_extra_config
+ fi
+}
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ if [[ ${PV} == 9999 ]]; then
+ eautoreconf
+ else
+ # remove this when upstream switches to automake with .pyc fix
+ eautomake
+ fi
+ distutils-r1_src_prepare
+}
+
+python_configure() {
+ local myconf=(
+ --disable-runtime-deps-check
+ --disable-static
+ --with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+ --with-systemduserunitdir="$(systemd_get_userunitdir)"
+ --with-dhcp-config="/etc/dhcp/dhcpd.conf"
+ $(use_enable policykit polkit)
+ $(use_enable nls)
+ $(use_enable pulseaudio)
+ # thunar integration is a single data file with no extra deps
+ # so install it unconditionally
+ --enable-thunar-sendto
+ )
+ econf "${myconf[@]}"
+}
+
+python_compile() {
+ default
+}
+
+python_install() {
+ default
+
+ if use policykit; then
+ # Allow users in plugdev group to modify connections
+ insinto /usr/share/polkit-1/rules.d
+ doins "${FILESDIR}/01-org.blueman.rules"
+ fi
+
+ find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+ xdg_icon_cache_update
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+ gnome2_schemas_update
+}
