[gentoo-commits] repo/gentoo:master commit in: net-misc/tuba/

[Michał Górny]

commit:     584a5235d0abfb829a7442bb606d4ccc75f27d30
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 29 19:43:10 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Apr 29 19:48:21 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=584a5235

net-misc/tuba: Bump to 0.7.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 net-misc/tuba/Manifest          |  1 +
 net-misc/tuba/tuba-0.7.2.ebuild | 73 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/net-misc/tuba/Manifest b/net-misc/tuba/Manifest
index bd303a7aa894..16968ac79828 100644
--- a/net-misc/tuba/Manifest
+++ b/net-misc/tuba/Manifest
@@ -1 +1,2 @@
 DIST Tuba-0.6.3.gh.tar.gz 1124191 BLAKE2B 
b5a7107c94d9adf89fc02224891c12b71fc2b640e962006fbfcf1d0673e5f3f73b11423b6d66e8952e2aef122ade6a57607cced5d4707bd91193157fd561ce11
 SHA512 
b987b9b8434a0abd086a3197154b27bd4a0bca69df07bcec26c59a2da51cf447943e7a05a83529a99670f2b1b7ea1a7dce1da39148844d23706940f3a0a423d8
+DIST Tuba-0.7.2.gh.tar.gz 1388074 BLAKE2B 
6785225612db57592f351d2e0937b9578f4861230e999190f64b1068f344624ad41e69afcb199913c0a8e5b5eadb1438b7c6c48746b3582e1978afe6e09cde32
 SHA512 
bbabadbf2131233a737d6ccded50fde0af44330c7a69d1e0688a6ef42fe548826cacbe714a61df78dbe5afe867940b1dbae868efc3dfae707342b9f7ce5a9835

diff --git a/net-misc/tuba/tuba-0.7.2.ebuild b/net-misc/tuba/tuba-0.7.2.ebuild
new file mode 100644
index 000000000000..ddb73ceb06b5
--- /dev/null
+++ b/net-misc/tuba/tuba-0.7.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson optfeature vala
+
+MY_P=${P^}
+DESCRIPTION="Browse the Fediverse (GTK client)"
+HOMEPAGE="
+       https://tuba.geopjr.dev/
+       https://github.com/GeopJr/Tuba/
+"
+SRC_URI="
+       https://github.com/GeopJr/Tuba/archive/v${PV}.tar.gz
+               -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-3 CC-BY-SA-4.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+# TODO: optional dep on libspelling-1
+DEPEND="
+       app-crypt/libsecret[introspection,vala]
+       >=dev-libs/glib-2.76.0:2
+       dev-libs/icu:=
+       >=dev-libs/json-glib-1.4.4[introspection]
+       >=dev-libs/libgee-0.8.5:0.8[introspection]
+       dev-libs/libxml2
+       >=gui-libs/gtk-4.13.4:4[gstreamer,introspection]
+       >=gui-libs/libadwaita-1.5:1[introspection,vala]
+       >=gui-libs/gtksourceview-5.6.0:5[introspection,vala]
+       net-libs/libsoup:3.0[introspection,vala]
+"
+RDEPEND="
+       ${DEPEND}
+"
+BDEPEND="
+       $(vala_depend)
+       sys-devel/gettext
+       virtual/pkgconfig
+"
+
+src_configure() {
+       local emesonargs=(
+               # disable calling updaters (see pkg_post*)
+               -Ddistro=true
+       )
+
+       vala_setup
+       meson_src_configure
+}
+
+src_install() {
+       meson_src_install
+       dosym dev.geopjr.Tuba /usr/bin/tuba
+}
+
+pkg_postinst() {
+       optfeature "WebP image support" gui-libs/gdk-pixbuf-loader-webp
+
+       gnome2_schemas_update
+       xdg_desktop_database_update
+       xdg_icon_cache_update
+}
+
+pkg_postrm() {
+       gnome2_schemas_update
+       xdg_desktop_database_update
+       xdg_icon_cache_update
+}