commit: c5dc0a5596945c5dd6b4b1c3da0da90641ae225a
Author: Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Tue May 14 22:12:49 2024 +0000
Commit: Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Tue May 14 22:20:58 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c5dc0a55
app-emacs/racket-mode: bump to 1_p20240515
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>
app-emacs/racket-mode/Manifest | 1 +
.../racket-mode/racket-mode-1_p20240515.ebuild | 74 ++++++++++++++++++++++
2 files changed, 75 insertions(+)
diff --git a/app-emacs/racket-mode/Manifest b/app-emacs/racket-mode/Manifest
index 29840c06a63a..199ee5bf577e 100644
--- a/app-emacs/racket-mode/Manifest
+++ b/app-emacs/racket-mode/Manifest
@@ -1 +1,2 @@
DIST racket-mode-1_p20240130.tar.gz 373342 BLAKE2B
20ad54d6c64cb52d3c81004131e957c1d4ae8eb32128cb99ba043337832c7398c27d070035440efc2b2debf0324495cc1b15d45169c15da2c5efcb43ad98a71d
SHA512
3bf87a0de204db58e1781899d2e1fc70d10f5493e1ae35338b8c92fa0b8ce0c5a953d05c4de60628a057d43aaa22d0d13e6f33cc8ac8073dce8e0fc3c3954bcb
+DIST racket-mode-1_p20240515.tar.gz 373968 BLAKE2B
9a704da188c0cb6948fd36135a6e8f7f7f4e8583acf10a1ed890a96d674fb300f179e8873fefcb6df4aed0f81c9210630ec995c8ad0a17f674101fc0ac9f7cd2
SHA512
b8a0126e085f1508086c437823f5cfdf076e3c857e467d4f20b63baabcfd00bd03f4caf9e9ec3773b19f530ab50e96fe40cf1ca0c77f37033321aa0e7af59b92
diff --git a/app-emacs/racket-mode/racket-mode-1_p20240515.ebuild
b/app-emacs/racket-mode/racket-mode-1_p20240515.ebuild
new file mode 100644
index 000000000000..8c8b1a21c4cd
--- /dev/null
+++ b/app-emacs/racket-mode/racket-mode-1_p20240515.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+[[ "${PV}" == *p20240515 ]] &&
COMMIT="d2cff2b7f210846108875c7eccb1b5ab98bceb74"
+
+inherit elisp
+
+DESCRIPTION="Emacs modes for Racket: edit, REPL, check-syntax, debug, profile,
and more"
+HOMEPAGE="https://www.racket-mode.com/
+ https://github.com/greghendershott/racket-mode/";
+
+if [[ "${PV}" == *9999* ]] ; then
+ inherit git-r3
+
+ EGIT_REPO_URI="https://github.com/greghendershott/${PN}.git";
+else
+
SRC_URI="https://github.com/greghendershott/${PN}/archive/${COMMIT}.tar.gz
+ -> ${P}.tar.gz"
+ S="${WORKDIR}/${PN}-${COMMIT}"
+
+ KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-scheme/racket:=[-minimal]
+"
+BDEPEND="
+ ${RDEPEND}
+"
+
+ELISP_REMOVE="
+ test/racket/hash-lang-test.rkt
+"
+PATCHES=( "${FILESDIR}/${PN}-rkt-source-dir.patch" )
+
+DOCS=( CONTRIBUTING.org README.org THANKS.org )
+ELISP_TEXINFO="doc/${PN}.texi"
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+ elisp_src_prepare
+
+ sed "s|@SITEETC@|${SITEETC}/${PN}|" -i "${S}/racket-util.el" || die
+}
+
+src_compile() {
+ elisp_src_compile
+
+ # Equivalent to compiling from Emacs with "racket-mode-start-faster",
+ # because this is installed globally we have to compile it now.
+ ebegin "Compiling Racket source files"
+ find "${S}/racket" -type f -name "*.rkt" -exec raco make -v {} +
+ eend $? "failed to compile Racket source files" || die
+}
+
+src_test() {
+ # Set "PLTUSERHOME" to a safe temp directory to prevent writing to "~".
+ PLTUSERHOME="${T}/racket-mode/test-racket" emake test-racket
+}
+
+src_install() {
+ elisp_src_install
+
+ # Install Racket files to "${SITEETC}".
+ insinto "${SITEETC}/${PN}"
+ doins -r racket
+}
