commit: 02e60f1e0e7de329fa363eb616b2824ed80abd99
Author: Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Tue May 28 00:28:37 2024 +0000
Commit: Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Tue May 28 00:30:47 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=02e60f1e
sys-apps/flatpak: add 1.14.8
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>
sys-apps/flatpak/Manifest | 1 +
sys-apps/flatpak/flatpak-1.14.8.ebuild | 121 +++++++++++++++++++++++++++++++++
2 files changed, 122 insertions(+)
diff --git a/sys-apps/flatpak/Manifest b/sys-apps/flatpak/Manifest
index dc467e2313ab..55263cd566bc 100644
--- a/sys-apps/flatpak/Manifest
+++ b/sys-apps/flatpak/Manifest
@@ -3,3 +3,4 @@ DIST flatpak-1.12.9.tar.xz 1572536 BLAKE2B
bd9b116bf0e51e60d1e0c420c4c4553a0ebc5
DIST flatpak-1.14.4.tar.xz 1637484 BLAKE2B
cf208c581ad76d46489ba473d290c35907da0d1d473bf2b4792fb56c31e7110cd38f1c6fc4ad04aa3675868d17116ba52a84b028d7b7789c1736cfe26f3cabfe
SHA512
3f97096affd4f1de184ded353f1ab403d9f1813b199b9a1595596cc7c5d6b46062aa2ef184255823f50ae95ca60d0542d9b9e520f9a605f9bc51091863bf89b0
DIST flatpak-1.14.5.tar.xz 1637692 BLAKE2B
180dc094ef3feef1ccefceb562836f55f6e875016588a5984435ea3157498a8746305c16aa2c83044c107fd7f0e8f6c034c326b4ae29ade1c657e82cff353d47
SHA512
552deaaf3e6712a56f33698c20e6b8225c8893fe9a375af897fd99e19c487bf79b19c3e4ce3b00f3caf90020019ff67c628ca6a8f2ae1e6e01db397d2081ab2b
DIST flatpak-1.14.6.tar.xz 1644056 BLAKE2B
68bc8bdaf1d1c8a6046a06f800d41c1603e691e60a90f070c694501d50ee6fba3ad1978e222d22a9f99e2b85de9154e670149227b0f2ea6543483c2d103b5093
SHA512
d858682dbf539afe1b91087b6a0e0ebeea6658a0ef02c96d68259f3d8c58d1e6d02dd8b69db1b3c55f6d5df0f4d7e41c6165f668f09763dd3f9c3beb48f8bcf5
+DIST flatpak-1.14.8.tar.xz 1698728 BLAKE2B
aecfe77371ec2479ab12f46035213d6cfb672fe9fb1882a3225ae3ee8d3bd23e96848061bc1c778265f3ff4daf369eb19e584f36f804107543b0287f774997f1
SHA512
a34d539f4ed0682459a22afa282de36da964a3545abd78138d3d86d9464d67cb57479f93bf84d1a9d811b80e72e0ea11f64293cb09a559fd5ec2c957be1729a1
diff --git a/sys-apps/flatpak/flatpak-1.14.8.ebuild
b/sys-apps/flatpak/flatpak-1.14.8.ebuild
new file mode 100644
index 000000000000..71f8492997bb
--- /dev/null
+++ b/sys-apps/flatpak/flatpak-1.14.8.ebuild
@@ -0,0 +1,121 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit linux-info python-any-r1 systemd tmpfiles
+
+DESCRIPTION="Linux application sandboxing and distribution framework"
+HOMEPAGE="https://flatpak.org/";
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz";
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="doc introspection policykit seccomp systemd X"
+RESTRICT="test"
+
+RDEPEND="
+ acct-group/flatpak
+ acct-user/flatpak
+ >=app-arch/libarchive-2.8:=
+ app-arch/zstd:=
+ >=app-crypt/gpgme-1.1.8:=
+ >=dev-libs/appstream-0.12:=
+ >=dev-libs/appstream-glib-0.5.10:=
+ >=dev-libs/glib-2.56:2=
+ >=dev-libs/libxml2-2.4:=
+ dev-libs/json-glib:=
+ dev-libs/libassuan:=
+ >=dev-util/ostree-2020.8:=[gpg(+)]
+ dev-util/ostree[curl]
+ >=gnome-base/dconf-0.26:=
+ gnome-base/gsettings-desktop-schemas
+ net-misc/curl:=
+ >=sys-apps/bubblewrap-0.5.0
+ sys-apps/dbus
+ >=sys-fs/fuse-3.1.1:3=
+ sys-apps/xdg-dbus-proxy
+ X? (
+ x11-apps/xauth
+ x11-libs/libXau:=
+ )
+ x11-libs/gdk-pixbuf:2=
+ policykit? ( >=sys-auth/polkit-0.98:= )
+ seccomp? ( sys-libs/libseccomp:= )
+ systemd? ( sys-apps/systemd:= )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+ >=dev-build/automake-1.13.4
+ >=sys-devel/gettext-0.18.2
+ virtual/pkgconfig
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ app-alternatives/yacc
+ $(python_gen_any_dep 'dev-python/pyparsing[${PYTHON_USEDEP}]')
+ introspection? ( >=dev-libs/gobject-introspection-1.40 )
+ doc? (
+ app-text/xmlto
+ dev-libs/libxslt
+ )
+"
+
+PDEPEND="sys-apps/xdg-desktop-portal"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-1.14.4-fuse-3-slotted.patch
+)
+
+python_check_deps() {
+ python_has_version "dev-python/pyparsing[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ local CONFIG_CHECK="~USER_NS"
+ linux-info_pkg_setup
+ python-any-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+ # This line fails because locales are in /usr/lib/locale/locale-archive.
+ sed -i 's:^cp -r /usr/lib/locale/C.*:#\0:' tests/make-test-runtime.sh
|| die
+}
+
+src_configure() {
+ local myeconfargs=(
+ --enable-sandboxed-triggers
+ --localstatedir="${EPREFIX}"/var
+ --with-system-bubblewrap
+ --with-system-dbus-proxy
+ --with-tmpfilesdir="/usr/lib/tmpfiles.d"
+ $(use_enable X xauth)
+ $(use_enable doc documentation)
+ $(use_enable doc docbook-docs)
+ $(use_enable introspection)
+ $(use_enable policykit system-helper)
+ $(use_enable seccomp)
+ $(use_with systemd)
+ )
+
+ econf "${myeconfargs[@]}"
+}
+
+src_install() {
+ default
+ #
https://projects.gentoo.org/qa/policy-guide/installed-files.html#pg0303
+ find "${ED}" -name '*.la' -delete || die
+ # resolve conflict with acct-user/flatpak for #856706
+ rm -rf "${ED}/usr/lib/sysusers.d"
+
+ if use systemd; then
+ systemd_dounit "${FILESDIR}"/flatpak-update.{service,timer}
+ fi
+}
+
+pkg_postinst() {
+ tmpfiles_process flatpak.conf
+}
