commit: 533a360710f418e3bb5ae5f69f4845184c27d469
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue May 28 07:41:17 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue May 28 11:51:57 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=533a3607
dev-python/pythran: Bump to 0.16.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pythran/Manifest | 1 +
dev-python/pythran/pythran-0.16.1.ebuild | 104 +++++++++++++++++++++++++++++++
2 files changed, 105 insertions(+)
diff --git a/dev-python/pythran/Manifest b/dev-python/pythran/Manifest
index 0014bf5c985b..d33967f99cd5 100644
--- a/dev-python/pythran/Manifest
+++ b/dev-python/pythran/Manifest
@@ -1,2 +1,3 @@
DIST pythran-0.15.0.gh.tar.gz 3676474 BLAKE2B
2b9c08d773f7848cf43c804ffa9a84eb19d20dbc40668657daea9698fb468e62ec86226f39aa3b8ff07b48a3120604b44a9d6a6c9e7f2b5f0f41ba2e9a201231
SHA512
2abba0ab5328e60d622512aa6c5442fcc28edb4da4209db50ede64961b58c91c2109b7bb90e5872c5c0d487542f669dc2ca3e721c28229e283f6e0130f95aee0
DIST pythran-0.16.0.gh.tar.gz 3680823 BLAKE2B
b0bd65b79831b2a64503d25a71b41ba493281e36d2a147f301ba81ffb9f2f40de07b89d300df2768ffc3eeb49ff3ad6698f6a12d92c68150c1e51655a8e983aa
SHA512
8d65f10df6f73518f3a2606a796ee91480d654a17269651e05ee79c0d0c68b9d583c211caa8ef348c8d11cef49da36b560da6e8889accfad8c9b3a8b51eeff57
+DIST pythran-0.16.1.gh.tar.gz 3680817 BLAKE2B
2a4b928e9d0ce68248eb543c97da5afca900d81bc660377313617149c5aae7529a371bfd3604dd9feb6e38f834360fef881c8324ae72b585d8ab86e867c2f6b3
SHA512
7a89546b52bdae9bdaeba42768ac822c584a3714b8f4e32417d793454dc0b5492342dfd393d92f8ecee12c854bc39e418f5860aadd00d328afef7b17ebddec99
diff --git a/dev-python/pythran/pythran-0.16.1.ebuild
b/dev-python/pythran/pythran-0.16.1.ebuild
new file mode 100644
index 000000000000..7742daea3351
--- /dev/null
+++ b/dev-python/pythran/pythran-0.16.1.ebuild
@@ -0,0 +1,104 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_TESTED=( pypy3 python3_{10..12} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="Ahead of Time compiler for numeric kernels"
+HOMEPAGE="
+ https://pypi.org/project/pythran/
+ https://github.com/serge-sans-paille/pythran/
+"
+SRC_URI="
+
https://github.com/serge-sans-paille/pythran/archive/${PV/_p/.post}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+ dev-libs/boost
+ dev-cpp/xsimd
+ =dev-python/beniget-0.4*[${PYTHON_USEDEP}]
+ =dev-python/gast-0.5*[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ >=dev-python/ply-3.4[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]
+"
+DEPEND="
+ test? (
+ dev-libs/boost
+ dev-cpp/xsimd
+ )
+"
+BDEPEND="
+ test? (
+ $(python_gen_cond_dep '
+ dev-python/ipython[${PYTHON_USEDEP}]
+ dev-python/pip[${PYTHON_USEDEP}]
+ dev-python/scipy[${PYTHON_USEDEP}]
+ ' "${PYTHON_TESTED[@]}")
+ dev-python/packaging[${PYTHON_USEDEP}]
+ dev-python/wheel[${PYTHON_USEDEP}]
+ virtual/cblas
+ !!dev-python/setuptools-declarative-requirements
+ )
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_configure() {
+ # vendored C++ headers -- use system copies
+ rm -r pythran/{boost,xsimd} || die
+
+ if use test ; then
+ # https://bugs.gentoo.org/916461
+ sed -i \
+ -e 's|blas=blas|blas=cblas|' \
+ -e 's|libs=|libs=cblas|' \
+ pythran/pythran-*.cfg || die
+ fi
+}
+
+python_test() {
+ local -x COLUMNS=80
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+
+ local EPYTEST_DESELECT=(
+ # TODO
+
pythran/tests/test_numpy_ufunc_unary.py::TestNumpyUFuncUnary::test_signbit0
+ )
+
+ if has_version ">=dev-python/numpy-2[${PYTHON_USEDEP}]"; then
+ case ${EPYTHON} in
+ pypy3)
+ EPYTEST_DESELECT+=(
+
pythran/tests/test_distutils.py::TestDistutils::test_setup_bdist_install3
+
pythran/tests/test_distutils.py::TestDistutils::test_setup_build3
+
pythran/tests/test_distutils.py::TestDistutils::test_setup_sdist_install
+
pythran/tests/test_distutils.py::TestDistutils::test_setup_sdist_install2
+
pythran/tests/test_distutils.py::TestDistutils::test_setup_sdist_install3
+
pythran/tests/test_exception.py::TestException::test_multiple_tuple_exception_register
+
pythran/tests/test_ndarray.py::TestNdarray::test_ndarray_fancy_indexing1
+
pythran/tests/test_numpy_fft.py::TestNumpyFFTN::test_fftn_1
+
pythran/tests/test_numpy_func0.py::TestNumpyFunc0::test_ravel0
+
pythran/tests/test_numpy_func3.py::TestNumpyFunc3::test_list_imag0
+
pythran/tests/test_numpy_random.py::TestNumpyRandom::test_numpy_uniform_size_int
+
pythran/tests/test_set.py::TestSet::test_fct_symmetric_difference_update
+ )
+ ;;
+ esac
+ fi
+
+ epytest
+}
