commit: ac9b0588d9ccc601e2be8c58e37940cf4957b851
Author: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 4 08:16:57 2024 +0000
Commit: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Tue Jun 4 19:30:48 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ac9b0588
dev-qt/qtwayland: add 6.8.9999
tst_client, tst_scaling, and tst_compositor failed but
still early on look at what's up with these.
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>
dev-qt/qtwayland/qtwayland-6.8.9999.ebuild | 60 ++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
diff --git a/dev-qt/qtwayland/qtwayland-6.8.9999.ebuild
b/dev-qt/qtwayland/qtwayland-6.8.9999.ebuild
new file mode 100644
index 000000000000..93ba392322f1
--- /dev/null
+++ b/dev-qt/qtwayland/qtwayland-6.8.9999.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Wayland platform plugin for Qt"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+ KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+IUSE="accessibility compositor gnome qml vulkan"
+
+RDEPEND="
+ dev-libs/wayland
+ ~dev-qt/qtbase-${PV}:6[accessibility=,gui,opengl,vulkan=,wayland]
+ media-libs/libglvnd
+ x11-libs/libxkbcommon
+ compositor? (
+ qml? ( ~dev-qt/qtdeclarative-${PV}:6 )
+ )
+ gnome? (
+ ~dev-qt/qtbase-${PV}:6[dbus]
+ ~dev-qt/qtsvg-${PV}:6
+ )
+"
+DEPEND="
+ ${RDEPEND}
+ vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="dev-util/wayland-scanner"
+
+CMAKE_SKIP_TESTS=(
+ # segfaults for not-looked-into reasons, but not considered
+ # an issue given >=seatv5 exists since wayland-1.10 (2016)
+ tst_seatv4
+ # needs a compositor/opengl, skip the extra trouble
+ tst_surface
+ tst_xdgdecorationv1
+)
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake_use_find_package qml Qt6Quick)
+ $(qt_feature compositor wayland_server)
+ $(qt_feature gnome wayland_decoration_adwaita)
+ )
+
+ qt6-build_src_configure
+}
+
+src_test() {
+ # users' session setting may break tst_clientextension (bug #927030)
+ unset DESKTOP_SESSION XDG_CURRENT_DESKTOP
+ unset GNOME_DESKTOP_SESSION_ID KDE_FULL_SESSION
+
+ qt6-build_src_test
+}
