commit: 1736af822cb1d2d9f27176c8849fc145f2b002c8
Author: David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 4 13:30:58 2024 +0000
Commit: David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Thu Jul 4 13:30:58 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1736af82
dev-libs/link-grammar: add 5.12.5
Signed-off-by: David Seifert <soap <AT> gentoo.org>
dev-libs/link-grammar/Manifest | 1 +
dev-libs/link-grammar/link-grammar-5.12.5.ebuild | 117 +++++++++++++++++++++++
2 files changed, 118 insertions(+)
diff --git a/dev-libs/link-grammar/Manifest b/dev-libs/link-grammar/Manifest
index 75d64829e040..219d8767dc3d 100644
--- a/dev-libs/link-grammar/Manifest
+++ b/dev-libs/link-grammar/Manifest
@@ -1 +1,2 @@
DIST link-grammar-5.12.4.tar.gz 4720724 BLAKE2B
6573895298128165d7f840a13aad124418dbd1b9c70436dbe2bd65b3fd1883777e72da13f5196031696edb7cdc6c9d86acd5fdd4d1aa8fb295a136b2ba0568cf
SHA512
fd5318c21202c17902de996882fd8630c7e95622b8ebe6877a334df22ff678a6040e0519bdabfa1138aaefdf3a7c20cbfe9e65bdce4dfe568729c9ba5a2d6fe5
+DIST link-grammar-5.12.5.tar.gz 4727809 BLAKE2B
76654a94bb1222761bc9107f2e129d6c7606e4cc0fa03b4564705714c8ac35f9562c28d66924b24143c8bbd6365f77714ad233f163f8f83de1da73ac66213f07
SHA512
2637d6b571ae027d8813da188a555a8b91afa0a216921842b43e4cf6aa4d799ea5342fe17081c13346c6bbecc46032765b6f5d978b53cee570e329b6b141094b
diff --git a/dev-libs/link-grammar/link-grammar-5.12.5.ebuild
b/dev-libs/link-grammar/link-grammar-5.12.5.ebuild
new file mode 100644
index 000000000000..8de336d90754
--- /dev/null
+++ b/dev-libs/link-grammar/link-grammar-5.12.5.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit autotools python-r1 out-of-source
+
+DESCRIPTION="A Syntactic English parser"
+HOMEPAGE="https://www.abisource.com/projects/link-grammar/
https://www.link.cs.cmu.edu/link/";
+SRC_URI="https://www.gnucash.org/link-grammar/downloads/${PV}/${P}.tar.gz";
+
+LICENSE="LGPL-2.1"
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="aspell +hunspell python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# XXX: sqlite is automagic
+# Does not build with >=sci-mathematics/minisat-2, bug #593662
+RDEPEND="
+ dev-db/sqlite:3
+ dev-libs/libpcre2:=
+ aspell? ( app-text/aspell )
+ hunspell? ( app-text/hunspell )
+ python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ dev-lang/swig:0
+ dev-build/autoconf-archive
+ sys-devel/flex
+ virtual/pkgconfig"
+
+QA_CONFIG_IMPL_DECL_SKIP=(
+ # _AC_UNDECLARED_BUILTIN false positive
+ strchr
+ typeof
+)
+
+pkg_setup() {
+ if use aspell && use hunspell; then
+ ewarn "You have enabled 'aspell' and 'hunspell' support, but
both cannot coexist,"
+ ewarn "only hunspell will be built. Press Ctrl+C and set only
'aspell' USE flag if"
+ ewarn "you want aspell support."
+ fi
+}
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+my_src_configure() {
+ local myconf=(
+ --disable-maintainer-mode
+ --disable-editline
+ # java is hopelessly broken, invokes maven at build time (bug
#806157)
+ --disable-java-bindings
+ --disable-perl-bindings
+ --disable-sat-solver
+ --with-regexlib=pcre2
+ $(use_enable aspell)
+ $(use_enable hunspell)
+ $(usev hunspell
--with-hunspell-dictdir="${EPREFIX}"/usr/share/myspell)
+ # requires flex, since reflex support is flaky, #890158
+ LEX="flex"
+ )
+
+ econf \
+ --disable-python-bindings \
+ "${myconf[@]}"
+
+ if use python; then
+ python_configure() {
+ econf \
+ --enable-python-bindings \
+ "${myconf[@]}"
+ }
+ python_foreach_impl run_in_build_dir python_configure
+ fi
+}
+
+my_src_compile() {
+ local -x MAIN_BUILD_DIR="${BUILD_DIR}"
+ default
+
+ if use python; then
+ python_compile() {
+ emake -C bindings/python \
+ VPATH="${S}:${MAIN_BUILD_DIR}" \
+
_clinkgrammar_la_DEPENDENCIES="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la
\
+
_clinkgrammar_la_LIBADD="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la
+ }
+ python_foreach_impl run_in_build_dir python_compile
+ fi
+}
+
+my_src_install() {
+ local -x MAIN_BUILD_DIR="${BUILD_DIR}"
+ default
+
+ if use python; then
+ python_install() {
+ emake -C bindings/python \
+ VPATH="${S}:${MAIN_BUILD_DIR}" \
+
_clinkgrammar_la_DEPENDENCIES="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la
\
+
_clinkgrammar_la_LIBADD="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la \
+ DESTDIR="${D}" \
+ install
+ }
+ python_foreach_impl run_in_build_dir python_install
+ fi
+
+ # no static archives
+ find "${ED}" -name '*.la' -delete || die
+}
