commit: 128f43e3887ae5ee2668949c6902d3b31036b1ee
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 22 01:43:00 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jul 22 01:43:00 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=128f43e3
dev-python/pylint: Bump to 3.2.6
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pylint/Manifest | 1 +
dev-python/pylint/pylint-3.2.6.ebuild | 93 +++++++++++++++++++++++++++++++++++
2 files changed, 94 insertions(+)
diff --git a/dev-python/pylint/Manifest b/dev-python/pylint/Manifest
index 8c38342880fc..a300c7086894 100644
--- a/dev-python/pylint/Manifest
+++ b/dev-python/pylint/Manifest
@@ -1 +1,2 @@
DIST pylint-3.2.5.gh.tar.gz 1446535 BLAKE2B
fdc88c7873868b1cb689158d014c51a14be9200715ad2f870cc7f8703e1e29881d04092c5e49fd043d54b31258b25d0c0f40cb81cd50c0603835a67197b29d85
SHA512
bba78776ae2610456ecfecffd9571712c13c38006de19d569aaf11bdeee978e1ad33b09ce64288fb2ebccd76d76a788a8db39209cf3f9963d8a38a43605bcbaa
+DIST pylint-3.2.6.gh.tar.gz 1447684 BLAKE2B
22ec600b327b405dfdd7a9ffe94b20faeed6cca92dbfff8e96baa6bebe5c049b90da55f16e84e53d4a22fdbcb5a8caf7719038935522235ccf3364fe2492c16c
SHA512
ba7e87f3eaca088b88cec35ae8d1dbd15ec2167a615638b1fe7c1abb711d54742e5fb2d2c9c2836294c464b98ec32d53efaf5afb170d4cb73dacf966dddca62c
diff --git a/dev-python/pylint/pylint-3.2.6.ebuild
b/dev-python/pylint/pylint-3.2.6.ebuild
new file mode 100644
index 000000000000..0cd2ec935a5d
--- /dev/null
+++ b/dev-python/pylint/pylint-3.2.6.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_beta/b}
+DESCRIPTION="Python code static checker"
+HOMEPAGE="
+ https://pypi.org/project/pylint/
+ https://github.com/pylint-dev/pylint/
+"
+SRC_URI="
+ https://github.com/pylint-dev/pylint/archive/v${PV/_beta/b}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="
+ <dev-python/astroid-3.3[${PYTHON_USEDEP}]
+ >=dev-python/astroid-3.2.4[${PYTHON_USEDEP}]
+ >=dev-python/dill-0.3.7[${PYTHON_USEDEP}]
+ >=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+ <dev-python/isort-6[${PYTHON_USEDEP}]
+ >=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
+ <dev-python/mccabe-0.8[${PYTHON_USEDEP}]
+ >=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
+ >=dev-python/tomlkit-0.10.1[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+ ' 3.10)
+"
+BDEPEND="
+ test? (
+ $(python_gen_cond_dep '
+ >=dev-python/GitPython-3[${PYTHON_USEDEP}]
+ ' 'python*' )
+ <dev-python/pytest-8[${PYTHON_USEDEP}]
+ dev-python/pytest-timeout[${PYTHON_USEDEP}]
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO
+
'tests/test_functional.py::test_functional[dataclass_with_field]'
+ 'tests/test_functional.py::test_functional[no_name_in_module]'
+
'tests/test_functional.py::test_functional[recursion_error_3159]'
+ 'tests/test_functional.py::test_functional[shadowed_import]'
+ 'tests/test_functional.py::test_functional[use_yield_from]'
+ 'tests/test_functional.py::test_functional[wrong_import_order]'
+ )
+ local EPYTEST_IGNORE=(
+ # No need to run the benchmarks
+ tests/benchmark/test_baseline_benchmarks.py
+ )
+
+ if ! has_version "dev-python/GitPython[${PYTHON_USEDEP}]"; then
+ EPYTEST_IGNORE+=(
+ tests/profile/test_profile_against_externals.py
+ tests/testutils/_primer/test_package_to_lint.py
+ tests/testutils/_primer/test_primer.py
+ )
+ fi
+
+ rm -rf pylint || die
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p timeout
+}
+
+python_install_all() {
+ if use examples ; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r examples/.
+ fi
+
+ distutils-r1_python_install_all
+}
